LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
ztrmm.f
Go to the documentation of this file.
1*> \brief \b ZTRMM
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE ZTRMM(SIDE,UPLO,TRANSA,DIAG,M,N,ALPHA,A,LDA,B,LDB)
12*
13* .. Scalar Arguments ..
14* COMPLEX*16 ALPHA
15* INTEGER LDA,LDB,M,N
16* CHARACTER DIAG,SIDE,TRANSA,UPLO
17* ..
18* .. Array Arguments ..
19* COMPLEX*16 A(LDA,*),B(LDB,*)
20* ..
21*
22*
23*> \par Purpose:
24* =============
25*>
26*> \verbatim
27*>
28*> ZTRMM performs one of the matrix-matrix operations
29*>
30*> B := alpha*op( A )*B, or B := alpha*B*op( A )
31*>
32*> where alpha is a scalar, B is an m by n matrix, A is a unit, or
33*> non-unit, upper or lower triangular matrix and op( A ) is one of
34*>
35*> op( A ) = A or op( A ) = A**T or op( A ) = A**H.
36*> \endverbatim
37*
38* Arguments:
39* ==========
40*
41*> \param[in] SIDE
42*> \verbatim
43*> SIDE is CHARACTER*1
44*> On entry, SIDE specifies whether op( A ) multiplies B from
45*> the left or right as follows:
46*>
47*> SIDE = 'L' or 'l' B := alpha*op( A )*B.
48*>
49*> SIDE = 'R' or 'r' B := alpha*B*op( A ).
50*> \endverbatim
51*>
52*> \param[in] UPLO
53*> \verbatim
54*> UPLO is CHARACTER*1
55*> On entry, UPLO specifies whether the matrix A is an upper or
56*> lower triangular matrix as follows:
57*>
58*> UPLO = 'U' or 'u' A is an upper triangular matrix.
59*>
60*> UPLO = 'L' or 'l' A is a lower triangular matrix.
61*> \endverbatim
62*>
63*> \param[in] TRANSA
64*> \verbatim
65*> TRANSA is CHARACTER*1
66*> On entry, TRANSA specifies the form of op( A ) to be used in
67*> the matrix multiplication as follows:
68*>
69*> TRANSA = 'N' or 'n' op( A ) = A.
70*>
71*> TRANSA = 'T' or 't' op( A ) = A**T.
72*>
73*> TRANSA = 'C' or 'c' op( A ) = A**H.
74*> \endverbatim
75*>
76*> \param[in] DIAG
77*> \verbatim
78*> DIAG is CHARACTER*1
79*> On entry, DIAG specifies whether or not A is unit triangular
80*> as follows:
81*>
82*> DIAG = 'U' or 'u' A is assumed to be unit triangular.
83*>
84*> DIAG = 'N' or 'n' A is not assumed to be unit
85*> triangular.
86*> \endverbatim
87*>
88*> \param[in] M
89*> \verbatim
90*> M is INTEGER
91*> On entry, M specifies the number of rows of B. M must be at
92*> least zero.
93*> \endverbatim
94*>
95*> \param[in] N
96*> \verbatim
97*> N is INTEGER
98*> On entry, N specifies the number of columns of B. N must be
99*> at least zero.
100*> \endverbatim
101*>
102*> \param[in] ALPHA
103*> \verbatim
104*> ALPHA is COMPLEX*16
105*> On entry, ALPHA specifies the scalar alpha. When alpha is
106*> zero then A is not referenced and B need not be set before
107*> entry.
108*> \endverbatim
109*>
110*> \param[in] A
111*> \verbatim
112*> A is COMPLEX*16 array, dimension ( LDA, k ), where k is m
113*> when SIDE = 'L' or 'l' and is n when SIDE = 'R' or 'r'.
114*> Before entry with UPLO = 'U' or 'u', the leading k by k
115*> upper triangular part of the array A must contain the upper
116*> triangular matrix and the strictly lower triangular part of
117*> A is not referenced.
118*> Before entry with UPLO = 'L' or 'l', the leading k by k
119*> lower triangular part of the array A must contain the lower
120*> triangular matrix and the strictly upper triangular part of
121*> A is not referenced.
122*> Note that when DIAG = 'U' or 'u', the diagonal elements of
123*> A are not referenced either, but are assumed to be unity.
124*> \endverbatim
125*>
126*> \param[in] LDA
127*> \verbatim
128*> LDA is INTEGER
129*> On entry, LDA specifies the first dimension of A as declared
130*> in the calling (sub) program. When SIDE = 'L' or 'l' then
131*> LDA must be at least max( 1, m ), when SIDE = 'R' or 'r'
132*> then LDA must be at least max( 1, n ).
133*> \endverbatim
134*>
135*> \param[in,out] B
136*> \verbatim
137*> B is COMPLEX*16 array, dimension ( LDB, N ).
138*> Before entry, the leading m by n part of the array B must
139*> contain the matrix B, and on exit is overwritten by the
140*> transformed matrix.
141*> \endverbatim
142*>
143*> \param[in] LDB
144*> \verbatim
145*> LDB is INTEGER
146*> On entry, LDB specifies the first dimension of B as declared
147*> in the calling (sub) program. LDB must be at least
148*> max( 1, m ).
149*> \endverbatim
150*
151* Authors:
152* ========
153*
154*> \author Univ. of Tennessee
155*> \author Univ. of California Berkeley
156*> \author Univ. of Colorado Denver
157*> \author NAG Ltd.
158*
159*> \ingroup complex16_blas_level3
160*
161*> \par Further Details:
162* =====================
163*>
164*> \verbatim
165*>
166*> Level 3 Blas routine.
167*>
168*> -- Written on 8-February-1989.
169*> Jack Dongarra, Argonne National Laboratory.
170*> Iain Duff, AERE Harwell.
171*> Jeremy Du Croz, Numerical Algorithms Group Ltd.
172*> Sven Hammarling, Numerical Algorithms Group Ltd.
173*> \endverbatim
174*>
175* =====================================================================
176 SUBROUTINE ztrmm(SIDE,UPLO,TRANSA,DIAG,M,N,ALPHA,A,LDA,B,LDB)
177*
178* -- Reference BLAS level3 routine --
179* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
180* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
181*
182* .. Scalar Arguments ..
183 COMPLEX*16 ALPHA
184 INTEGER LDA,LDB,M,N
185 CHARACTER DIAG,SIDE,TRANSA,UPLO
186* ..
187* .. Array Arguments ..
188 COMPLEX*16 A(LDA,*),B(LDB,*)
189* ..
190*
191* =====================================================================
192*
193* .. External Functions ..
194 LOGICAL LSAME
195 EXTERNAL lsame
196* ..
197* .. External Subroutines ..
198 EXTERNAL xerbla
199* ..
200* .. Intrinsic Functions ..
201 INTRINSIC dconjg,max
202* ..
203* .. Local Scalars ..
204 COMPLEX*16 TEMP
205 INTEGER I,INFO,J,K,NROWA
206 LOGICAL LSIDE,NOCONJ,NOUNIT,UPPER
207* ..
208* .. Parameters ..
209 COMPLEX*16 ONE
210 parameter(one= (1.0d+0,0.0d+0))
211 COMPLEX*16 ZERO
212 parameter(zero= (0.0d+0,0.0d+0))
213* ..
214*
215* Test the input parameters.
216*
217 lside = lsame(side,'L')
218 IF (lside) THEN
219 nrowa = m
220 ELSE
221 nrowa = n
222 END IF
223 noconj = lsame(transa,'T')
224 nounit = lsame(diag,'N')
225 upper = lsame(uplo,'U')
226*
227 info = 0
228 IF ((.NOT.lside) .AND. (.NOT.lsame(side,'R'))) THEN
229 info = 1
230 ELSE IF ((.NOT.upper) .AND. (.NOT.lsame(uplo,'L'))) THEN
231 info = 2
232 ELSE IF ((.NOT.lsame(transa,'N')) .AND.
233 + (.NOT.lsame(transa,'T')) .AND.
234 + (.NOT.lsame(transa,'C'))) THEN
235 info = 3
236 ELSE IF ((.NOT.lsame(diag,'U')) .AND. (.NOT.lsame(diag,'N'))) THEN
237 info = 4
238 ELSE IF (m.LT.0) THEN
239 info = 5
240 ELSE IF (n.LT.0) THEN
241 info = 6
242 ELSE IF (lda.LT.max(1,nrowa)) THEN
243 info = 9
244 ELSE IF (ldb.LT.max(1,m)) THEN
245 info = 11
246 END IF
247 IF (info.NE.0) THEN
248 CALL xerbla('ZTRMM ',info)
249 RETURN
250 END IF
251*
252* Quick return if possible.
253*
254 IF (m.EQ.0 .OR. n.EQ.0) RETURN
255*
256* And when alpha.eq.zero.
257*
258 IF (alpha.EQ.zero) THEN
259 DO 20 j = 1,n
260 DO 10 i = 1,m
261 b(i,j) = zero
262 10 CONTINUE
263 20 CONTINUE
264 RETURN
265 END IF
266*
267* Start the operations.
268*
269 IF (lside) THEN
270 IF (lsame(transa,'N')) THEN
271*
272* Form B := alpha*A*B.
273*
274 IF (upper) THEN
275 DO 50 j = 1,n
276 DO 40 k = 1,m
277 IF (b(k,j).NE.zero) THEN
278 temp = alpha*b(k,j)
279 DO 30 i = 1,k - 1
280 b(i,j) = b(i,j) + temp*a(i,k)
281 30 CONTINUE
282 IF (nounit) temp = temp*a(k,k)
283 b(k,j) = temp
284 END IF
285 40 CONTINUE
286 50 CONTINUE
287 ELSE
288 DO 80 j = 1,n
289 DO 70 k = m,1,-1
290 IF (b(k,j).NE.zero) THEN
291 temp = alpha*b(k,j)
292 b(k,j) = temp
293 IF (nounit) b(k,j) = b(k,j)*a(k,k)
294 DO 60 i = k + 1,m
295 b(i,j) = b(i,j) + temp*a(i,k)
296 60 CONTINUE
297 END IF
298 70 CONTINUE
299 80 CONTINUE
300 END IF
301 ELSE
302*
303* Form B := alpha*A**T*B or B := alpha*A**H*B.
304*
305 IF (upper) THEN
306 DO 120 j = 1,n
307 DO 110 i = m,1,-1
308 temp = b(i,j)
309 IF (noconj) THEN
310 IF (nounit) temp = temp*a(i,i)
311 DO 90 k = 1,i - 1
312 temp = temp + a(k,i)*b(k,j)
313 90 CONTINUE
314 ELSE
315 IF (nounit) temp = temp*dconjg(a(i,i))
316 DO 100 k = 1,i - 1
317 temp = temp + dconjg(a(k,i))*b(k,j)
318 100 CONTINUE
319 END IF
320 b(i,j) = alpha*temp
321 110 CONTINUE
322 120 CONTINUE
323 ELSE
324 DO 160 j = 1,n
325 DO 150 i = 1,m
326 temp = b(i,j)
327 IF (noconj) THEN
328 IF (nounit) temp = temp*a(i,i)
329 DO 130 k = i + 1,m
330 temp = temp + a(k,i)*b(k,j)
331 130 CONTINUE
332 ELSE
333 IF (nounit) temp = temp*dconjg(a(i,i))
334 DO 140 k = i + 1,m
335 temp = temp + dconjg(a(k,i))*b(k,j)
336 140 CONTINUE
337 END IF
338 b(i,j) = alpha*temp
339 150 CONTINUE
340 160 CONTINUE
341 END IF
342 END IF
343 ELSE
344 IF (lsame(transa,'N')) THEN
345*
346* Form B := alpha*B*A.
347*
348 IF (upper) THEN
349 DO 200 j = n,1,-1
350 temp = alpha
351 IF (nounit) temp = temp*a(j,j)
352 DO 170 i = 1,m
353 b(i,j) = temp*b(i,j)
354 170 CONTINUE
355 DO 190 k = 1,j - 1
356 IF (a(k,j).NE.zero) THEN
357 temp = alpha*a(k,j)
358 DO 180 i = 1,m
359 b(i,j) = b(i,j) + temp*b(i,k)
360 180 CONTINUE
361 END IF
362 190 CONTINUE
363 200 CONTINUE
364 ELSE
365 DO 240 j = 1,n
366 temp = alpha
367 IF (nounit) temp = temp*a(j,j)
368 DO 210 i = 1,m
369 b(i,j) = temp*b(i,j)
370 210 CONTINUE
371 DO 230 k = j + 1,n
372 IF (a(k,j).NE.zero) THEN
373 temp = alpha*a(k,j)
374 DO 220 i = 1,m
375 b(i,j) = b(i,j) + temp*b(i,k)
376 220 CONTINUE
377 END IF
378 230 CONTINUE
379 240 CONTINUE
380 END IF
381 ELSE
382*
383* Form B := alpha*B*A**T or B := alpha*B*A**H.
384*
385 IF (upper) THEN
386 DO 280 k = 1,n
387 DO 260 j = 1,k - 1
388 IF (a(j,k).NE.zero) THEN
389 IF (noconj) THEN
390 temp = alpha*a(j,k)
391 ELSE
392 temp = alpha*dconjg(a(j,k))
393 END IF
394 DO 250 i = 1,m
395 b(i,j) = b(i,j) + temp*b(i,k)
396 250 CONTINUE
397 END IF
398 260 CONTINUE
399 temp = alpha
400 IF (nounit) THEN
401 IF (noconj) THEN
402 temp = temp*a(k,k)
403 ELSE
404 temp = temp*dconjg(a(k,k))
405 END IF
406 END IF
407 IF (temp.NE.one) THEN
408 DO 270 i = 1,m
409 b(i,k) = temp*b(i,k)
410 270 CONTINUE
411 END IF
412 280 CONTINUE
413 ELSE
414 DO 320 k = n,1,-1
415 DO 300 j = k + 1,n
416 IF (a(j,k).NE.zero) THEN
417 IF (noconj) THEN
418 temp = alpha*a(j,k)
419 ELSE
420 temp = alpha*dconjg(a(j,k))
421 END IF
422 DO 290 i = 1,m
423 b(i,j) = b(i,j) + temp*b(i,k)
424 290 CONTINUE
425 END IF
426 300 CONTINUE
427 temp = alpha
428 IF (nounit) THEN
429 IF (noconj) THEN
430 temp = temp*a(k,k)
431 ELSE
432 temp = temp*dconjg(a(k,k))
433 END IF
434 END IF
435 IF (temp.NE.one) THEN
436 DO 310 i = 1,m
437 b(i,k) = temp*b(i,k)
438 310 CONTINUE
439 END IF
440 320 CONTINUE
441 END IF
442 END IF
443 END IF
444*
445 RETURN
446*
447* End of ZTRMM
448*
449 END
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
ztrmm
subroutine ztrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRMM
Definition: ztrmm.f:177