dlasd8.f

Go to the documentation of this file.

*> \brief \b DLASD8 finds the square roots of the roots of the secular equation, and stores, for each element in D, the distance to its two nearest poles. Used by sbdsdc.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download DLASD8 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlasd8.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlasd8.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlasd8.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE DLASD8( ICOMPQ, K, D, Z, VF, VL, DIFL, DIFR, LDDIFR,
*                          DSIGMA, WORK, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            ICOMPQ, INFO, K, LDDIFR
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   D( * ), DIFL( * ), DIFR( LDDIFR, * ),
*      $                   DSIGMA( * ), VF( * ), VL( * ), WORK( * ),
*      $                   Z( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DLASD8 finds the square roots of the roots of the secular equation,
*> as defined by the values in DSIGMA and Z. It makes the appropriate
*> calls to DLASD4, and stores, for each  element in D, the distance
*> to its two nearest poles (elements in DSIGMA). It also updates
*> the arrays VF and VL, the first and last components of all the
*> right singular vectors of the original bidiagonal matrix.
*>
*> DLASD8 is called from DLASD6.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] ICOMPQ
*> \verbatim
*>          ICOMPQ is INTEGER
*>          Specifies whether singular vectors are to be computed in
*>          factored form in the calling routine:
*>          = 0: Compute singular values only.
*>          = 1: Compute singular vectors in factored form as well.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of terms in the rational function to be solved
*>          by DLASD4.  K >= 1.
*> \endverbatim
*>
*> \param[out] D
*> \verbatim
*>          D is DOUBLE PRECISION array, dimension ( K )
*>          On output, D contains the updated singular values.
*> \endverbatim
*>
*> \param[in,out] Z
*> \verbatim
*>          Z is DOUBLE PRECISION array, dimension ( K )
*>          On entry, the first K elements of this array contain the
*>          components of the deflation-adjusted updating row vector.
*>          On exit, Z is updated.
*> \endverbatim
*>
*> \param[in,out] VF
*> \verbatim
*>          VF is DOUBLE PRECISION array, dimension ( K )
*>          On entry, VF contains  information passed through DBEDE8.
*>          On exit, VF contains the first K components of the first
*>          components of all right singular vectors of the bidiagonal
*>          matrix.
*> \endverbatim
*>
*> \param[in,out] VL
*> \verbatim
*>          VL is DOUBLE PRECISION array, dimension ( K )
*>          On entry, VL contains  information passed through DBEDE8.
*>          On exit, VL contains the first K components of the last
*>          components of all right singular vectors of the bidiagonal
*>          matrix.
*> \endverbatim
*>
*> \param[out] DIFL
*> \verbatim
*>          DIFL is DOUBLE PRECISION array, dimension ( K )
*>          On exit, DIFL(I) = D(I) - DSIGMA(I).
*> \endverbatim
*>
*> \param[out] DIFR
*> \verbatim
*>          DIFR is DOUBLE PRECISION array,
*>                   dimension ( LDDIFR, 2 ) if ICOMPQ = 1 and
*>                   dimension ( K ) if ICOMPQ = 0.
*>          On exit, DIFR(I,1) = D(I) - DSIGMA(I+1), DIFR(K,1) is not
*>          defined and will not be referenced.
*>
*>          If ICOMPQ = 1, DIFR(1:K,2) is an array containing the
*>          normalizing factors for the right singular vector matrix.
*> \endverbatim
*>
*> \param[in] LDDIFR
*> \verbatim
*>          LDDIFR is INTEGER
*>          The leading dimension of DIFR, must be at least K.
*> \endverbatim
*>
*> \param[in] DSIGMA
*> \verbatim
*>          DSIGMA is DOUBLE PRECISION array, dimension ( K )
*>          On entry, the first K elements of this array contain the old
*>          roots of the deflated updating problem.  These are the poles
*>          of the secular equation.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (3*K)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*>          > 0:  if INFO = 1, a singular value did not converge
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup lasd8
*
*> \par Contributors:
*  ==================
*>
*>     Ming Gu and Huan Ren, Computer Science Division, University of
*>     California at Berkeley, USA
*>
*  =====================================================================
      SUBROUTINE dlasd8( ICOMPQ, K, D, Z, VF, VL, DIFL, DIFR, LDDIFR,
     $                   DSIGMA, WORK, INFO )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            ICOMPQ, INFO, K, LDDIFR
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), DIFL( * ), DIFR( LDDIFR, * ),
     $                   dsigma( * ), vf( * ), vl( * ), work( * ),
     $                   z( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IWK1, IWK2, IWK2I, IWK3, IWK3I, J
      DOUBLE PRECISION   DIFLJ, DIFRJ, DJ, DSIGJ, DSIGJP, RHO, TEMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dlascl, dlasd4, dlaset, xerbla
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DDOT, DLAMC3, DNRM2
      EXTERNAL           ddot, dlamc3, dnrm2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sign, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( ( icompq.LT.0 ) .OR. ( icompq.GT.1 ) ) THEN
         info = -1
      ELSE IF( k.LT.1 ) THEN
         info = -2
      ELSE IF( lddifr.LT.k ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DLASD8', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( k.EQ.1 ) THEN
         d( 1 ) = abs( z( 1 ) )
         difl( 1 ) = d( 1 )
         IF( icompq.EQ.1 ) THEN
            difl( 2 ) = one
            difr( 1, 2 ) = one
         END IF
         RETURN
      END IF
*
*     Book keeping.
*
      iwk1 = 1
      iwk2 = iwk1 + k
      iwk3 = iwk2 + k
      iwk2i = iwk2 - 1
      iwk3i = iwk3 - 1
*
*     Normalize Z.
*
      rho = dnrm2( k, z, 1 )
      CALL dlascl( 'G', 0, 0, rho, one, k, 1, z, k, info )
      rho = rho*rho
*
*     Initialize WORK(IWK3).
*
      CALL dlaset( 'A', k, 1, one, one, work( iwk3 ), k )
*
*     Compute the updated singular values, the arrays DIFL, DIFR,
*     and the updated Z.
*
      DO 40 j = 1, k
         CALL dlasd4( k, j, dsigma, z, work( iwk1 ), rho, d( j ),
     $                work( iwk2 ), info )
*
*        If the root finder fails, report the convergence failure.
*
         IF( info.NE.0 ) THEN
            RETURN
         END IF
         work( iwk3i+j ) = work( iwk3i+j )*work( j )*work( iwk2i+j )
         difl( j ) = -work( j )
         difr( j, 1 ) = -work( j+1 )
         DO 20 i = 1, j - 1
            work( iwk3i+i ) = work( iwk3i+i )*work( i )*
     $                        work( iwk2i+i ) / ( dsigma( i )-
     $                        dsigma( j ) ) / ( dsigma( i )+
     $                        dsigma( j ) )
   20    CONTINUE
         DO 30 i = j + 1, k
            work( iwk3i+i ) = work( iwk3i+i )*work( i )*
     $                        work( iwk2i+i ) / ( dsigma( i )-
     $                        dsigma( j ) ) / ( dsigma( i )+
     $                        dsigma( j ) )
   30    CONTINUE
   40 CONTINUE
*
*     Compute updated Z.
*
      DO 50 i = 1, k
         z( i ) = sign( sqrt( abs( work( iwk3i+i ) ) ), z( i ) )
   50 CONTINUE
*
*     Update VF and VL.
*
      DO 80 j = 1, k
         diflj = difl( j )
         dj = d( j )
         dsigj = -dsigma( j )
         IF( j.LT.k ) THEN
            difrj = -difr( j, 1 )
            dsigjp = -dsigma( j+1 )
         END IF
         work( j ) = -z( j ) / diflj / ( dsigma( j )+dj )
*
*        Use calls to the subroutine DLAMC3 to enforce the parentheses
*        (x+y)+z. The goal is to prevent optimizing compilers
*        from doing x+(y+z).
*
         DO 60 i = 1, j - 1
            work( i ) = z( i ) / ( dlamc3( dsigma( i ), dsigj )-diflj )
     $                   / ( dsigma( i )+dj )
   60    CONTINUE
         DO 70 i = j + 1, k
            work( i ) = z( i ) / ( dlamc3( dsigma( i ), dsigjp )+difrj )
     $                   / ( dsigma( i )+dj )
   70    CONTINUE
         temp = dnrm2( k, work, 1 )
         work( iwk2i+j ) = ddot( k, work, 1, vf, 1 ) / temp
         work( iwk3i+j ) = ddot( k, work, 1, vl, 1 ) / temp
         IF( icompq.EQ.1 ) THEN
            difr( j, 2 ) = temp
         END IF
   80 CONTINUE
*
      CALL dcopy( k, work( iwk2 ), 1, vf, 1 )
      CALL dcopy( k, work( iwk3 ), 1, vl, 1 )
*
      RETURN
*
*     End of DLASD8
*
      END