LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zhseqr()

subroutine zhseqr ( character job,
character compz,
integer n,
integer ilo,
integer ihi,
complex*16, dimension( ldh, * ) h,
integer ldh,
complex*16, dimension( * ) w,
complex*16, dimension( ldz, * ) z,
integer ldz,
complex*16, dimension( * ) work,
integer lwork,
integer info )

ZHSEQR

Download ZHSEQR + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!>    ZHSEQR computes the eigenvalues of a Hessenberg matrix H
!>    and, optionally, the matrices T and Z from the Schur decomposition
!>    H = Z T Z**H, where T is an upper triangular matrix (the
!>    Schur form), and Z is the unitary matrix of Schur vectors.
!>
!>    Optionally Z may be postmultiplied into an input unitary
!>    matrix Q so that this routine can give the Schur factorization
!>    of a matrix A which has been reduced to the Hessenberg form H
!>    by the unitary matrix Q:  A = Q*H*Q**H = (QZ)*T*(QZ)**H.
!>
Parameters
[in]JOB
!>          JOB is CHARACTER*1
!>           = 'E':  compute eigenvalues only;
!>           = 'S':  compute eigenvalues and the Schur form T.
!>
[in]COMPZ
!>          COMPZ is CHARACTER*1
!>           = 'N':  no Schur vectors are computed;
!>           = 'I':  Z is initialized to the unit matrix and the matrix Z
!>                   of Schur vectors of H is returned;
!>           = 'V':  Z must contain an unitary matrix Q on entry, and
!>                   the product Q*Z is returned.
!>
[in]N
!>          N is INTEGER
!>           The order of the matrix H.  N >= 0.
!>
[in]ILO
!>          ILO is INTEGER
!>
[in]IHI
!>          IHI is INTEGER
!>
!>           It is assumed that H is already upper triangular in rows
!>           and columns 1:ILO-1 and IHI+1:N. ILO and IHI are normally
!>           set by a previous call to ZGEBAL, and then passed to ZGEHRD
!>           when the matrix output by ZGEBAL is reduced to Hessenberg
!>           form. Otherwise ILO and IHI should be set to 1 and N
!>           respectively.  If N > 0, then 1 <= ILO <= IHI <= N.
!>           If N = 0, then ILO = 1 and IHI = 0.
!>
[in,out]H
!>          H is COMPLEX*16 array, dimension (LDH,N)
!>           On entry, the upper Hessenberg matrix H.
!>           On exit, if INFO = 0 and JOB = 'S', H contains the upper
!>           triangular matrix T from the Schur decomposition (the
!>           Schur form). If INFO = 0 and JOB = 'E', the contents of
!>           H are unspecified on exit.  (The output value of H when
!>           INFO > 0 is given under the description of INFO below.)
!>
!>           Unlike earlier versions of ZHSEQR, this subroutine may
!>           explicitly H(i,j) = 0 for i > j and j = 1, 2, ... ILO-1
!>           or j = IHI+1, IHI+2, ... N.
!>
[in]LDH
!>          LDH is INTEGER
!>           The leading dimension of the array H. LDH >= max(1,N).
!>
[out]W
!>          W is COMPLEX*16 array, dimension (N)
!>           The computed eigenvalues. If JOB = 'S', the eigenvalues are
!>           stored in the same order as on the diagonal of the Schur
!>           form returned in H, with W(i) = H(i,i).
!>
[in,out]Z
!>          Z is COMPLEX*16 array, dimension (LDZ,N)
!>           If COMPZ = 'N', Z is not referenced.
!>           If COMPZ = 'I', on entry Z need not be set and on exit,
!>           if INFO = 0, Z contains the unitary matrix Z of the Schur
!>           vectors of H.  If COMPZ = 'V', on entry Z must contain an
!>           N-by-N matrix Q, which is assumed to be equal to the unit
!>           matrix except for the submatrix Z(ILO:IHI,ILO:IHI). On exit,
!>           if INFO = 0, Z contains Q*Z.
!>           Normally Q is the unitary matrix generated by ZUNGHR
!>           after the call to ZGEHRD which formed the Hessenberg matrix
!>           H. (The output value of Z when INFO > 0 is given under
!>           the description of INFO below.)
!>
[in]LDZ
!>          LDZ is INTEGER
!>           The leading dimension of the array Z.  if COMPZ = 'I' or
!>           COMPZ = 'V', then LDZ >= MAX(1,N).  Otherwise, LDZ >= 1.
!>
[out]WORK
!>          WORK is COMPLEX*16 array, dimension (LWORK)
!>           On exit, if INFO = 0, WORK(1) returns an estimate of
!>           the optimal value for LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>           The dimension of the array WORK.  LWORK >= max(1,N)
!>           is sufficient and delivers very good and sometimes
!>           optimal performance.  However, LWORK as large as 11*N
!>           may be required for optimal performance.  A workspace
!>           query is recommended to determine the optimal workspace
!>           size.
!>
!>           If LWORK = -1, then ZHSEQR does a workspace query.
!>           In this case, ZHSEQR checks the input parameters and
!>           estimates the optimal workspace size for the given
!>           values of N, ILO and IHI.  The estimate is returned
!>           in WORK(1).  No error message related to LWORK is
!>           issued by XERBLA.  Neither H nor Z are accessed.
!>
[out]INFO
!>          INFO is INTEGER
!>             = 0:  successful exit
!>             < 0:  if INFO = -i, the i-th argument had an illegal
!>                    value
!>             > 0:  if INFO = i, ZHSEQR failed to compute all of
!>                the eigenvalues.  Elements 1:ilo-1 and i+1:n of W
!>                contain those eigenvalues which have been
!>                successfully computed.  (Failures are rare.)
!>
!>                If INFO > 0 and JOB = 'E', then on exit, the
!>                remaining unconverged eigenvalues are the eigen-
!>                values of the upper Hessenberg matrix rows and
!>                columns ILO through INFO of the final, output
!>                value of H.
!>
!>                If INFO > 0 and JOB   = 'S', then on exit
!>
!>           (*)  (initial value of H)*U  = U*(final value of H)
!>
!>                where U is a unitary matrix.  The final
!>                value of  H is upper Hessenberg and triangular in
!>                rows and columns INFO+1 through IHI.
!>
!>                If INFO > 0 and COMPZ = 'V', then on exit
!>
!>                  (final value of Z)  =  (initial value of Z)*U
!>
!>                where U is the unitary matrix in (*) (regard-
!>                less of the value of JOB.)
!>
!>                If INFO > 0 and COMPZ = 'I', then on exit
!>                      (final value of Z)  = U
!>                where U is the unitary matrix in (*) (regard-
!>                less of the value of JOB.)
!>
!>                If INFO > 0 and COMPZ = 'N', then Z is not
!>                accessed.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
Karen Braman and Ralph Byers, Department of Mathematics, University of Kansas, USA
Further Details:
!>
!>             Default values supplied by
!>             ILAENV(ISPEC,'ZHSEQR',JOB(:1)//COMPZ(:1),N,ILO,IHI,LWORK).
!>             It is suggested that these defaults be adjusted in order
!>             to attain best performance in each particular
!>             computational environment.
!>
!>            ISPEC=12: The ZLAHQR vs ZLAQR0 crossover point.
!>                      Default: 75. (Must be at least 11.)
!>
!>            ISPEC=13: Recommended deflation window size.
!>                      This depends on ILO, IHI and NS.  NS is the
!>                      number of simultaneous shifts returned
!>                      by ILAENV(ISPEC=15).  (See ISPEC=15 below.)
!>                      The default for (IHI-ILO+1) <= 500 is NS.
!>                      The default for (IHI-ILO+1) >  500 is 3*NS/2.
!>
!>            ISPEC=14: Nibble crossover point. (See IPARMQ for
!>                      details.)  Default: 14% of deflation window
!>                      size.
!>
!>            ISPEC=15: Number of simultaneous shifts in a multishift
!>                      QR iteration.
!>
!>                      If IHI-ILO+1 is ...
!>
!>                      greater than      ...but less    ... the
!>                      or equal to ...      than        default is
!>
!>                           1               30          NS =   2(+)
!>                          30               60          NS =   4(+)
!>                          60              150          NS =  10(+)
!>                         150              590          NS =  **
!>                         590             3000          NS =  64
!>                        3000             6000          NS = 128
!>                        6000             infinity      NS = 256
!>
!>                  (+)  By default some or all matrices of this order
!>                       are passed to the implicit double shift routine
!>                       ZLAHQR and this parameter is ignored.  See
!>                       ISPEC=12 above and comments in IPARMQ for
!>                       details.
!>
!>                 (**)  The asterisks (**) indicate an ad-hoc
!>                       function of N increasing from 10 to 64.
!>
!>            ISPEC=16: Select structured matrix multiply.
!>                      If the number of simultaneous shifts (specified
!>                      by ISPEC=15) is less than 14, then the default
!>                      for ISPEC=16 is 0.  Otherwise the default for
!>                      ISPEC=16 is 2.
!>
References:
  K. Braman, R. Byers and R. Mathias, The Multi-Shift QR
  Algorithm Part I: Maintaining Well Focused Shifts, and Level 3
  Performance, SIAM Journal of Matrix Analysis, volume 23, pages
  929--947, 2002.

K. Braman, R. Byers and R. Mathias, The Multi-Shift QR Algorithm Part II: Aggressive Early Deflation, SIAM Journal of Matrix Analysis, volume 23, pages 948–973, 2002.

Definition at line 295 of file zhseqr.f.

297*
298* -- LAPACK computational routine --
299* -- LAPACK is a software package provided by Univ. of Tennessee, --
300* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
301*
302* .. Scalar Arguments ..
303 INTEGER IHI, ILO, INFO, LDH, LDZ, LWORK, N
304 CHARACTER COMPZ, JOB
305* ..
306* .. Array Arguments ..
307 COMPLEX*16 H( LDH, * ), W( * ), WORK( * ), Z( LDZ, * )
308* ..
309*
310* =====================================================================
311*
312* .. Parameters ..
313*
314* ==== Matrices of order NTINY or smaller must be processed by
315* . ZLAHQR because of insufficient subdiagonal scratch space.
316* . (This is a hard limit.) ====
317 INTEGER NTINY
318 parameter( ntiny = 15 )
319*
320* ==== NL allocates some local workspace to help small matrices
321* . through a rare ZLAHQR failure. NL > NTINY = 15 is
322* . required and NL <= NMIN = ILAENV(ISPEC=12,...) is recom-
323* . mended. (The default value of NMIN is 75.) Using NL = 49
324* . allows up to six simultaneous shifts and a 16-by-16
325* . deflation window. ====
326 INTEGER NL
327 parameter( nl = 49 )
328 COMPLEX*16 ZERO, ONE
329 parameter( zero = ( 0.0d0, 0.0d0 ),
330 $ one = ( 1.0d0, 0.0d0 ) )
331 DOUBLE PRECISION RZERO
332 parameter( rzero = 0.0d0 )
333* ..
334* .. Local Arrays ..
335 COMPLEX*16 HL( NL, NL ), WORKL( NL )
336* ..
337* .. Local Scalars ..
338 INTEGER KBOT, NMIN
339 LOGICAL INITZ, LQUERY, WANTT, WANTZ
340* ..
341* .. External Functions ..
342 INTEGER ILAENV
343 LOGICAL LSAME
344 EXTERNAL ilaenv, lsame
345* ..
346* .. External Subroutines ..
347 EXTERNAL xerbla, zcopy, zlacpy, zlahqr, zlaqr0,
348 $ zlaset
349* ..
350* .. Intrinsic Functions ..
351 INTRINSIC dble, dcmplx, max, min
352* ..
353* .. Executable Statements ..
354*
355* ==== Decode and check the input parameters. ====
356*
357 wantt = lsame( job, 'S' )
358 initz = lsame( compz, 'I' )
359 wantz = initz .OR. lsame( compz, 'V' )
360 work( 1 ) = dcmplx( dble( max( 1, n ) ), rzero )
361 lquery = lwork.EQ.-1
362*
363 info = 0
364 IF( .NOT.lsame( job, 'E' ) .AND. .NOT.wantt ) THEN
365 info = -1
366 ELSE IF( .NOT.lsame( compz, 'N' ) .AND. .NOT.wantz ) THEN
367 info = -2
368 ELSE IF( n.LT.0 ) THEN
369 info = -3
370 ELSE IF( ilo.LT.1 .OR. ilo.GT.max( 1, n ) ) THEN
371 info = -4
372 ELSE IF( ihi.LT.min( ilo, n ) .OR. ihi.GT.n ) THEN
373 info = -5
374 ELSE IF( ldh.LT.max( 1, n ) ) THEN
375 info = -7
376 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.max( 1, n ) ) ) THEN
377 info = -10
378 ELSE IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
379 info = -12
380 END IF
381*
382 IF( info.NE.0 ) THEN
383*
384* ==== Quick return in case of invalid argument. ====
385*
386 CALL xerbla( 'ZHSEQR', -info )
387 RETURN
388*
389 ELSE IF( n.EQ.0 ) THEN
390*
391* ==== Quick return in case N = 0; nothing to do. ====
392*
393 RETURN
394*
395 ELSE IF( lquery ) THEN
396*
397* ==== Quick return in case of a workspace query ====
398*
399 CALL zlaqr0( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo, ihi,
400 $ z,
401 $ ldz, work, lwork, info )
402* ==== Ensure reported workspace size is backward-compatible with
403* . previous LAPACK versions. ====
404 work( 1 ) = dcmplx( max( dble( work( 1 ) ), dble( max( 1,
405 $ n ) ) ), rzero )
406 RETURN
407*
408 ELSE
409*
410* ==== copy eigenvalues isolated by ZGEBAL ====
411*
412 IF( ilo.GT.1 )
413 $ CALL zcopy( ilo-1, h, ldh+1, w, 1 )
414 IF( ihi.LT.n )
415 $ CALL zcopy( n-ihi, h( ihi+1, ihi+1 ), ldh+1, w( ihi+1 ),
416 $ 1 )
417*
418* ==== Initialize Z, if requested ====
419*
420 IF( initz )
421 $ CALL zlaset( 'A', n, n, zero, one, z, ldz )
422*
423* ==== Quick return if possible ====
424*
425 IF( ilo.EQ.ihi ) THEN
426 w( ilo ) = h( ilo, ilo )
427 RETURN
428 END IF
429*
430* ==== ZLAHQR/ZLAQR0 crossover point ====
431*
432 nmin = ilaenv( 12, 'ZHSEQR', job( : 1 ) // compz( : 1 ), n,
433 $ ilo, ihi, lwork )
434 nmin = max( ntiny, nmin )
435*
436* ==== ZLAQR0 for big matrices; ZLAHQR for small ones ====
437*
438 IF( n.GT.nmin ) THEN
439 CALL zlaqr0( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo,
440 $ ihi,
441 $ z, ldz, work, lwork, info )
442 ELSE
443*
444* ==== Small matrix ====
445*
446 CALL zlahqr( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo,
447 $ ihi,
448 $ z, ldz, info )
449*
450 IF( info.GT.0 ) THEN
451*
452* ==== A rare ZLAHQR failure! ZLAQR0 sometimes succeeds
453* . when ZLAHQR fails. ====
454*
455 kbot = info
456*
457 IF( n.GE.nl ) THEN
458*
459* ==== Larger matrices have enough subdiagonal scratch
460* . space to call ZLAQR0 directly. ====
461*
462 CALL zlaqr0( wantt, wantz, n, ilo, kbot, h, ldh, w,
463 $ ilo, ihi, z, ldz, work, lwork, info )
464*
465 ELSE
466*
467* ==== Tiny matrices don't have enough subdiagonal
468* . scratch space to benefit from ZLAQR0. Hence,
469* . tiny matrices must be copied into a larger
470* . array before calling ZLAQR0. ====
471*
472 CALL zlacpy( 'A', n, n, h, ldh, hl, nl )
473 hl( n+1, n ) = zero
474 CALL zlaset( 'A', nl, nl-n, zero, zero, hl( 1,
475 $ n+1 ),
476 $ nl )
477 CALL zlaqr0( wantt, wantz, nl, ilo, kbot, hl, nl,
478 $ w,
479 $ ilo, ihi, z, ldz, workl, nl, info )
480 IF( wantt .OR. info.NE.0 )
481 $ CALL zlacpy( 'A', n, n, hl, nl, h, ldh )
482 END IF
483 END IF
484 END IF
485*
486* ==== Clear out the trash, if necessary. ====
487*
488 IF( ( wantt .OR. info.NE.0 ) .AND. n.GT.2 )
489 $ CALL zlaset( 'L', n-2, n-2, zero, zero, h( 3, 1 ), ldh )
490*
491* ==== Ensure reported workspace size is backward-compatible with
492* . previous LAPACK versions. ====
493*
494 work( 1 ) = dcmplx( max( dble( max( 1, n ) ),
495 $ dble( work( 1 ) ) ), rzero )
496 END IF
497*
498* ==== End of ZHSEQR ====
499*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zcopy
subroutine zcopy(n, zx, incx, zy, incy)
ZCOPY
Definition zcopy.f:81
ilaenv
integer function ilaenv(ispec, name, opts, n1, n2, n3, n4)
ILAENV
Definition ilaenv.f:160
zlacpy
subroutine zlacpy(uplo, m, n, a, lda, b, ldb)
ZLACPY copies all or part of one two-dimensional array to another.
Definition zlacpy.f:101
zlahqr
subroutine zlahqr(wantt, wantz, n, ilo, ihi, h, ldh, w, iloz, ihiz, z, ldz, info)
ZLAHQR computes the eigenvalues and Schur factorization of an upper Hessenberg matrix,...
Definition zlahqr.f:193
zlaqr0
subroutine zlaqr0(wantt, wantz, n, ilo, ihi, h, ldh, w, iloz, ihiz, z, ldz, work, lwork, info)
ZLAQR0 computes the eigenvalues of a Hessenberg matrix, and optionally the matrices from the Schur de...
Definition zlaqr0.f:239
zlaset
subroutine zlaset(uplo, m, n, alpha, beta, a, lda)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition zlaset.f:104
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: