LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ slarot()

subroutine slarot ( logical  LROWS,
logical  LLEFT,
logical  LRIGHT,
integer  NL,
real  C,
real  S,
real, dimension( * )  A,
integer  LDA,
real  XLEFT,
real  XRIGHT 
)

SLAROT

Purpose:
    SLAROT applies a (Givens) rotation to two adjacent rows or
    columns, where one element of the first and/or last column/row
    for use on matrices stored in some format other than GE, so
    that elements of the matrix may be used or modified for which
    no array element is provided.

    One example is a symmetric matrix in SB format (bandwidth=4), for
    which UPLO='L':  Two adjacent rows will have the format:

    row j:     C> C> C> C> C> .  .  .  .
    row j+1:      C> C> C> C> C> .  .  .  .

    '*' indicates elements for which storage is provided,
    '.' indicates elements for which no storage is provided, but
    are not necessarily zero; their values are determined by
    symmetry.  ' ' indicates elements which are necessarily zero,
     and have no storage provided.

    Those columns which have two '*'s can be handled by SROT.
    Those columns which have no '*'s can be ignored, since as long
    as the Givens rotations are carefully applied to preserve
    symmetry, their values are determined.
    Those columns which have one '*' have to be handled separately,
    by using separate variables "p" and "q":

    row j:     C> C> C> C> C> p  .  .  .
    row j+1:   q  C> C> C> C> C> .  .  .  .

    The element p would have to be set correctly, then that column
    is rotated, setting p to its new value.  The next call to
    SLAROT would rotate columns j and j+1, using p, and restore
    symmetry.  The element q would start out being zero, and be
    made non-zero by the rotation.  Later, rotations would presumably
    be chosen to zero q out.

    Typical Calling Sequences: rotating the i-th and (i+1)-st rows.
    ------- ------- ---------

      General dense matrix:

              CALL SLAROT(.TRUE.,.FALSE.,.FALSE., N, C,S,
                      A(i,1),LDA, DUMMY, DUMMY)

      General banded matrix in GB format:

              j = MAX(1, i-KL )
              NL = MIN( N, i+KU+1 ) + 1-j
              CALL SLAROT( .TRUE., i-KL.GE.1, i+KU.LT.N, NL, C,S,
                      A(KU+i+1-j,j),LDA-1, XLEFT, XRIGHT )

              [ note that i+1-j is just MIN(i,KL+1) ]

      Symmetric banded matrix in SY format, bandwidth K,
      lower triangle only:

              j = MAX(1, i-K )
              NL = MIN( K+1, i ) + 1
              CALL SLAROT( .TRUE., i-K.GE.1, .TRUE., NL, C,S,
                      A(i,j), LDA, XLEFT, XRIGHT )

      Same, but upper triangle only:

              NL = MIN( K+1, N-i ) + 1
              CALL SLAROT( .TRUE., .TRUE., i+K.LT.N, NL, C,S,
                      A(i,i), LDA, XLEFT, XRIGHT )

      Symmetric banded matrix in SB format, bandwidth K,
      lower triangle only:

              [ same as for SY, except:]
                  . . . .
                      A(i+1-j,j), LDA-1, XLEFT, XRIGHT )

              [ note that i+1-j is just MIN(i,K+1) ]

      Same, but upper triangle only:
                   . . .
                      A(K+1,i), LDA-1, XLEFT, XRIGHT )

      Rotating columns is just the transpose of rotating rows, except
      for GB and SB: (rotating columns i and i+1)

      GB:
              j = MAX(1, i-KU )
              NL = MIN( N, i+KL+1 ) + 1-j
              CALL SLAROT( .TRUE., i-KU.GE.1, i+KL.LT.N, NL, C,S,
                      A(KU+j+1-i,i),LDA-1, XTOP, XBOTTM )

              [note that KU+j+1-i is just MAX(1,KU+2-i)]

      SB: (upper triangle)

                   . . . . . .
                      A(K+j+1-i,i),LDA-1, XTOP, XBOTTM )

      SB: (lower triangle)

                   . . . . . .
                      A(1,i),LDA-1, XTOP, XBOTTM )
  LROWS  - LOGICAL
           If .TRUE., then SLAROT will rotate two rows.  If .FALSE.,
           then it will rotate two columns.
           Not modified.

  LLEFT  - LOGICAL
           If .TRUE., then XLEFT will be used instead of the
           corresponding element of A for the first element in the
           second row (if LROWS=.FALSE.) or column (if LROWS=.TRUE.)
           If .FALSE., then the corresponding element of A will be
           used.
           Not modified.

  LRIGHT - LOGICAL
           If .TRUE., then XRIGHT will be used instead of the
           corresponding element of A for the last element in the
           first row (if LROWS=.FALSE.) or column (if LROWS=.TRUE.) If
           .FALSE., then the corresponding element of A will be used.
           Not modified.

  NL     - INTEGER
           The length of the rows (if LROWS=.TRUE.) or columns (if
           LROWS=.FALSE.) to be rotated.  If XLEFT and/or XRIGHT are
           used, the columns/rows they are in should be included in
           NL, e.g., if LLEFT = LRIGHT = .TRUE., then NL must be at
           least 2.  The number of rows/columns to be rotated
           exclusive of those involving XLEFT and/or XRIGHT may
           not be negative, i.e., NL minus how many of LLEFT and
           LRIGHT are .TRUE. must be at least zero; if not, XERBLA
           will be called.
           Not modified.

  C, S   - REAL
           Specify the Givens rotation to be applied.  If LROWS is
           true, then the matrix ( c  s )
                                 (-s  c )  is applied from the left;
           if false, then the transpose thereof is applied from the
           right.  For a Givens rotation, C**2 + S**2 should be 1,
           but this is not checked.
           Not modified.

  A      - REAL array.
           The array containing the rows/columns to be rotated.  The
           first element of A should be the upper left element to
           be rotated.
           Read and modified.

  LDA    - INTEGER
           The "effective" leading dimension of A.  If A contains
           a matrix stored in GE or SY format, then this is just
           the leading dimension of A as dimensioned in the calling
           routine.  If A contains a matrix stored in band (GB or SB)
           format, then this should be *one less* than the leading
           dimension used in the calling routine.  Thus, if
           A were dimensioned A(LDA,*) in SLAROT, then A(1,j) would
           be the j-th element in the first of the two rows
           to be rotated, and A(2,j) would be the j-th in the second,
           regardless of how the array may be stored in the calling
           routine.  [A cannot, however, actually be dimensioned thus,
           since for band format, the row number may exceed LDA, which
           is not legal FORTRAN.]
           If LROWS=.TRUE., then LDA must be at least 1, otherwise
           it must be at least NL minus the number of .TRUE. values
           in XLEFT and XRIGHT.
           Not modified.

  XLEFT  - REAL
           If LLEFT is .TRUE., then XLEFT will be used and modified
           instead of A(2,1) (if LROWS=.TRUE.) or A(1,2)
           (if LROWS=.FALSE.).
           Read and modified.

  XRIGHT - REAL
           If LRIGHT is .TRUE., then XRIGHT will be used and modified
           instead of A(1,NL) (if LROWS=.TRUE.) or A(NL,1)
           (if LROWS=.FALSE.).
           Read and modified.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 224 of file slarot.f.

226*
227* -- LAPACK auxiliary routine --
228* -- LAPACK is a software package provided by Univ. of Tennessee, --
229* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
230*
231* .. Scalar Arguments ..
232 LOGICAL LLEFT, LRIGHT, LROWS
233 INTEGER LDA, NL
234 REAL C, S, XLEFT, XRIGHT
235* ..
236* .. Array Arguments ..
237 REAL A( * )
238* ..
239*
240* =====================================================================
241*
242* .. Local Scalars ..
243 INTEGER IINC, INEXT, IX, IY, IYT, NT
244* ..
245* .. Local Arrays ..
246 REAL XT( 2 ), YT( 2 )
247* ..
248* .. External Subroutines ..
249 EXTERNAL srot, xerbla
250* ..
251* .. Executable Statements ..
252*
253* Set up indices, arrays for ends
254*
255 IF( lrows ) THEN
256 iinc = lda
257 inext = 1
258 ELSE
259 iinc = 1
260 inext = lda
261 END IF
262*
263 IF( lleft ) THEN
264 nt = 1
265 ix = 1 + iinc
266 iy = 2 + lda
267 xt( 1 ) = a( 1 )
268 yt( 1 ) = xleft
269 ELSE
270 nt = 0
271 ix = 1
272 iy = 1 + inext
273 END IF
274*
275 IF( lright ) THEN
276 iyt = 1 + inext + ( nl-1 )*iinc
277 nt = nt + 1
278 xt( nt ) = xright
279 yt( nt ) = a( iyt )
280 END IF
281*
282* Check for errors
283*
284 IF( nl.LT.nt ) THEN
285 CALL xerbla( 'SLAROT', 4 )
286 RETURN
287 END IF
288 IF( lda.LE.0 .OR. ( .NOT.lrows .AND. lda.LT.nl-nt ) ) THEN
289 CALL xerbla( 'SLAROT', 8 )
290 RETURN
291 END IF
292*
293* Rotate
294*
295 CALL srot( nl-nt, a( ix ), iinc, a( iy ), iinc, c, s )
296 CALL srot( nt, xt, 1, yt, 1, c, s )
297*
298* Stuff values back into XLEFT, XRIGHT, etc.
299*
300 IF( lleft ) THEN
301 a( 1 ) = xt( 1 )
302 xleft = yt( 1 )
303 END IF
304*
305 IF( lright ) THEN
306 xright = xt( nt )
307 a( iyt ) = yt( nt )
308 END IF
309*
310 RETURN
311*
312* End of SLAROT
313*
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine srot(N, SX, INCX, SY, INCY, C, S)
SROT
Definition: srot.f:92
Here is the call graph for this function:
Here is the caller graph for this function: