slartgs()

subroutine slartgs	(	real	x,
		real	y,
		real	sigma,
		real	cs,
		real	sn )

SLARTGS generates a plane rotation designed to introduce a bulge in implicit QR iteration for the bidiagonal SVD problem.

Download SLARTGS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SLARTGS generates a plane rotation designed to introduce a bulge in
!> Golub-Reinsch-style implicit QR iteration for the bidiagonal SVD
!> problem. X and Y are the top-row entries, and SIGMA is the shift.
!> The computed CS and SN define a plane rotation satisfying
!>
!>    [  CS  SN  ]  .  [ X^2 - SIGMA ]  =  [ R ],
!>    [ -SN  CS  ]     [    X * Y    ]     [ 0 ]
!>
!> with R nonnegative.  If X^2 - SIGMA and X * Y are 0, then the
!> rotation is by PI/2.
!> 

Parameters

[in]	X	!> X is REAL !> The (1,1) entry of an upper bidiagonal matrix. !>
[in]	Y	!> Y is REAL !> The (1,2) entry of an upper bidiagonal matrix. !>
[in]	SIGMA	!> SIGMA is REAL !> The shift. !>
[out]	CS	!> CS is REAL !> The cosine of the rotation. !>
[out]	SN	!> SN is REAL !> The sine of the rotation. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 87 of file slartgs.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      REAL                    CS, SIGMA, SN, X, Y
*     ..
*
*  ===================================================================
*
*     .. Parameters ..
      REAL                    NEGONE, ONE, ZERO
      parameter( negone = -1.0e0, one = 1.0e0, zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      REAL                    R, S, THRESH, W, Z
*     ..
*     .. External Subroutines ..
      EXTERNAL           slartgp
*     ..
*     .. External Functions ..
      REAL                    SLAMCH
      EXTERNAL           slamch
*     .. Executable Statements ..
*
      thresh = slamch('E')
*
*     Compute the first column of B**T*B - SIGMA^2*I, up to a scale
*     factor.
*
      IF( (sigma .EQ. zero .AND. abs(x) .LT. thresh) .OR.
     $          (abs(x) .EQ. sigma .AND. y .EQ. zero) ) THEN
         z = zero
         w = zero
      ELSE IF( sigma .EQ. zero ) THEN
         IF( x .GE. zero ) THEN
            z = x
            w = y
         ELSE
            z = -x
            w = -y
         END IF
      ELSE IF( abs(x) .LT. thresh ) THEN
         z = -sigma*sigma
         w = zero
      ELSE
         IF( x .GE. zero ) THEN
            s = one
         ELSE
            s = negone
         END IF
         z = s * (abs(x)-sigma) * (s+sigma/x)
         w = s * y
      END IF
*
*     Generate the rotation.
*     CALL SLARTGP( Z, W, CS, SN, R ) might seem more natural;
*     reordering the arguments ensures that if Z = 0 then the rotation
*     is by PI/2.
*
      CALL slartgp( w, z, sn, cs, r )
*
      RETURN
*
*     End SLARTGS
*

Here is the call graph for this function:

Here is the caller graph for this function: