dtzrqf()

subroutine dtzrqf	(	integer	m,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	tau,
		integer	info )

DTZRQF

Download DTZRQF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> This routine is deprecated and has been replaced by routine DTZRZF.
!>
!> DTZRQF reduces the M-by-N ( M<=N ) real upper trapezoidal matrix A
!> to upper triangular form by means of orthogonal transformations.
!>
!> The upper trapezoidal matrix A is factored as
!>
!>    A = ( R  0 ) * Z,
!>
!> where Z is an N-by-N orthogonal matrix and R is an M-by-M upper
!> triangular matrix.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= M. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> On entry, the leading M-by-N upper trapezoidal part of the !> array A must contain the matrix to be factorized. !> On exit, the leading M-by-M upper triangular part of A !> contains the upper triangular matrix R, and elements M+1 to !> N of the first M rows of A, with the array TAU, represent the !> orthogonal matrix Z as a product of M elementary reflectors. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[out]	TAU	!> TAU is DOUBLE PRECISION array, dimension (M) !> The scalar factors of the elementary reflectors. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The factorization is obtained by Householder's method.  The kth
!>  transformation matrix, Z( k ), which is used to introduce zeros into
!>  the ( m - k + 1 )th row of A, is given in the form
!>
!>     Z( k ) = ( I     0   ),
!>              ( 0  T( k ) )
!>
!>  where
!>
!>     T( k ) = I - tau*u( k )*u( k )**T,   u( k ) = (   1    ),
!>                                                   (   0    )
!>                                                   ( z( k ) )
!>
!>  tau is a scalar and z( k ) is an ( n - m ) element vector.
!>  tau and z( k ) are chosen to annihilate the elements of the kth row
!>  of X.
!>
!>  The scalar tau is returned in the kth element of TAU and the vector
!>  u( k ) in the kth row of A, such that the elements of z( k ) are
!>  in  a( k, m + 1 ), ..., a( k, n ). The elements of R are returned in
!>  the upper triangular part of A.
!>
!>  Z is given by
!>
!>     Z =  Z( 1 ) * Z( 2 ) * ... * Z( m ).
!> 

Definition at line 135 of file dtzrqf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), TAU( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, K, M1
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dcopy, dgemv, dger, dlarfg, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.m ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DTZRQF', -info )
         RETURN
      END IF
*
*     Perform the factorization.
*
      IF( m.EQ.0 )
     $   RETURN
      IF( m.EQ.n ) THEN
         DO 10 i = 1, n
            tau( i ) = zero
   10    CONTINUE
      ELSE
         m1 = min( m+1, n )
         DO 20 k = m, 1, -1
*
*           Use a Householder reflection to zero the kth row of A.
*           First set up the reflection.
*
            CALL dlarfg( n-m+1, a( k, k ), a( k, m1 ), lda,
     $                   tau( k ) )
*
            IF( ( tau( k ).NE.zero ) .AND. ( k.GT.1 ) ) THEN
*
*              We now perform the operation  A := A*P( k ).
*
*              Use the first ( k - 1 ) elements of TAU to store  a( k ),
*              where  a( k ) consists of the first ( k - 1 ) elements of
*              the  kth column  of  A.  Also  let  B  denote  the  first
*              ( k - 1 ) rows of the last ( n - m ) columns of A.
*
               CALL dcopy( k-1, a( 1, k ), 1, tau, 1 )
*
*              Form   w = a( k ) + B*z( k )  in TAU.
*
               CALL dgemv( 'No transpose', k-1, n-m, one, a( 1, m1 ),
     $                     lda, a( k, m1 ), lda, one, tau, 1 )
*
*              Now form  a( k ) := a( k ) - tau*w
*              and       B      := B      - tau*w*z( k )**T.
*
               CALL daxpy( k-1, -tau( k ), tau, 1, a( 1, k ), 1 )
               CALL dger( k-1, n-m, -tau( k ), tau, 1, a( k, m1 ),
     $                    lda, a( 1, m1 ), lda )
            END IF
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of DTZRQF
*

Here is the call graph for this function:

Here is the caller graph for this function: