LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
chpgvd.f
Go to the documentation of this file.
1*> \brief \b CHPGVD
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download CHPGVD + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chpgvd.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chpgvd.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chpgvd.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE CHPGVD( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
22* LWORK, RWORK, LRWORK, IWORK, LIWORK, INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER JOBZ, UPLO
26* INTEGER INFO, ITYPE, LDZ, LIWORK, LRWORK, LWORK, N
27* ..
28* .. Array Arguments ..
29* INTEGER IWORK( * )
30* REAL RWORK( * ), W( * )
31* COMPLEX AP( * ), BP( * ), WORK( * ), Z( LDZ, * )
32* ..
33*
34*
35*> \par Purpose:
36* =============
37*>
38*> \verbatim
39*>
40*> CHPGVD computes all the eigenvalues and, optionally, the eigenvectors
41*> of a complex generalized Hermitian-definite eigenproblem, of the form
42*> A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x. Here A and
43*> B are assumed to be Hermitian, stored in packed format, and B is also
44*> positive definite.
45*> If eigenvectors are desired, it uses a divide and conquer algorithm.
46*>
47*> The divide and conquer algorithm makes very mild assumptions about
48*> floating point arithmetic. It will work on machines with a guard
49*> digit in add/subtract, or on those binary machines without guard
50*> digits which subtract like the Cray X-MP, Cray Y-MP, Cray C-90, or
51*> Cray-2. It could conceivably fail on hexadecimal or decimal machines
52*> without guard digits, but we know of none.
53*> \endverbatim
54*
55* Arguments:
56* ==========
57*
58*> \param[in] ITYPE
59*> \verbatim
60*> ITYPE is INTEGER
61*> Specifies the problem type to be solved:
62*> = 1: A*x = (lambda)*B*x
63*> = 2: A*B*x = (lambda)*x
64*> = 3: B*A*x = (lambda)*x
65*> \endverbatim
66*>
67*> \param[in] JOBZ
68*> \verbatim
69*> JOBZ is CHARACTER*1
70*> = 'N': Compute eigenvalues only;
71*> = 'V': Compute eigenvalues and eigenvectors.
72*> \endverbatim
73*>
74*> \param[in] UPLO
75*> \verbatim
76*> UPLO is CHARACTER*1
77*> = 'U': Upper triangles of A and B are stored;
78*> = 'L': Lower triangles of A and B are stored.
79*> \endverbatim
80*>
81*> \param[in] N
82*> \verbatim
83*> N is INTEGER
84*> The order of the matrices A and B. N >= 0.
85*> \endverbatim
86*>
87*> \param[in,out] AP
88*> \verbatim
89*> AP is COMPLEX array, dimension (N*(N+1)/2)
90*> On entry, the upper or lower triangle of the Hermitian matrix
91*> A, packed columnwise in a linear array. The j-th column of A
92*> is stored in the array AP as follows:
93*> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
94*> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
95*>
96*> On exit, the contents of AP are destroyed.
97*> \endverbatim
98*>
99*> \param[in,out] BP
100*> \verbatim
101*> BP is COMPLEX array, dimension (N*(N+1)/2)
102*> On entry, the upper or lower triangle of the Hermitian matrix
103*> B, packed columnwise in a linear array. The j-th column of B
104*> is stored in the array BP as follows:
105*> if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
106*> if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
107*>
108*> On exit, the triangular factor U or L from the Cholesky
109*> factorization B = U**H*U or B = L*L**H, in the same storage
110*> format as B.
111*> \endverbatim
112*>
113*> \param[out] W
114*> \verbatim
115*> W is REAL array, dimension (N)
116*> If INFO = 0, the eigenvalues in ascending order.
117*> \endverbatim
118*>
119*> \param[out] Z
120*> \verbatim
121*> Z is COMPLEX array, dimension (LDZ, N)
122*> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
123*> eigenvectors. The eigenvectors are normalized as follows:
124*> if ITYPE = 1 or 2, Z**H*B*Z = I;
125*> if ITYPE = 3, Z**H*inv(B)*Z = I.
126*> If JOBZ = 'N', then Z is not referenced.
127*> \endverbatim
128*>
129*> \param[in] LDZ
130*> \verbatim
131*> LDZ is INTEGER
132*> The leading dimension of the array Z. LDZ >= 1, and if
133*> JOBZ = 'V', LDZ >= max(1,N).
134*> \endverbatim
135*>
136*> \param[out] WORK
137*> \verbatim
138*> WORK is COMPLEX array, dimension (MAX(1,LWORK))
139*> On exit, if INFO = 0, WORK(1) returns the required LWORK.
140*> \endverbatim
141*>
142*> \param[in] LWORK
143*> \verbatim
144*> LWORK is INTEGER
145*> The dimension of array WORK.
146*> If N <= 1, LWORK >= 1.
147*> If JOBZ = 'N' and N > 1, LWORK >= N.
148*> If JOBZ = 'V' and N > 1, LWORK >= 2*N.
149*>
150*> If LWORK = -1, then a workspace query is assumed; the routine
151*> only calculates the required sizes of the WORK, RWORK and
152*> IWORK arrays, returns these values as the first entries of
153*> the WORK, RWORK and IWORK arrays, and no error message
154*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
155*> \endverbatim
156*>
157*> \param[out] RWORK
158*> \verbatim
159*> RWORK is REAL array, dimension (MAX(1,LRWORK))
160*> On exit, if INFO = 0, RWORK(1) returns the required LRWORK.
161*> \endverbatim
162*>
163*> \param[in] LRWORK
164*> \verbatim
165*> LRWORK is INTEGER
166*> The dimension of array RWORK.
167*> If N <= 1, LRWORK >= 1.
168*> If JOBZ = 'N' and N > 1, LRWORK >= N.
169*> If JOBZ = 'V' and N > 1, LRWORK >= 1 + 5*N + 2*N**2.
170*>
171*> If LRWORK = -1, then a workspace query is assumed; the
172*> routine only calculates the required sizes of the WORK, RWORK
173*> and IWORK arrays, returns these values as the first entries
174*> of the WORK, RWORK and IWORK arrays, and no error message
175*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
176*> \endverbatim
177*>
178*> \param[out] IWORK
179*> \verbatim
180*> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
181*> On exit, if INFO = 0, IWORK(1) returns the required LIWORK.
182*> \endverbatim
183*>
184*> \param[in] LIWORK
185*> \verbatim
186*> LIWORK is INTEGER
187*> The dimension of array IWORK.
188*> If JOBZ = 'N' or N <= 1, LIWORK >= 1.
189*> If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
190*>
191*> If LIWORK = -1, then a workspace query is assumed; the
192*> routine only calculates the required sizes of the WORK, RWORK
193*> and IWORK arrays, returns these values as the first entries
194*> of the WORK, RWORK and IWORK arrays, and no error message
195*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
196*> \endverbatim
197*>
198*> \param[out] INFO
199*> \verbatim
200*> INFO is INTEGER
201*> = 0: successful exit
202*> < 0: if INFO = -i, the i-th argument had an illegal value
203*> > 0: CPPTRF or CHPEVD returned an error code:
204*> <= N: if INFO = i, CHPEVD failed to converge;
205*> i off-diagonal elements of an intermediate
206*> tridiagonal form did not convergeto zero;
207*> > N: if INFO = N + i, for 1 <= i <= n, then the leading
208*> minor of order i of B is not positive definite.
209*> The factorization of B could not be completed and
210*> no eigenvalues or eigenvectors were computed.
211*> \endverbatim
212*
213* Authors:
214* ========
215*
216*> \author Univ. of Tennessee
217*> \author Univ. of California Berkeley
218*> \author Univ. of Colorado Denver
219*> \author NAG Ltd.
220*
221*> \ingroup complexOTHEReigen
222*
223*> \par Contributors:
224* ==================
225*>
226*> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
227*
228* =====================================================================
229 SUBROUTINE chpgvd( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
230 $ LWORK, RWORK, LRWORK, IWORK, LIWORK, INFO )
231*
232* -- LAPACK driver routine --
233* -- LAPACK is a software package provided by Univ. of Tennessee, --
234* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
235*
236* .. Scalar Arguments ..
237 CHARACTER JOBZ, UPLO
238 INTEGER INFO, ITYPE, LDZ, LIWORK, LRWORK, LWORK, N
239* ..
240* .. Array Arguments ..
241 INTEGER IWORK( * )
242 REAL RWORK( * ), W( * )
243 COMPLEX AP( * ), BP( * ), WORK( * ), Z( LDZ, * )
244* ..
245*
246* =====================================================================
247*
248* .. Local Scalars ..
249 LOGICAL LQUERY, UPPER, WANTZ
250 CHARACTER TRANS
251 INTEGER J, LIWMIN, LRWMIN, LWMIN, NEIG
252* ..
253* .. External Functions ..
254 LOGICAL LSAME
255 EXTERNAL lsame
256* ..
257* .. External Subroutines ..
258 EXTERNAL chpevd, chpgst, cpptrf, ctpmv, ctpsv, xerbla
259* ..
260* .. Intrinsic Functions ..
261 INTRINSIC max, real
262* ..
263* .. Executable Statements ..
264*
265* Test the input parameters.
266*
267 wantz = lsame( jobz, 'V' )
268 upper = lsame( uplo, 'U' )
269 lquery = ( lwork.EQ.-1 .OR. lrwork.EQ.-1 .OR. liwork.EQ.-1 )
270*
271 info = 0
272 IF( itype.LT.1 .OR. itype.GT.3 ) THEN
273 info = -1
274 ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
275 info = -2
276 ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
277 info = -3
278 ELSE IF( n.LT.0 ) THEN
279 info = -4
280 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
281 info = -9
282 END IF
283*
284 IF( info.EQ.0 ) THEN
285 IF( n.LE.1 ) THEN
286 lwmin = 1
287 liwmin = 1
288 lrwmin = 1
289 ELSE
290 IF( wantz ) THEN
291 lwmin = 2*n
292 lrwmin = 1 + 5*n + 2*n**2
293 liwmin = 3 + 5*n
294 ELSE
295 lwmin = n
296 lrwmin = n
297 liwmin = 1
298 END IF
299 END IF
300*
301 work( 1 ) = lwmin
302 rwork( 1 ) = lrwmin
303 iwork( 1 ) = liwmin
304 IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
305 info = -11
306 ELSE IF( lrwork.LT.lrwmin .AND. .NOT.lquery ) THEN
307 info = -13
308 ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
309 info = -15
310 END IF
311 END IF
312*
313 IF( info.NE.0 ) THEN
314 CALL xerbla( 'CHPGVD', -info )
315 RETURN
316 ELSE IF( lquery ) THEN
317 RETURN
318 END IF
319*
320* Quick return if possible
321*
322 IF( n.EQ.0 )
323 $ RETURN
324*
325* Form a Cholesky factorization of B.
326*
327 CALL cpptrf( uplo, n, bp, info )
328 IF( info.NE.0 ) THEN
329 info = n + info
330 RETURN
331 END IF
332*
333* Transform problem to standard eigenvalue problem and solve.
334*
335 CALL chpgst( itype, uplo, n, ap, bp, info )
336 CALL chpevd( jobz, uplo, n, ap, w, z, ldz, work, lwork, rwork,
337 $ lrwork, iwork, liwork, info )
338 lwmin = int( max( real( lwmin ), real( work( 1 ) ) ) )
339 lrwmin = int( max( real( lrwmin ), real( rwork( 1 ) ) ) )
340 liwmin = int( max( real( liwmin ), real( iwork( 1 ) ) ) )
341*
342 IF( wantz ) THEN
343*
344* Backtransform eigenvectors to the original problem.
345*
346 neig = n
347 IF( info.GT.0 )
348 $ neig = info - 1
349 IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
350*
351* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
352* backtransform eigenvectors: x = inv(L)**H *y or inv(U)*y
353*
354 IF( upper ) THEN
355 trans = 'N'
356 ELSE
357 trans = 'C'
358 END IF
359*
360 DO 10 j = 1, neig
361 CALL ctpsv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
362 $ 1 )
363 10 CONTINUE
364*
365 ELSE IF( itype.EQ.3 ) THEN
366*
367* For B*A*x=(lambda)*x;
368* backtransform eigenvectors: x = L*y or U**H *y
369*
370 IF( upper ) THEN
371 trans = 'C'
372 ELSE
373 trans = 'N'
374 END IF
375*
376 DO 20 j = 1, neig
377 CALL ctpmv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
378 $ 1 )
379 20 CONTINUE
380 END IF
381 END IF
382*
383 work( 1 ) = lwmin
384 rwork( 1 ) = lrwmin
385 iwork( 1 ) = liwmin
386 RETURN
387*
388* End of CHPGVD
389*
390 END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine ctpsv(UPLO, TRANS, DIAG, N, AP, X, INCX)
CTPSV
Definition: ctpsv.f:144
subroutine ctpmv(UPLO, TRANS, DIAG, N, AP, X, INCX)
CTPMV
Definition: ctpmv.f:142
subroutine cpptrf(UPLO, N, AP, INFO)
CPPTRF
Definition: cpptrf.f:119
subroutine chpgst(ITYPE, UPLO, N, AP, BP, INFO)
CHPGST
Definition: chpgst.f:113
subroutine chpgvd(ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK, LWORK, RWORK, LRWORK, IWORK, LIWORK, INFO)
CHPGVD
Definition: chpgvd.f:231
subroutine chpevd(JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK, RWORK, LRWORK, IWORK, LIWORK, INFO)
CHPEVD computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrice...
Definition: chpevd.f:200