zchkbk()

subroutine zchkbk	(	integer	nin,
		integer	nout
	)

ZCHKBK

Purpose:

 ZCHKBK tests ZGEBAK, a routine for backward transformation of
 the computed right or left eigenvectors if the original matrix
 was preprocessed by balance subroutine ZGEBAL.

Parameters

[in]	NIN	NIN is INTEGER The logical unit number for input. NIN > 0.
[in]	NOUT	NOUT is INTEGER The logical unit number for output. NOUT > 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 54 of file zchkbk.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NIN, NOUT
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      INTEGER            LDE
      parameter( lde = 20 )
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IHI, ILO, INFO, J, KNT, N, NINFO
      DOUBLE PRECISION   EPS, RMAX, SAFMIN, VMAX, X
      COMPLEX*16         CDUM
*     ..
*     .. Local Arrays ..
      INTEGER            LMAX( 2 )
      DOUBLE PRECISION   SCALE( LDE )
      COMPLEX*16         E( LDE, LDE ), EIN( LDE, LDE )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgebak
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( dble( cdum ) ) + abs( dimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
      eps = dlamch( 'E' )
      safmin = dlamch( 'S' )
*
   10 CONTINUE
*
      READ( nin, fmt = * )n, ilo, ihi
      IF( n.EQ.0 )
     $   GO TO 60
*
      READ( nin, fmt = * )( scale( i ), i = 1, n )
      DO 20 i = 1, n
         READ( nin, fmt = * )( e( i, j ), j = 1, n )
   20 CONTINUE
*
      DO 30 i = 1, n
         READ( nin, fmt = * )( ein( i, j ), j = 1, n )
   30 CONTINUE
*
      knt = knt + 1
      CALL zgebak( 'B', 'R', n, ilo, ihi, scale, n, e, lde, info )
*
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      vmax = zero
      DO 50 i = 1, n
         DO 40 j = 1, n
            x = cabs1( e( i, j )-ein( i, j ) ) / eps
            IF( cabs1( e( i, j ) ).GT.safmin )
     $         x = x / cabs1( e( i, j ) )
            vmax = max( vmax, x )
   40    CONTINUE
   50 CONTINUE
*
      IF( vmax.GT.rmax ) THEN
         lmax( 2 ) = knt
         rmax = vmax
      END IF
*
      GO TO 10
*
   60 CONTINUE
*
      WRITE( nout, fmt = 9999 )
 9999 FORMAT( 1x, '.. test output of ZGEBAK .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 FORMAT( 1x, 'value of largest test error             = ', d12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 FORMAT( 1x, 'example number where info is not zero   = ', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 FORMAT( 1x, 'example number having largest error     = ', i4 )
      WRITE( nout, fmt = 9995 )ninfo
 9995 FORMAT( 1x, 'number of examples where info is not 0  = ', i4 )
      WRITE( nout, fmt = 9994 )knt
 9994 FORMAT( 1x, 'total number of examples tested         = ', i4 )
*
      RETURN
*
*     End of ZCHKBK
*

Here is the call graph for this function:

Here is the caller graph for this function: