cpbequ()

subroutine cpbequ	(	character	uplo,
		integer	n,
		integer	kd,
		complex, dimension( ldab, * )	ab,
		integer	ldab,
		real, dimension( * )	s,
		real	scond,
		real	amax,
		integer	info )

CPBEQU

Download CPBEQU + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CPBEQU computes row and column scalings intended to equilibrate a
!> Hermitian positive definite band matrix A and reduce its condition
!> number (with respect to the two-norm).  S contains the scale factors,
!> S(i) = 1/sqrt(A(i,i)), chosen so that the scaled matrix B with
!> elements B(i,j) = S(i)*A(i,j)*S(j) has ones on the diagonal.  This
!> choice of S puts the condition number of B within a factor N of the
!> smallest possible condition number over all possible diagonal
!> scalings.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangular of A is stored; !> = 'L': Lower triangular of A is stored. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	KD	!> KD is INTEGER !> The number of superdiagonals of the matrix A if UPLO = 'U', !> or the number of subdiagonals if UPLO = 'L'. KD >= 0. !>
[in]	AB	!> AB is COMPLEX array, dimension (LDAB,N) !> The upper or lower triangle of the Hermitian band matrix A, !> stored in the first KD+1 rows of the array. The j-th column !> of A is stored in the j-th column of the array AB as follows: !> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; !> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array A. LDAB >= KD+1. !>
[out]	S	!> S is REAL array, dimension (N) !> If INFO = 0, S contains the scale factors for A. !>
[out]	SCOND	!> SCOND is REAL !> If INFO = 0, S contains the ratio of the smallest S(i) to !> the largest S(i). If SCOND >= 0.1 and AMAX is neither too !> large nor too small, it is not worth scaling by S. !>
[out]	AMAX	!> AMAX is REAL !> Absolute value of largest matrix element. If AMAX is very !> close to overflow or very close to underflow, the matrix !> should be scaled. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = i, the i-th diagonal element is nonpositive. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 127 of file cpbequ.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, KD, LDAB, N
      REAL               AMAX, SCOND
*     ..
*     .. Array Arguments ..
      REAL               S( * )
      COMPLEX            AB( LDAB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, J
      REAL               SMIN
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kd.LT.0 ) THEN
         info = -3
      ELSE IF( ldab.LT.kd+1 ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPBEQU', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         scond = one
         amax = zero
         RETURN
      END IF
*
      IF( upper ) THEN
         j = kd + 1
      ELSE
         j = 1
      END IF
*
*     Initialize SMIN and AMAX.
*
      s( 1 ) = real( ab( j, 1 ) )
      smin = s( 1 )
      amax = s( 1 )
*
*     Find the minimum and maximum diagonal elements.
*
      DO 10 i = 2, n
         s( i ) = real( ab( j, i ) )
         smin = min( smin, s( i ) )
         amax = max( amax, s( i ) )
   10 CONTINUE
*
      IF( smin.LE.zero ) THEN
*
*        Find the first non-positive diagonal element and return.
*
         DO 20 i = 1, n
            IF( s( i ).LE.zero ) THEN
               info = i
               RETURN
            END IF
   20    CONTINUE
      ELSE
*
*        Set the scale factors to the reciprocals
*        of the diagonal elements.
*
         DO 30 i = 1, n
            s( i ) = one / sqrt( s( i ) )
   30    CONTINUE
*
*        Compute SCOND = min(S(I)) / max(S(I))
*
         scond = sqrt( smin ) / sqrt( amax )
      END IF
      RETURN
*
*     End of CPBEQU
*

Here is the call graph for this function:

Here is the caller graph for this function: