dtbt03()

subroutine dtbt03	(	character	uplo,
		character	trans,
		character	diag,
		integer	n,
		integer	kd,
		integer	nrhs,
		double precision, dimension( ldab, * )	ab,
		integer	ldab,
		double precision	scale,
		double precision, dimension( * )	cnorm,
		double precision	tscal,
		double precision, dimension( ldx, * )	x,
		integer	ldx,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( * )	work,
		double precision	resid )

DTBT03

Purpose:

!>
!> DTBT03 computes the residual for the solution to a scaled triangular
!> system of equations  A*x = s*b  or  A'*x = s*b  when A is a
!> triangular band matrix. Here A' is the transpose of A, s is a scalar,
!> and x and b are N by NRHS matrices.  The test ratio is the maximum
!> over the number of right hand sides of
!>    norm(s*b - op(A)*x) / ( norm(op(A)) * norm(x) * EPS ),
!> where op(A) denotes A or A' and EPS is the machine epsilon.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the matrix A is upper or lower triangular. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the operation applied to A. !> = 'N': A *x = b (No transpose) !> = 'T': A'*x = b (Transpose) !> = 'C': A'*x = b (Conjugate transpose = Transpose) !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> Specifies whether or not the matrix A is unit triangular. !> = 'N': Non-unit triangular !> = 'U': Unit triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	KD	!> KD is INTEGER !> The number of superdiagonals or subdiagonals of the !> triangular band matrix A. KD >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices X and B. NRHS >= 0. !>
[in]	AB	!> AB is DOUBLE PRECISION array, dimension (LDAB,N) !> The upper or lower triangular band matrix A, stored in the !> first kd+1 rows of the array. The j-th column of A is stored !> in the j-th column of the array AB as follows: !> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; !> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= KD+1. !>
[in]	SCALE	!> SCALE is DOUBLE PRECISION !> The scaling factor s used in solving the triangular system. !>
[in]	CNORM	!> CNORM is DOUBLE PRECISION array, dimension (N) !> The 1-norms of the columns of A, not counting the diagonal. !>
[in]	TSCAL	!> TSCAL is DOUBLE PRECISION !> The scaling factor used in computing the 1-norms in CNORM. !> CNORM actually contains the column norms of TSCAL*A. !>
[in]	X	!> X is DOUBLE PRECISION array, dimension (LDX,NRHS) !> The computed solution vectors for the system of linear !> equations. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[in]	B	!> B is DOUBLE PRECISION array, dimension (LDB,NRHS) !> The right hand side vectors for the system of linear !> equations. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (N) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> The maximum over the number of right hand sides of !> norm(op(A)*x - s*b) / ( norm(op(A)) * norm(x) * EPS ). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 172 of file dtbt03.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, TRANS, UPLO
      INTEGER            KD, LDAB, LDB, LDX, N, NRHS
      DOUBLE PRECISION   RESID, SCALE, TSCAL
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AB( LDAB, * ), B( LDB, * ), CNORM( * ),
     $                   WORK( * ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            IX, J
      DOUBLE PRECISION   BIGNUM, EPS, ERR, SMLNUM, TNORM, XNORM, XSCAL
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IDAMAX
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           lsame, idamax, dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dcopy, dscal, dtbmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
      eps = dlamch( 'Epsilon' )
      smlnum = dlamch( 'Safe minimum' )
      bignum = one / smlnum
*
*     Compute the norm of the triangular matrix A using the column
*     norms already computed by DLATBS.
*
      tnorm = zero
      IF( lsame( diag, 'N' ) ) THEN
         IF( lsame( uplo, 'U' ) ) THEN
            DO 10 j = 1, n
               tnorm = max( tnorm, tscal*abs( ab( kd+1, j ) )+
     $                 cnorm( j ) )
   10       CONTINUE
         ELSE
            DO 20 j = 1, n
               tnorm = max( tnorm, tscal*abs( ab( 1, j ) )+cnorm( j ) )
   20       CONTINUE
         END IF
      ELSE
         DO 30 j = 1, n
            tnorm = max( tnorm, tscal+cnorm( j ) )
   30    CONTINUE
      END IF
*
*     Compute the maximum over the number of right hand sides of
*        norm(op(A)*x - s*b) / ( norm(op(A)) * norm(x) * EPS ).
*
      resid = zero
      DO 40 j = 1, nrhs
         CALL dcopy( n, x( 1, j ), 1, work, 1 )
         ix = idamax( n, work, 1 )
         xnorm = max( one, abs( x( ix, j ) ) )
         xscal = ( one / xnorm ) / dble( kd+1 )
         CALL dscal( n, xscal, work, 1 )
         CALL dtbmv( uplo, trans, diag, n, kd, ab, ldab, work, 1 )
         CALL daxpy( n, -scale*xscal, b( 1, j ), 1, work, 1 )
         ix = idamax( n, work, 1 )
         err = tscal*abs( work( ix ) )
         ix = idamax( n, x( 1, j ), 1 )
         xnorm = abs( x( ix, j ) )
         IF( err*smlnum.LE.xnorm ) THEN
            IF( xnorm.GT.zero )
     $         err = err / xnorm
         ELSE
            IF( err.GT.zero )
     $         err = one / eps
         END IF
         IF( err*smlnum.LE.tnorm ) THEN
            IF( tnorm.GT.zero )
     $         err = err / tnorm
         ELSE
            IF( err.GT.zero )
     $         err = one / eps
         END IF
         resid = max( resid, err )
   40 CONTINUE
*
      RETURN
*
*     End of DTBT03
*

Here is the call graph for this function:

Here is the caller graph for this function: