LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ dsprfs()

subroutine dsprfs ( character uplo,
integer n,
integer nrhs,
double precision, dimension( * ) ap,
double precision, dimension( * ) afp,
integer, dimension( * ) ipiv,
double precision, dimension( ldb, * ) b,
integer ldb,
double precision, dimension( ldx, * ) x,
integer ldx,
double precision, dimension( * ) ferr,
double precision, dimension( * ) berr,
double precision, dimension( * ) work,
integer, dimension( * ) iwork,
integer info )

DSPRFS

Download DSPRFS + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> DSPRFS improves the computed solution to a system of linear
!> equations when the coefficient matrix is symmetric indefinite
!> and packed, and provides error bounds and backward error estimates
!> for the solution.
!>
Parameters
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangle of A is stored;
!>          = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix A.  N >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>          The number of right hand sides, i.e., the number of columns
!>          of the matrices B and X.  NRHS >= 0.
!>
[in]AP
!>          AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
!>          The upper or lower triangle of the symmetric matrix A, packed
!>          columnwise in a linear array.  The j-th column of A is stored
!>          in the array AP as follows:
!>          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
!>          if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
!>
[in]AFP
!>          AFP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
!>          The factored form of the matrix A.  AFP contains the block
!>          diagonal matrix D and the multipliers used to obtain the
!>          factor U or L from the factorization A = U*D*U**T or
!>          A = L*D*L**T as computed by DSPTRF, stored as a packed
!>          triangular matrix.
!>
[in]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>          Details of the interchanges and the block structure of D
!>          as determined by DSPTRF.
!>
[in]B
!>          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
!>          The right hand side matrix B.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[in,out]X
!>          X is DOUBLE PRECISION array, dimension (LDX,NRHS)
!>          On entry, the solution matrix X, as computed by DSPTRS.
!>          On exit, the improved solution matrix X.
!>
[in]LDX
!>          LDX is INTEGER
!>          The leading dimension of the array X.  LDX >= max(1,N).
!>
[out]FERR
!>          FERR is DOUBLE PRECISION array, dimension (NRHS)
!>          The estimated forward error bound for each solution vector
!>          X(j) (the j-th column of the solution matrix X).
!>          If XTRUE is the true solution corresponding to X(j), FERR(j)
!>          is an estimated upper bound for the magnitude of the largest
!>          element in (X(j) - XTRUE) divided by the magnitude of the
!>          largest element in X(j).  The estimate is as reliable as
!>          the estimate for RCOND, and is almost always a slight
!>          overestimate of the true error.
!>
[out]BERR
!>          BERR is DOUBLE PRECISION array, dimension (NRHS)
!>          The componentwise relative backward error of each solution
!>          vector X(j) (i.e., the smallest relative change in
!>          any element of A or B that makes X(j) an exact solution).
!>
[out]WORK
!>          WORK is DOUBLE PRECISION array, dimension (3*N)
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (N)
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>
Internal Parameters:
!>  ITMAX is the maximum number of steps of iterative refinement.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 175 of file dsprfs.f.

178*
179* -- LAPACK computational routine --
180* -- LAPACK is a software package provided by Univ. of Tennessee, --
181* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
182*
183* .. Scalar Arguments ..
184 CHARACTER UPLO
185 INTEGER INFO, LDB, LDX, N, NRHS
186* ..
187* .. Array Arguments ..
188 INTEGER IPIV( * ), IWORK( * )
189 DOUBLE PRECISION AFP( * ), AP( * ), B( LDB, * ), BERR( * ),
190 $ FERR( * ), WORK( * ), X( LDX, * )
191* ..
192*
193* =====================================================================
194*
195* .. Parameters ..
196 INTEGER ITMAX
197 parameter( itmax = 5 )
198 DOUBLE PRECISION ZERO
199 parameter( zero = 0.0d+0 )
200 DOUBLE PRECISION ONE
201 parameter( one = 1.0d+0 )
202 DOUBLE PRECISION TWO
203 parameter( two = 2.0d+0 )
204 DOUBLE PRECISION THREE
205 parameter( three = 3.0d+0 )
206* ..
207* .. Local Scalars ..
208 LOGICAL UPPER
209 INTEGER COUNT, I, IK, J, K, KASE, KK, NZ
210 DOUBLE PRECISION EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
211* ..
212* .. Local Arrays ..
213 INTEGER ISAVE( 3 )
214* ..
215* .. External Subroutines ..
216 EXTERNAL daxpy, dcopy, dlacn2, dspmv, dsptrs,
217 $ xerbla
218* ..
219* .. Intrinsic Functions ..
220 INTRINSIC abs, max
221* ..
222* .. External Functions ..
223 LOGICAL LSAME
224 DOUBLE PRECISION DLAMCH
225 EXTERNAL lsame, dlamch
226* ..
227* .. Executable Statements ..
228*
229* Test the input parameters.
230*
231 info = 0
232 upper = lsame( uplo, 'U' )
233 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
234 info = -1
235 ELSE IF( n.LT.0 ) THEN
236 info = -2
237 ELSE IF( nrhs.LT.0 ) THEN
238 info = -3
239 ELSE IF( ldb.LT.max( 1, n ) ) THEN
240 info = -8
241 ELSE IF( ldx.LT.max( 1, n ) ) THEN
242 info = -10
243 END IF
244 IF( info.NE.0 ) THEN
245 CALL xerbla( 'DSPRFS', -info )
246 RETURN
247 END IF
248*
249* Quick return if possible
250*
251 IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
252 DO 10 j = 1, nrhs
253 ferr( j ) = zero
254 berr( j ) = zero
255 10 CONTINUE
256 RETURN
257 END IF
258*
259* NZ = maximum number of nonzero elements in each row of A, plus 1
260*
261 nz = n + 1
262 eps = dlamch( 'Epsilon' )
263 safmin = dlamch( 'Safe minimum' )
264 safe1 = nz*safmin
265 safe2 = safe1 / eps
266*
267* Do for each right hand side
268*
269 DO 140 j = 1, nrhs
270*
271 count = 1
272 lstres = three
273 20 CONTINUE
274*
275* Loop until stopping criterion is satisfied.
276*
277* Compute residual R = B - A * X
278*
279 CALL dcopy( n, b( 1, j ), 1, work( n+1 ), 1 )
280 CALL dspmv( uplo, n, -one, ap, x( 1, j ), 1, one,
281 $ work( n+1 ),
282 $ 1 )
283*
284* Compute componentwise relative backward error from formula
285*
286* max(i) ( abs(R(i)) / ( abs(A)*abs(X) + abs(B) )(i) )
287*
288* where abs(Z) is the componentwise absolute value of the matrix
289* or vector Z. If the i-th component of the denominator is less
290* than SAFE2, then SAFE1 is added to the i-th components of the
291* numerator and denominator before dividing.
292*
293 DO 30 i = 1, n
294 work( i ) = abs( b( i, j ) )
295 30 CONTINUE
296*
297* Compute abs(A)*abs(X) + abs(B).
298*
299 kk = 1
300 IF( upper ) THEN
301 DO 50 k = 1, n
302 s = zero
303 xk = abs( x( k, j ) )
304 ik = kk
305 DO 40 i = 1, k - 1
306 work( i ) = work( i ) + abs( ap( ik ) )*xk
307 s = s + abs( ap( ik ) )*abs( x( i, j ) )
308 ik = ik + 1
309 40 CONTINUE
310 work( k ) = work( k ) + abs( ap( kk+k-1 ) )*xk + s
311 kk = kk + k
312 50 CONTINUE
313 ELSE
314 DO 70 k = 1, n
315 s = zero
316 xk = abs( x( k, j ) )
317 work( k ) = work( k ) + abs( ap( kk ) )*xk
318 ik = kk + 1
319 DO 60 i = k + 1, n
320 work( i ) = work( i ) + abs( ap( ik ) )*xk
321 s = s + abs( ap( ik ) )*abs( x( i, j ) )
322 ik = ik + 1
323 60 CONTINUE
324 work( k ) = work( k ) + s
325 kk = kk + ( n-k+1 )
326 70 CONTINUE
327 END IF
328 s = zero
329 DO 80 i = 1, n
330 IF( work( i ).GT.safe2 ) THEN
331 s = max( s, abs( work( n+i ) ) / work( i ) )
332 ELSE
333 s = max( s, ( abs( work( n+i ) )+safe1 ) /
334 $ ( work( i )+safe1 ) )
335 END IF
336 80 CONTINUE
337 berr( j ) = s
338*
339* Test stopping criterion. Continue iterating if
340* 1) The residual BERR(J) is larger than machine epsilon, and
341* 2) BERR(J) decreased by at least a factor of 2 during the
342* last iteration, and
343* 3) At most ITMAX iterations tried.
344*
345 IF( berr( j ).GT.eps .AND. two*berr( j ).LE.lstres .AND.
346 $ count.LE.itmax ) THEN
347*
348* Update solution and try again.
349*
350 CALL dsptrs( uplo, n, 1, afp, ipiv, work( n+1 ), n,
351 $ info )
352 CALL daxpy( n, one, work( n+1 ), 1, x( 1, j ), 1 )
353 lstres = berr( j )
354 count = count + 1
355 GO TO 20
356 END IF
357*
358* Bound error from formula
359*
360* norm(X - XTRUE) / norm(X) .le. FERR =
361* norm( abs(inv(A))*
362* ( abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) ))) / norm(X)
363*
364* where
365* norm(Z) is the magnitude of the largest component of Z
366* inv(A) is the inverse of A
367* abs(Z) is the componentwise absolute value of the matrix or
368* vector Z
369* NZ is the maximum number of nonzeros in any row of A, plus 1
370* EPS is machine epsilon
371*
372* The i-th component of abs(R)+NZ*EPS*(abs(A)*abs(X)+abs(B))
373* is incremented by SAFE1 if the i-th component of
374* abs(A)*abs(X) + abs(B) is less than SAFE2.
375*
376* Use DLACN2 to estimate the infinity-norm of the matrix
377* inv(A) * diag(W),
378* where W = abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) )))
379*
380 DO 90 i = 1, n
381 IF( work( i ).GT.safe2 ) THEN
382 work( i ) = abs( work( n+i ) ) + nz*eps*work( i )
383 ELSE
384 work( i ) = abs( work( n+i ) ) + nz*eps*work( i ) + safe1
385 END IF
386 90 CONTINUE
387*
388 kase = 0
389 100 CONTINUE
390 CALL dlacn2( n, work( 2*n+1 ), work( n+1 ), iwork,
391 $ ferr( j ),
392 $ kase, isave )
393 IF( kase.NE.0 ) THEN
394 IF( kase.EQ.1 ) THEN
395*
396* Multiply by diag(W)*inv(A**T).
397*
398 CALL dsptrs( uplo, n, 1, afp, ipiv, work( n+1 ), n,
399 $ info )
400 DO 110 i = 1, n
401 work( n+i ) = work( i )*work( n+i )
402 110 CONTINUE
403 ELSE IF( kase.EQ.2 ) THEN
404*
405* Multiply by inv(A)*diag(W).
406*
407 DO 120 i = 1, n
408 work( n+i ) = work( i )*work( n+i )
409 120 CONTINUE
410 CALL dsptrs( uplo, n, 1, afp, ipiv, work( n+1 ), n,
411 $ info )
412 END IF
413 GO TO 100
414 END IF
415*
416* Normalize error.
417*
418 lstres = zero
419 DO 130 i = 1, n
420 lstres = max( lstres, abs( x( i, j ) ) )
421 130 CONTINUE
422 IF( lstres.NE.zero )
423 $ ferr( j ) = ferr( j ) / lstres
424*
425 140 CONTINUE
426*
427 RETURN
428*
429* End of DSPRFS
430*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
daxpy
subroutine daxpy(n, da, dx, incx, dy, incy)
DAXPY
Definition daxpy.f:89
dcopy
subroutine dcopy(n, dx, incx, dy, incy)
DCOPY
Definition dcopy.f:82
dspmv
subroutine dspmv(uplo, n, alpha, ap, x, incx, beta, y, incy)
DSPMV
Definition dspmv.f:147
dsptrs
subroutine dsptrs(uplo, n, nrhs, ap, ipiv, b, ldb, info)
DSPTRS
Definition dsptrs.f:113
dlacn2
subroutine dlacn2(n, v, x, isgn, est, kase, isave)
DLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition dlacn2.f:134
dlamch
double precision function dlamch(cmach)
DLAMCH
Definition dlamch.f:69
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: