 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ dlanhs()

 double precision function dlanhs ( character NORM, integer N, double precision, dimension( lda, * ) A, integer LDA, double precision, dimension( * ) WORK )

DLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.

Purpose:
``` DLANHS  returns the value of the one norm,  or the Frobenius norm, or
the  infinity norm,  or the  element of  largest absolute value  of a
Hessenberg matrix A.```
Returns
DLANHS
```    DLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
(
( norm1(A),         NORM = '1', 'O' or 'o'
(
( normI(A),         NORM = 'I' or 'i'
(
( normF(A),         NORM = 'F', 'f', 'E' or 'e'

where  norm1  denotes the  one norm of a matrix (maximum column sum),
normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
normF  denotes the  Frobenius norm of a matrix (square root of sum of
squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.```
Parameters
 [in] NORM ``` NORM is CHARACTER*1 Specifies the value to be returned in DLANHS as described above.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0. When N = 0, DLANHS is set to zero.``` [in] A ``` A is DOUBLE PRECISION array, dimension (LDA,N) The n by n upper Hessenberg matrix A; the part of A below the first sub-diagonal is not referenced.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(N,1).``` [out] WORK ``` WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)), where LWORK >= N when NORM = 'I'; otherwise, WORK is not referenced.```

Definition at line 107 of file dlanhs.f.

108 *
109 * -- LAPACK auxiliary routine --
110 * -- LAPACK is a software package provided by Univ. of Tennessee, --
111 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
112 *
113 * .. Scalar Arguments ..
114  CHARACTER NORM
115  INTEGER LDA, N
116 * ..
117 * .. Array Arguments ..
118  DOUBLE PRECISION A( LDA, * ), WORK( * )
119 * ..
120 *
121 * =====================================================================
122 *
123 * .. Parameters ..
124  DOUBLE PRECISION ONE, ZERO
125  parameter( one = 1.0d+0, zero = 0.0d+0 )
126 * ..
127 * .. Local Scalars ..
128  INTEGER I, J
129  DOUBLE PRECISION SCALE, SUM, VALUE
130 * ..
131 * .. External Subroutines ..
132  EXTERNAL dlassq
133 * ..
134 * .. External Functions ..
135  LOGICAL LSAME, DISNAN
136  EXTERNAL lsame, disnan
137 * ..
138 * .. Intrinsic Functions ..
139  INTRINSIC abs, min, sqrt
140 * ..
141 * .. Executable Statements ..
142 *
143  IF( n.EQ.0 ) THEN
144  VALUE = zero
145  ELSE IF( lsame( norm, 'M' ) ) THEN
146 *
147 * Find max(abs(A(i,j))).
148 *
149  VALUE = zero
150  DO 20 j = 1, n
151  DO 10 i = 1, min( n, j+1 )
152  sum = abs( a( i, j ) )
153  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
154  10 CONTINUE
155  20 CONTINUE
156  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
157 *
158 * Find norm1(A).
159 *
160  VALUE = zero
161  DO 40 j = 1, n
162  sum = zero
163  DO 30 i = 1, min( n, j+1 )
164  sum = sum + abs( a( i, j ) )
165  30 CONTINUE
166  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
167  40 CONTINUE
168  ELSE IF( lsame( norm, 'I' ) ) THEN
169 *
170 * Find normI(A).
171 *
172  DO 50 i = 1, n
173  work( i ) = zero
174  50 CONTINUE
175  DO 70 j = 1, n
176  DO 60 i = 1, min( n, j+1 )
177  work( i ) = work( i ) + abs( a( i, j ) )
178  60 CONTINUE
179  70 CONTINUE
180  VALUE = zero
181  DO 80 i = 1, n
182  sum = work( i )
183  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
184  80 CONTINUE
185  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
186 *
187 * Find normF(A).
188 *
189  scale = zero
190  sum = one
191  DO 90 j = 1, n
192  CALL dlassq( min( n, j+1 ), a( 1, j ), 1, scale, sum )
193  90 CONTINUE
194  VALUE = scale*sqrt( sum )
195  END IF
196 *
197  dlanhs = VALUE
198  RETURN
199 *
200 * End of DLANHS
201 *
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dlassq(n, x, incx, scl, sumsq)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f90:137
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function dlanhs(NORM, N, A, LDA, WORK)
DLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlanhs.f:108
Here is the call graph for this function: