dtpqrt2()

subroutine dtpqrt2	(	integer	m,
		integer	n,
		integer	l,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( ldt, * )	t,
		integer	ldt,
		integer	info )

DTPQRT2 computes a QR factorization of a real or complex "triangular-pentagonal" matrix, which is composed of a triangular block and a pentagonal block, using the compact WY representation for Q.

Download DTPQRT2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DTPQRT2 computes a QR factorization of a real 
!> matrix C, which is composed of a triangular block A and pentagonal block B,
!> using the compact WY representation for Q.
!> 

Parameters

[in]	M	!> M is INTEGER !> The total number of rows of the matrix B. !> M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix B, and the order of !> the triangular matrix A. !> N >= 0. !>
[in]	L	!> L is INTEGER !> The number of rows of the upper trapezoidal part of B. !> MIN(M,N) >= L >= 0. See Further Details. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> On entry, the upper triangular N-by-N matrix A. !> On exit, the elements on and above the diagonal of the array !> contain the upper triangular matrix R. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in,out]	B	!> B is DOUBLE PRECISION array, dimension (LDB,N) !> On entry, the pentagonal M-by-N matrix B. The first M-L rows !> are rectangular, and the last L rows are upper trapezoidal. !> On exit, B contains the pentagonal matrix V. See Further Details. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,M). !>
[out]	T	!> T is DOUBLE PRECISION array, dimension (LDT,N) !> The N-by-N upper triangular factor T of the block reflector. !> See Further Details. !>
[in]	LDT	!> LDT is INTEGER !> The leading dimension of the array T. LDT >= max(1,N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The input matrix C is a (N+M)-by-N matrix
!>
!>               C = [ A ]
!>                   [ B ]
!>
!>  where A is an upper triangular N-by-N matrix, and B is M-by-N pentagonal
!>  matrix consisting of a (M-L)-by-N rectangular matrix B1 on top of a L-by-N
!>  upper trapezoidal matrix B2:
!>
!>               B = [ B1 ]  <- (M-L)-by-N rectangular
!>                   [ B2 ]  <-     L-by-N upper trapezoidal.
!>
!>  The upper trapezoidal matrix B2 consists of the first L rows of a
!>  N-by-N upper triangular matrix, where 0 <= L <= MIN(M,N).  If L=0,
!>  B is rectangular M-by-N; if M=L=N, B is upper triangular.
!>
!>  The matrix W stores the elementary reflectors H(i) in the i-th column
!>  below the diagonal (of A) in the (N+M)-by-N input matrix C
!>
!>               C = [ A ]  <- upper triangular N-by-N
!>                   [ B ]  <- M-by-N pentagonal
!>
!>  so that W can be represented as
!>
!>               W = [ I ]  <- identity, N-by-N
!>                   [ V ]  <- M-by-N, same form as B.
!>
!>  Thus, all of information needed for W is contained on exit in B, which
!>  we call V above.  Note that V has the same form as B; that is,
!>
!>               V = [ V1 ] <- (M-L)-by-N rectangular
!>                   [ V2 ] <-     L-by-N upper trapezoidal.
!>
!>  The columns of V represent the vectors which define the H(i)'s.
!>  The (M+N)-by-(M+N) block reflector H is then given by
!>
!>               H = I - W * T * W**T
!>
!>  where W^H is the conjugate transpose of W and T is the upper triangular
!>  factor of the block reflector.
!> 

Definition at line 170 of file dtpqrt2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER   INFO, LDA, LDB, LDT, N, M, L
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), T( LDT, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION  ONE, ZERO
      parameter( one = 1.0, zero = 0.0 )
*     ..
*     .. Local Scalars ..
      INTEGER   I, J, P, MP, NP
      DOUBLE PRECISION   ALPHA
*     ..
*     .. External Subroutines ..
      EXTERNAL  dlarfg, dgemv, dger, dtrmv, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( l.LT.0 .OR. l.GT.min(m,n) ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, m ) ) THEN
         info = -7
      ELSE IF( ldt.LT.max( 1, n ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DTPQRT2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. m.EQ.0 ) RETURN
*
      DO i = 1, n
*
*        Generate elementary reflector H(I) to annihilate B(:,I)
*
         p = m-l+min( l, i )
         CALL dlarfg( p+1, a( i, i ), b( 1, i ), 1, t( i, 1 ) )
         IF( i.LT.n ) THEN
*
*           W(1:N-I) := C(I:M,I+1:N)^H * C(I:M,I) [use W = T(:,N)]
*
            DO j = 1, n-i
               t( j, n ) = (a( i, i+j ))
            END DO
            CALL dgemv( 'T', p, n-i, one, b( 1, i+1 ), ldb,
     $                  b( 1, i ), 1, one, t( 1, n ), 1 )
*
*           C(I:M,I+1:N) = C(I:m,I+1:N) + alpha*C(I:M,I)*W(1:N-1)^H
*
            alpha = -(t( i, 1 ))
            DO j = 1, n-i
               a( i, i+j ) = a( i, i+j ) + alpha*(t( j, n ))
            END DO
            CALL dger( p, n-i, alpha, b( 1, i ), 1,
     $           t( 1, n ), 1, b( 1, i+1 ), ldb )
         END IF
      END DO
*
      DO i = 2, n
*
*        T(1:I-1,I) := C(I:M,1:I-1)^H * (alpha * C(I:M,I))
*
         alpha = -t( i, 1 )
 
         DO j = 1, i-1
            t( j, i ) = zero
         END DO
         p = min( i-1, l )
         mp = min( m-l+1, m )
         np = min( p+1, n )
*
*        Triangular part of B2
*
         DO j = 1, p
            t( j, i ) = alpha*b( m-l+j, i )
         END DO
         CALL dtrmv( 'U', 'T', 'N', p, b( mp, 1 ), ldb,
     $               t( 1, i ), 1 )
*
*        Rectangular part of B2
*
         CALL dgemv( 'T', l, i-1-p, alpha, b( mp, np ), ldb,
     $               b( mp, i ), 1, zero, t( np, i ), 1 )
*
*        B1
*
         CALL dgemv( 'T', m-l, i-1, alpha, b, ldb, b( 1, i ), 1,
     $               one, t( 1, i ), 1 )
*
*        T(1:I-1,I) := T(1:I-1,1:I-1) * T(1:I-1,I)
*
         CALL dtrmv( 'U', 'N', 'N', i-1, t, ldt, t( 1, i ), 1 )
*
*        T(I,I) = tau(I)
*
         t( i, i ) = t( i, 1 )
         t( i, 1 ) = zero
      END DO
 
*
*     End of DTPQRT2
*

Here is the call graph for this function:

Here is the caller graph for this function: