slae2()

subroutine slae2	(	real	a,
		real	b,
		real	c,
		real	rt1,
		real	rt2
	)

SLAE2 computes the eigenvalues of a 2-by-2 symmetric matrix.

Download SLAE2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SLAE2  computes the eigenvalues of a 2-by-2 symmetric matrix
    [  A   B  ]
    [  B   C  ].
 On return, RT1 is the eigenvalue of larger absolute value, and RT2
 is the eigenvalue of smaller absolute value.

Parameters

[in]	A	A is REAL The (1,1) element of the 2-by-2 matrix.
[in]	B	B is REAL The (1,2) and (2,1) elements of the 2-by-2 matrix.
[in]	C	C is REAL The (2,2) element of the 2-by-2 matrix.
[out]	RT1	RT1 is REAL The eigenvalue of larger absolute value.
[out]	RT2	RT2 is REAL The eigenvalue of smaller absolute value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  RT1 is accurate to a few ulps barring over/underflow.

  RT2 may be inaccurate if there is massive cancellation in the
  determinant A*C-B*B; higher precision or correctly rounded or
  correctly truncated arithmetic would be needed to compute RT2
  accurately in all cases.

  Overflow is possible only if RT1 is within a factor of 5 of overflow.
  Underflow is harmless if the input data is 0 or exceeds
     underflow_threshold / macheps.

Definition at line 101 of file slae2.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      REAL               A, B, C, RT1, RT2
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e0 )
      REAL               TWO
      parameter( two = 2.0e0 )
      REAL               ZERO
      parameter( zero = 0.0e0 )
      REAL               HALF
      parameter( half = 0.5e0 )
*     ..
*     .. Local Scalars ..
      REAL               AB, ACMN, ACMX, ADF, DF, RT, SM, TB
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
*     Compute the eigenvalues
*
      sm = a + c
      df = a - c
      adf = abs( df )
      tb = b + b
      ab = abs( tb )
      IF( abs( a ).GT.abs( c ) ) THEN
         acmx = a
         acmn = c
      ELSE
         acmx = c
         acmn = a
      END IF
      IF( adf.GT.ab ) THEN
         rt = adf*sqrt( one+( ab / adf )**2 )
      ELSE IF( adf.LT.ab ) THEN
         rt = ab*sqrt( one+( adf / ab )**2 )
      ELSE
*
*        Includes case AB=ADF=0
*
         rt = ab*sqrt( two )
      END IF
      IF( sm.LT.zero ) THEN
         rt1 = half*( sm-rt )
*
*        Order of execution important.
*        To get fully accurate smaller eigenvalue,
*        next line needs to be executed in higher precision.
*
         rt2 = ( acmx / rt1 )*acmn - ( b / rt1 )*b
      ELSE IF( sm.GT.zero ) THEN
         rt1 = half*( sm+rt )
*
*        Order of execution important.
*        To get fully accurate smaller eigenvalue,
*        next line needs to be executed in higher precision.
*
         rt2 = ( acmx / rt1 )*acmn - ( b / rt1 )*b
      ELSE
*
*        Includes case RT1 = RT2 = 0
*
         rt1 = half*rt
         rt2 = -half*rt
      END IF
      RETURN
*
*     End of SLAE2
*

Here is the caller graph for this function: