cptt01()

subroutine cptt01	(	integer	n,
		real, dimension( * )	d,
		complex, dimension( * )	e,
		real, dimension( * )	df,
		complex, dimension( * )	ef,
		complex, dimension( * )	work,
		real	resid )

CPTT01

Purpose:

!>
!> CPTT01 reconstructs a tridiagonal matrix A from its L*D*L'
!> factorization and computes the residual
!>    norm(L*D*L' - A) / ( n * norm(A) * EPS ),
!> where EPS is the machine epsilon.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. !>
[in]	D	!> D is REAL array, dimension (N) !> The n diagonal elements of the tridiagonal matrix A. !>
[in]	E	!> E is COMPLEX array, dimension (N-1) !> The (n-1) subdiagonal elements of the tridiagonal matrix A. !>
[in]	DF	!> DF is REAL array, dimension (N) !> The n diagonal elements of the factor L from the L*D*L' !> factorization of A. !>
[in]	EF	!> EF is COMPLEX array, dimension (N-1) !> The (n-1) subdiagonal elements of the factor L from the !> L*D*L' factorization of A. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (2*N) !>
[out]	RESID	!> RESID is REAL !> norm(L*D*L' - A) / (n * norm(A) * EPS) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 91 of file cptt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               D( * ), DF( * )
      COMPLEX            E( * ), EF( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      REAL               ANORM, EPS
      COMPLEX            DE
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      EXTERNAL           slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, conjg, max, real
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
      eps = slamch( 'Epsilon' )
*
*     Construct the difference L*D*L' - A.
*
      work( 1 ) = df( 1 ) - d( 1 )
      DO 10 i = 1, n - 1
         de = df( i )*ef( i )
         work( n+i ) = de - e( i )
         work( 1+i ) = de*conjg( ef( i ) ) + df( i+1 ) - d( i+1 )
   10 CONTINUE
*
*     Compute the 1-norms of the tridiagonal matrices A and WORK.
*
      IF( n.EQ.1 ) THEN
         anorm = d( 1 )
         resid = abs( work( 1 ) )
      ELSE
         anorm = max( d( 1 )+abs( e( 1 ) ), d( n )+abs( e( n-1 ) ) )
         resid = max( abs( work( 1 ) )+abs( work( n+1 ) ),
     $           abs( work( n ) )+abs( work( 2*n-1 ) ) )
         DO 20 i = 2, n - 1
            anorm = max( anorm, d( i )+abs( e( i ) )+abs( e( i-1 ) ) )
            resid = max( resid, abs( work( i ) )+abs( work( n+i-1 ) )+
     $              abs( work( n+i ) ) )
   20    CONTINUE
      END IF
*
*     Compute norm(L*D*L' - A) / (n * norm(A) * EPS)
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / real( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of CPTT01
*

Here is the caller graph for this function: