LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ sgebd2()

subroutine sgebd2 ( integer  M,
integer  N,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  D,
real, dimension( * )  E,
real, dimension( * )  TAUQ,
real, dimension( * )  TAUP,
real, dimension( * )  WORK,
integer  INFO 
)

SGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.

Download SGEBD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGEBD2 reduces a real general m by n matrix A to upper or lower
 bidiagonal form B by an orthogonal transformation: Q**T * A * P = B.

 If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
Parameters
[in]M
          M is INTEGER
          The number of rows in the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns in the matrix A.  N >= 0.
[in,out]A
          A is REAL array, dimension (LDA,N)
          On entry, the m by n general matrix to be reduced.
          On exit,
          if m >= n, the diagonal and the first superdiagonal are
            overwritten with the upper bidiagonal matrix B; the
            elements below the diagonal, with the array TAUQ, represent
            the orthogonal matrix Q as a product of elementary
            reflectors, and the elements above the first superdiagonal,
            with the array TAUP, represent the orthogonal matrix P as
            a product of elementary reflectors;
          if m < n, the diagonal and the first subdiagonal are
            overwritten with the lower bidiagonal matrix B; the
            elements below the first subdiagonal, with the array TAUQ,
            represent the orthogonal matrix Q as a product of
            elementary reflectors, and the elements above the diagonal,
            with the array TAUP, represent the orthogonal matrix P as
            a product of elementary reflectors.
          See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]D
          D is REAL array, dimension (min(M,N))
          The diagonal elements of the bidiagonal matrix B:
          D(i) = A(i,i).
[out]E
          E is REAL array, dimension (min(M,N)-1)
          The off-diagonal elements of the bidiagonal matrix B:
          if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
          if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
[out]TAUQ
          TAUQ is REAL array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix Q. See Further Details.
[out]TAUP
          TAUP is REAL array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix P. See Further Details.
[out]WORK
          WORK is REAL array, dimension (max(M,N))
[out]INFO
          INFO is INTEGER
          = 0: successful exit.
          < 0: if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The matrices Q and P are represented as products of elementary
  reflectors:

  If m >= n,

     Q = H(1) H(2) . . . H(n)  and  P = G(1) G(2) . . . G(n-1)

  Each H(i) and G(i) has the form:

     H(i) = I - tauq * v * v**T  and G(i) = I - taup * u * u**T

  where tauq and taup are real scalars, and v and u are real vectors;
  v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in A(i+1:m,i);
  u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in A(i,i+2:n);
  tauq is stored in TAUQ(i) and taup in TAUP(i).

  If m < n,

     Q = H(1) H(2) . . . H(m-1)  and  P = G(1) G(2) . . . G(m)

  Each H(i) and G(i) has the form:

     H(i) = I - tauq * v * v**T  and G(i) = I - taup * u * u**T

  where tauq and taup are real scalars, and v and u are real vectors;
  v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
  u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
  tauq is stored in TAUQ(i) and taup in TAUP(i).

  The contents of A on exit are illustrated by the following examples:

  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):

    (  d   e   u1  u1  u1 )           (  d   u1  u1  u1  u1  u1 )
    (  v1  d   e   u2  u2 )           (  e   d   u2  u2  u2  u2 )
    (  v1  v2  d   e   u3 )           (  v1  e   d   u3  u3  u3 )
    (  v1  v2  v3  d   e  )           (  v1  v2  e   d   u4  u4 )
    (  v1  v2  v3  v4  d  )           (  v1  v2  v3  e   d   u5 )
    (  v1  v2  v3  v4  v5 )

  where d and e denote diagonal and off-diagonal elements of B, vi
  denotes an element of the vector defining H(i), and ui an element of
  the vector defining G(i).

Definition at line 188 of file sgebd2.f.

189*
190* -- LAPACK computational routine --
191* -- LAPACK is a software package provided by Univ. of Tennessee, --
192* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
193*
194* .. Scalar Arguments ..
195 INTEGER INFO, LDA, M, N
196* ..
197* .. Array Arguments ..
198 REAL A( LDA, * ), D( * ), E( * ), TAUP( * ),
199 $ TAUQ( * ), WORK( * )
200* ..
201*
202* =====================================================================
203*
204* .. Parameters ..
205 REAL ZERO, ONE
206 parameter( zero = 0.0e+0, one = 1.0e+0 )
207* ..
208* .. Local Scalars ..
209 INTEGER I
210* ..
211* .. External Subroutines ..
212 EXTERNAL slarf, slarfg, xerbla
213* ..
214* .. Intrinsic Functions ..
215 INTRINSIC max, min
216* ..
217* .. Executable Statements ..
218*
219* Test the input parameters
220*
221 info = 0
222 IF( m.LT.0 ) THEN
223 info = -1
224 ELSE IF( n.LT.0 ) THEN
225 info = -2
226 ELSE IF( lda.LT.max( 1, m ) ) THEN
227 info = -4
228 END IF
229 IF( info.LT.0 ) THEN
230 CALL xerbla( 'SGEBD2', -info )
231 RETURN
232 END IF
233*
234 IF( m.GE.n ) THEN
235*
236* Reduce to upper bidiagonal form
237*
238 DO 10 i = 1, n
239*
240* Generate elementary reflector H(i) to annihilate A(i+1:m,i)
241*
242 CALL slarfg( m-i+1, a( i, i ), a( min( i+1, m ), i ), 1,
243 $ tauq( i ) )
244 d( i ) = a( i, i )
245 a( i, i ) = one
246*
247* Apply H(i) to A(i:m,i+1:n) from the left
248*
249 IF( i.LT.n )
250 $ CALL slarf( 'Left', m-i+1, n-i, a( i, i ), 1, tauq( i ),
251 $ a( i, i+1 ), lda, work )
252 a( i, i ) = d( i )
253*
254 IF( i.LT.n ) THEN
255*
256* Generate elementary reflector G(i) to annihilate
257* A(i,i+2:n)
258*
259 CALL slarfg( n-i, a( i, i+1 ), a( i, min( i+2, n ) ),
260 $ lda, taup( i ) )
261 e( i ) = a( i, i+1 )
262 a( i, i+1 ) = one
263*
264* Apply G(i) to A(i+1:m,i+1:n) from the right
265*
266 CALL slarf( 'Right', m-i, n-i, a( i, i+1 ), lda,
267 $ taup( i ), a( i+1, i+1 ), lda, work )
268 a( i, i+1 ) = e( i )
269 ELSE
270 taup( i ) = zero
271 END IF
272 10 CONTINUE
273 ELSE
274*
275* Reduce to lower bidiagonal form
276*
277 DO 20 i = 1, m
278*
279* Generate elementary reflector G(i) to annihilate A(i,i+1:n)
280*
281 CALL slarfg( n-i+1, a( i, i ), a( i, min( i+1, n ) ), lda,
282 $ taup( i ) )
283 d( i ) = a( i, i )
284 a( i, i ) = one
285*
286* Apply G(i) to A(i+1:m,i:n) from the right
287*
288 IF( i.LT.m )
289 $ CALL slarf( 'Right', m-i, n-i+1, a( i, i ), lda,
290 $ taup( i ), a( i+1, i ), lda, work )
291 a( i, i ) = d( i )
292*
293 IF( i.LT.m ) THEN
294*
295* Generate elementary reflector H(i) to annihilate
296* A(i+2:m,i)
297*
298 CALL slarfg( m-i, a( i+1, i ), a( min( i+2, m ), i ), 1,
299 $ tauq( i ) )
300 e( i ) = a( i+1, i )
301 a( i+1, i ) = one
302*
303* Apply H(i) to A(i+1:m,i+1:n) from the left
304*
305 CALL slarf( 'Left', m-i, n-i, a( i+1, i ), 1, tauq( i ),
306 $ a( i+1, i+1 ), lda, work )
307 a( i+1, i ) = e( i )
308 ELSE
309 tauq( i ) = zero
310 END IF
311 20 CONTINUE
312 END IF
313 RETURN
314*
315* End of SGEBD2
316*
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slarfg(N, ALPHA, X, INCX, TAU)
SLARFG generates an elementary reflector (Householder matrix).
Definition: slarfg.f:106
subroutine slarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition: slarf.f:124
Here is the call graph for this function:
Here is the caller graph for this function: