cheequb()

subroutine cheequb	(	character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	s,
		real	scond,
		real	amax,
		complex, dimension( * )	work,
		integer	info )

CHEEQUB

Download CHEEQUB + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CHEEQUB computes row and column scalings intended to equilibrate a
!> Hermitian matrix A (with respect to the Euclidean norm) and reduce
!> its condition number. The scale factors S are computed by the BIN
!> algorithm (see references) so that the scaled matrix B with elements
!> B(i,j) = S(i)*A(i,j)*S(j) has a condition number within a factor N of
!> the smallest possible condition number over all possible diagonal
!> scalings.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangle of A is stored; !> = 'L': Lower triangle of A is stored. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	A	!> A is COMPLEX array, dimension (LDA,N) !> The N-by-N Hermitian matrix whose scaling factors are to be !> computed. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	S	!> S is REAL array, dimension (N) !> If INFO = 0, S contains the scale factors for A. !>
[out]	SCOND	!> SCOND is REAL !> If INFO = 0, S contains the ratio of the smallest S(i) to !> the largest S(i). If SCOND >= 0.1 and AMAX is neither too !> large nor too small, it is not worth scaling by S. !>
[out]	AMAX	!> AMAX is REAL !> Largest absolute value of any matrix element. If AMAX is !> very close to overflow or very close to underflow, the !> matrix should be scaled. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (2*N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, the i-th diagonal element is nonpositive. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

References:

Livne, O.E. and Golub, G.H., "Scaling by Binormalization",
Numerical Algorithms, vol. 35, no. 1, pp. 97-120, January 2004.
DOI 10.1023/B:NUMA.0000016606.32820.69
Tech report version: http://citeseerx.ist.psu.edu/viewdoc/summary?doi=10.1.1.3.1679

Definition at line 129 of file cheequb.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, N
      REAL               AMAX, SCOND
      CHARACTER          UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), WORK( * )
      REAL               S( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e0, zero = 0.0e0 )
      INTEGER            MAX_ITER
      parameter( max_iter = 100 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, ITER
      REAL               AVG, STD, TOL, C0, C1, C2, T, U, SI, D, BASE,
     $                   SMIN, SMAX, SMLNUM, BIGNUM, SCALE, SUMSQ
      LOGICAL            UP
      COMPLEX            ZDUM
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      LOGICAL            LSAME
      EXTERNAL           lsame, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           classq, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, int, log, max, min, real, sqrt
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF ( .NOT. ( lsame( uplo, 'U' ) .OR.
     $     lsame( uplo, 'L' ) ) ) THEN
         info = -1
      ELSE IF ( n .LT. 0 ) THEN
         info = -2
      ELSE IF ( lda .LT. max( 1, n ) ) THEN
         info = -4
      END IF
      IF ( info .NE. 0 ) THEN
         CALL xerbla( 'CHEEQUB', -info )
         RETURN
      END IF
 
      up = lsame( uplo, 'U' )
      amax = zero
*
*     Quick return if possible.
*
      IF ( n .EQ. 0 ) THEN
         scond = one
         RETURN
      END IF
 
      DO i = 1, n
         s( i ) = zero
      END DO
 
      amax = zero
      IF ( up ) THEN
         DO j = 1, n
            DO i = 1, j-1
               s( i ) = max( s( i ), cabs1( a( i, j ) ) )
               s( j ) = max( s( j ), cabs1( a( i, j ) ) )
               amax = max( amax, cabs1( a( i, j ) ) )
            END DO
            s( j ) = max( s( j ), cabs1( a( j, j ) ) )
            amax = max( amax, cabs1( a( j, j ) ) )
         END DO
      ELSE
         DO j = 1, n
            s( j ) = max( s( j ), cabs1( a( j, j ) ) )
            amax = max( amax, cabs1( a( j, j ) ) )
            DO i = j+1, n
               s( i ) = max( s( i ), cabs1( a( i, j ) ) )
               s( j ) = max( s( j ), cabs1( a( i, j ) ) )
               amax = max( amax, cabs1( a( i, j ) ) )
            END DO
         END DO
      END IF
      DO j = 1, n
         s( j ) = 1.0e0 / s( j )
      END DO
 
      tol = one / sqrt( 2.0e0 * real( n ) )
 
      DO iter = 1, max_iter
         scale = 0.0e0
         sumsq = 0.0e0
*        beta = |A|s
         DO i = 1, n
            work( i ) = zero
         END DO
         IF ( up ) THEN
            DO j = 1, n
               DO i = 1, j-1
                  work( i ) = work( i ) + cabs1( a( i, j ) ) * s( j )
                  work( j ) = work( j ) + cabs1( a( i, j ) ) * s( i )
               END DO
               work( j ) = work( j ) + cabs1( a( j, j ) ) * s( j )
            END DO
         ELSE
            DO j = 1, n
               work( j ) = work( j ) + cabs1( a( j, j ) ) * s( j )
               DO i = j+1, n
                  work( i ) = work( i ) + cabs1( a( i, j ) ) * s( j )
                  work( j ) = work( j ) + cabs1( a( i, j ) ) * s( i )
               END DO
            END DO
         END IF
 
*        avg = s^T beta / n
         avg = 0.0e0
         DO i = 1, n
            avg = avg + real( s( i )*work( i ) )
         END DO
         avg = avg / real( n )
 
         std = 0.0e0
         DO i = n+1, 2*n
            work( i ) = s( i-n ) * work( i-n ) - avg
         END DO
         CALL classq( n, work( n+1 ), 1, scale, sumsq )
         std = scale * sqrt( sumsq / real( n ) )
 
         IF ( std .LT. tol * avg ) GOTO 999
 
         DO i = 1, n
            t = cabs1( a( i, i ) )
            si = s( i )
            c2 = real( n-1 ) * t
            c1 = real( n-2 ) * ( real( work( i ) ) - t*si )
            c0 = real( -(t*si)*si + 2*work( i )*si - real( n )*avg )
            d = c1*c1 - 4*c0*c2
 
            IF ( d .LE. 0 ) THEN
               info = -1
               RETURN
            END IF
            si = -2*c0 / ( c1 + sqrt( d ) )
 
            d = si - s( i )
            u = zero
            IF ( up ) THEN
               DO j = 1, i
                  t = cabs1( a( j, i ) )
                  u = u + s( j )*t
                  work( j ) = work( j ) + d*t
               END DO
               DO j = i+1,n
                  t = cabs1( a( i, j ) )
                  u = u + s( j )*t
                  work( j ) = work( j ) + d*t
               END DO
            ELSE
               DO j = 1, i
                  t = cabs1( a( i, j ) )
                  u = u + s( j )*t
                  work( j ) = work( j ) + d*t
               END DO
               DO j = i+1,n
                  t = cabs1( a( j, i ) )
                  u = u + s( j )*t
                  work( j ) = work( j ) + d*t
               END DO
            END IF
 
            avg = avg + ( u + real( work( i ) ) ) * d / real( n )
            s( i ) = si
         END DO
      END DO
 
 999  CONTINUE
 
      smlnum = slamch( 'SAFEMIN' )
      bignum = one / smlnum
      smin = bignum
      smax = zero
      t = one / sqrt( avg )
      base = slamch( 'B' )
      u = one / log( base )
      DO i = 1, n
         s( i ) = base ** int( u * log( s( i ) * t ) )
         smin = min( smin, s( i ) )
         smax = max( smax, s( i ) )
      END DO
      scond = max( smin, smlnum ) / min( smax, bignum )
*

Here is the call graph for this function:

Here is the caller graph for this function: