LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ chesv_rk()

subroutine chesv_rk ( character  UPLO,
integer  N,
integer  NRHS,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( * )  E,
integer, dimension( * )  IPIV,
complex, dimension( ldb, * )  B,
integer  LDB,
complex, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

CHESV_RK computes the solution to system of linear equations A * X = B for SY matrices

Download CHESV_RK + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CHESV_RK computes the solution to a complex system of linear
 equations A * X = B, where A is an N-by-N Hermitian matrix
 and X and B are N-by-NRHS matrices.

 The bounded Bunch-Kaufman (rook) diagonal pivoting method is used
 to factor A as
    A = P*U*D*(U**H)*(P**T),  if UPLO = 'U', or
    A = P*L*D*(L**H)*(P**T),  if UPLO = 'L',
 where U (or L) is unit upper (or lower) triangular matrix,
 U**H (or L**H) is the conjugate of U (or L), P is a permutation
 matrix, P**T is the transpose of P, and D is Hermitian and block
 diagonal with 1-by-1 and 2-by-2 diagonal blocks.

 CHETRF_RK is called to compute the factorization of a complex
 Hermitian matrix.  The factored form of A is then used to solve
 the system of equations A * X = B by calling BLAS3 routine CHETRS_3.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          Hermitian matrix A is stored:
          = 'U':  Upper triangle of A is stored;
          = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
          The number of linear equations, i.e., the order of the
          matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the Hermitian matrix A.
            If UPLO = 'U': the leading N-by-N upper triangular part
            of A contains the upper triangular part of the matrix A,
            and the strictly lower triangular part of A is not
            referenced.

            If UPLO = 'L': the leading N-by-N lower triangular part
            of A contains the lower triangular part of the matrix A,
            and the strictly upper triangular part of A is not
            referenced.

          On exit, if INFO = 0, diagonal of the block diagonal
          matrix D and factors U or L  as computed by CHETRF_RK:
            a) ONLY diagonal elements of the Hermitian block diagonal
               matrix D on the diagonal of A, i.e. D(k,k) = A(k,k);
               (superdiagonal (or subdiagonal) elements of D
                are stored on exit in array E), and
            b) If UPLO = 'U': factor U in the superdiagonal part of A.
               If UPLO = 'L': factor L in the subdiagonal part of A.

          For more info see the description of CHETRF_RK routine.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]E
          E is COMPLEX array, dimension (N)
          On exit, contains the output computed by the factorization
          routine CHETRF_RK, i.e. the superdiagonal (or subdiagonal)
          elements of the Hermitian block diagonal matrix D
          with 1-by-1 or 2-by-2 diagonal blocks, where
          If UPLO = 'U': E(i) = D(i-1,i), i=2:N, E(1) is set to 0;
          If UPLO = 'L': E(i) = D(i+1,i), i=1:N-1, E(N) is set to 0.

          NOTE: For 1-by-1 diagonal block D(k), where
          1 <= k <= N, the element E(k) is set to 0 in both
          UPLO = 'U' or UPLO = 'L' cases.

          For more info see the description of CHETRF_RK routine.
[out]IPIV
          IPIV is INTEGER array, dimension (N)
          Details of the interchanges and the block structure of D,
          as determined by CHETRF_RK.

          For more info see the description of CHETRF_RK routine.
[in,out]B
          B is COMPLEX array, dimension (LDB,NRHS)
          On entry, the N-by-NRHS right hand side matrix B.
          On exit, if INFO = 0, the N-by-NRHS solution matrix X.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]WORK
          WORK is COMPLEX array, dimension ( MAX(1,LWORK) ).
          Work array used in the factorization stage.
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The length of WORK.  LWORK >= 1. For best performance
          of factorization stage LWORK >= max(1,N*NB), where NB is
          the optimal blocksize for CHETRF_RK.

          If LWORK = -1, then a workspace query is assumed;
          the routine only calculates the optimal size of the WORK
          array for factorization stage, returns this value as
          the first entry of the WORK array, and no error message
          related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
          = 0: successful exit

          < 0: If INFO = -k, the k-th argument had an illegal value

          > 0: If INFO = k, the matrix A is singular, because:
                 If UPLO = 'U': column k in the upper
                 triangular part of A contains all zeros.
                 If UPLO = 'L': column k in the lower
                 triangular part of A contains all zeros.

               Therefore D(k,k) is exactly zero, and superdiagonal
               elements of column k of U (or subdiagonal elements of
               column k of L ) are all zeros. The factorization has
               been completed, but the block diagonal matrix D is
               exactly singular, and division by zero will occur if
               it is used to solve a system of equations.

               NOTE: INFO only stores the first occurrence of
               a singularity, any subsequent occurrence of singularity
               is not stored in INFO even though the factorization
               always completes.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
  December 2016,  Igor Kozachenko,
                  Computer Science Division,
                  University of California, Berkeley

  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
                  School of Mathematics,
                  University of Manchester

Definition at line 226 of file chesv_rk.f.

228 *
229 * -- LAPACK driver routine --
230 * -- LAPACK is a software package provided by Univ. of Tennessee, --
231 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
232 *
233 * .. Scalar Arguments ..
234  CHARACTER UPLO
235  INTEGER INFO, LDA, LDB, LWORK, N, NRHS
236 * ..
237 * .. Array Arguments ..
238  INTEGER IPIV( * )
239  COMPLEX A( LDA, * ), B( LDB, * ), E( * ), WORK( * )
240 * ..
241 *
242 * =====================================================================
243 *
244 * .. Local Scalars ..
245  LOGICAL LQUERY
246  INTEGER LWKOPT
247 * ..
248 * .. External Functions ..
249  LOGICAL LSAME
250  EXTERNAL lsame
251 * ..
252 * .. External Subroutines ..
253  EXTERNAL xerbla, chetrf_rk, chetrs_3
254 * ..
255 * .. Intrinsic Functions ..
256  INTRINSIC max
257 * ..
258 * .. Executable Statements ..
259 *
260 * Test the input parameters.
261 *
262  info = 0
263  lquery = ( lwork.EQ.-1 )
264  IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
265  info = -1
266  ELSE IF( n.LT.0 ) THEN
267  info = -2
268  ELSE IF( nrhs.LT.0 ) THEN
269  info = -3
270  ELSE IF( lda.LT.max( 1, n ) ) THEN
271  info = -5
272  ELSE IF( ldb.LT.max( 1, n ) ) THEN
273  info = -9
274  ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
275  info = -11
276  END IF
277 *
278  IF( info.EQ.0 ) THEN
279  IF( n.EQ.0 ) THEN
280  lwkopt = 1
281  ELSE
282  CALL chetrf_rk( uplo, n, a, lda, e, ipiv, work, -1, info )
283  lwkopt = real( work(1) )
284  END IF
285  work( 1 ) = lwkopt
286  END IF
287 *
288  IF( info.NE.0 ) THEN
289  CALL xerbla( 'CHESV_RK ', -info )
290  RETURN
291  ELSE IF( lquery ) THEN
292  RETURN
293  END IF
294 *
295 * Compute the factorization A = U*D*U**T or A = L*D*L**T.
296 *
297  CALL chetrf_rk( uplo, n, a, lda, e, ipiv, work, lwork, info )
298 *
299  IF( info.EQ.0 ) THEN
300 *
301 * Solve the system A*X = B with BLAS3 solver, overwriting B with X.
302 *
303  CALL chetrs_3( uplo, n, nrhs, a, lda, e, ipiv, b, ldb, info )
304 *
305  END IF
306 *
307  work( 1 ) = lwkopt
308 *
309  RETURN
310 *
311 * End of CHESV_RK
312 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine chetrf_rk(UPLO, N, A, LDA, E, IPIV, WORK, LWORK, INFO)
CHETRF_RK computes the factorization of a complex Hermitian indefinite matrix using the bounded Bunch...
Definition: chetrf_rk.f:259
subroutine chetrs_3(UPLO, N, NRHS, A, LDA, E, IPIV, B, LDB, INFO)
CHETRS_3
Definition: chetrs_3.f:165
Here is the call graph for this function:
Here is the caller graph for this function: