 LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ sgecon()

 subroutine sgecon ( character NORM, integer N, real, dimension( lda, * ) A, integer LDA, real ANORM, real RCOND, real, dimension( * ) WORK, integer, dimension( * ) IWORK, integer INFO )

SGECON

Purpose:
``` SGECON estimates the reciprocal of the condition number of a general
real matrix A, in either the 1-norm or the infinity-norm, using
the LU factorization computed by SGETRF.

An estimate is obtained for norm(inv(A)), and the reciprocal of the
condition number is computed as
RCOND = 1 / ( norm(A) * norm(inv(A)) ).```
Parameters
 [in] NORM ``` NORM is CHARACTER*1 Specifies whether the 1-norm condition number or the infinity-norm condition number is required: = '1' or 'O': 1-norm; = 'I': Infinity-norm.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in] A ``` A is REAL array, dimension (LDA,N) The factors L and U from the factorization A = P*L*U as computed by SGETRF.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [in] ANORM ``` ANORM is REAL If NORM = '1' or 'O', the 1-norm of the original matrix A. If NORM = 'I', the infinity-norm of the original matrix A.``` [out] RCOND ``` RCOND is REAL The reciprocal of the condition number of the matrix A, computed as RCOND = 1/(norm(A) * norm(inv(A))).``` [out] WORK ` WORK is REAL array, dimension (4*N)` [out] IWORK ` IWORK is INTEGER array, dimension (N)` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value```

Definition at line 122 of file sgecon.f.

124*
125* -- LAPACK computational routine --
126* -- LAPACK is a software package provided by Univ. of Tennessee, --
127* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128*
129* .. Scalar Arguments ..
130 CHARACTER NORM
131 INTEGER INFO, LDA, N
132 REAL ANORM, RCOND
133* ..
134* .. Array Arguments ..
135 INTEGER IWORK( * )
136 REAL A( LDA, * ), WORK( * )
137* ..
138*
139* =====================================================================
140*
141* .. Parameters ..
142 REAL ONE, ZERO
143 parameter( one = 1.0e+0, zero = 0.0e+0 )
144* ..
145* .. Local Scalars ..
146 LOGICAL ONENRM
147 CHARACTER NORMIN
148 INTEGER IX, KASE, KASE1
149 REAL AINVNM, SCALE, SL, SMLNUM, SU
150* ..
151* .. Local Arrays ..
152 INTEGER ISAVE( 3 )
153* ..
154* .. External Functions ..
155 LOGICAL LSAME
156 INTEGER ISAMAX
157 REAL SLAMCH
158 EXTERNAL lsame, isamax, slamch
159* ..
160* .. External Subroutines ..
161 EXTERNAL slacn2, slatrs, srscl, xerbla
162* ..
163* .. Intrinsic Functions ..
164 INTRINSIC abs, max
165* ..
166* .. Executable Statements ..
167*
168* Test the input parameters.
169*
170 info = 0
171 onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
172 IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
173 info = -1
174 ELSE IF( n.LT.0 ) THEN
175 info = -2
176 ELSE IF( lda.LT.max( 1, n ) ) THEN
177 info = -4
178 ELSE IF( anorm.LT.zero ) THEN
179 info = -5
180 END IF
181 IF( info.NE.0 ) THEN
182 CALL xerbla( 'SGECON', -info )
183 RETURN
184 END IF
185*
186* Quick return if possible
187*
188 rcond = zero
189 IF( n.EQ.0 ) THEN
190 rcond = one
191 RETURN
192 ELSE IF( anorm.EQ.zero ) THEN
193 RETURN
194 END IF
195*
196 smlnum = slamch( 'Safe minimum' )
197*
198* Estimate the norm of inv(A).
199*
200 ainvnm = zero
201 normin = 'N'
202 IF( onenrm ) THEN
203 kase1 = 1
204 ELSE
205 kase1 = 2
206 END IF
207 kase = 0
208 10 CONTINUE
209 CALL slacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
210 IF( kase.NE.0 ) THEN
211 IF( kase.EQ.kase1 ) THEN
212*
213* Multiply by inv(L).
214*
215 CALL slatrs( 'Lower', 'No transpose', 'Unit', normin, n, a,
216 \$ lda, work, sl, work( 2*n+1 ), info )
217*
218* Multiply by inv(U).
219*
220 CALL slatrs( 'Upper', 'No transpose', 'Non-unit', normin, n,
221 \$ a, lda, work, su, work( 3*n+1 ), info )
222 ELSE
223*
224* Multiply by inv(U**T).
225*
226 CALL slatrs( 'Upper', 'Transpose', 'Non-unit', normin, n, a,
227 \$ lda, work, su, work( 3*n+1 ), info )
228*
229* Multiply by inv(L**T).
230*
231 CALL slatrs( 'Lower', 'Transpose', 'Unit', normin, n, a,
232 \$ lda, work, sl, work( 2*n+1 ), info )
233 END IF
234*
235* Divide X by 1/(SL*SU) if doing so will not cause overflow.
236*
237 scale = sl*su
238 normin = 'Y'
239 IF( scale.NE.one ) THEN
240 ix = isamax( n, work, 1 )
241 IF( scale.LT.abs( work( ix ) )*smlnum .OR. scale.EQ.zero )
242 \$ GO TO 20
243 CALL srscl( n, scale, work, 1 )
244 END IF
245 GO TO 10
246 END IF
247*
248* Compute the estimate of the reciprocal condition number.
249*
250 IF( ainvnm.NE.zero )
251 \$ rcond = ( one / ainvnm ) / anorm
252*
253 20 CONTINUE
254 RETURN
255*
256* End of SGECON
257*
integer function isamax(N, SX, INCX)
ISAMAX
Definition: isamax.f:71
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine slatrs(UPLO, TRANS, DIAG, NORMIN, N, A, LDA, X, SCALE, CNORM, INFO)
SLATRS solves a triangular system of equations with the scale factor set to prevent overflow.
Definition: slatrs.f:238
subroutine slacn2(N, V, X, ISGN, EST, KASE, ISAVE)
SLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: slacn2.f:136
subroutine srscl(N, SA, SX, INCX)
SRSCL multiplies a vector by the reciprocal of a real scalar.
Definition: srscl.f:84
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: