LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
dsyt01_aa.f
Go to the documentation of this file.
1*> \brief \b DSYT01
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE DSYT01_AA( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C, LDC,
12* RWORK, RESID )
13*
14* .. Scalar Arguments ..
15* CHARACTER UPLO
16* INTEGER LDA, LDAFAC, LDC, N
17* DOUBLE PRECISION RESID
18* ..
19* .. Array Arguments ..
20* INTEGER IPIV( * )
21* DOUBLE PRECISION A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
22* $ RWORK( * )
23* ..
24*
25*
26*> \par Purpose:
27* =============
28*>
29*> \verbatim
30*>
31*> DSYT01 reconstructs a symmetric indefinite matrix A from its
32*> block L*D*L' or U*D*U' factorization and computes the residual
33*> norm( C - A ) / ( N * norm(A) * EPS ),
34*> where C is the reconstructed matrix and EPS is the machine epsilon.
35*> \endverbatim
36*
37* Arguments:
38* ==========
39*
40*> \param[in] UPLO
41*> \verbatim
42*> UPLO is CHARACTER*1
43*> Specifies whether the upper or lower triangular part of the
44*> symmetric matrix A is stored:
45*> = 'U': Upper triangular
46*> = 'L': Lower triangular
47*> \endverbatim
48*>
49*> \param[in] N
50*> \verbatim
51*> N is INTEGER
52*> The number of rows and columns of the matrix A. N >= 0.
53*> \endverbatim
54*>
55*> \param[in] A
56*> \verbatim
57*> A is DOUBLE PRECISION array, dimension (LDA,N)
58*> The original symmetric matrix A.
59*> \endverbatim
60*>
61*> \param[in] LDA
62*> \verbatim
63*> LDA is INTEGER
64*> The leading dimension of the array A. LDA >= max(1,N)
65*> \endverbatim
66*>
67*> \param[in] AFAC
68*> \verbatim
69*> AFAC is DOUBLE PRECISION array, dimension (LDAFAC,N)
70*> The factored form of the matrix A. AFAC contains the block
71*> diagonal matrix D and the multipliers used to obtain the
72*> factor L or U from the block L*D*L' or U*D*U' factorization
73*> as computed by DSYTRF.
74*> \endverbatim
75*>
76*> \param[in] LDAFAC
77*> \verbatim
78*> LDAFAC is INTEGER
79*> The leading dimension of the array AFAC. LDAFAC >= max(1,N).
80*> \endverbatim
81*>
82*> \param[in] IPIV
83*> \verbatim
84*> IPIV is INTEGER array, dimension (N)
85*> The pivot indices from DSYTRF.
86*> \endverbatim
87*>
88*> \param[out] C
89*> \verbatim
90*> C is DOUBLE PRECISION array, dimension (LDC,N)
91*> \endverbatim
92*>
93*> \param[in] LDC
94*> \verbatim
95*> LDC is INTEGER
96*> The leading dimension of the array C. LDC >= max(1,N).
97*> \endverbatim
98*>
99*> \param[out] RWORK
100*> \verbatim
101*> RWORK is DOUBLE PRECISION array, dimension (N)
102*> \endverbatim
103*>
104*> \param[out] RESID
105*> \verbatim
106*> RESID is DOUBLE PRECISION
107*> If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
108*> If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
109*> \endverbatim
110*
111* Authors:
112* ========
113*
114*> \author Univ. of Tennessee
115*> \author Univ. of California Berkeley
116*> \author Univ. of Colorado Denver
117*> \author NAG Ltd.
118*
119*> \ingroup double_lin
120*
121* =====================================================================
122 SUBROUTINE dsyt01_aa( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C,
123 $ LDC, RWORK, RESID )
124*
125* -- LAPACK test routine --
126* -- LAPACK is a software package provided by Univ. of Tennessee, --
127* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128*
129* .. Scalar Arguments ..
130 CHARACTER UPLO
131 INTEGER LDA, LDAFAC, LDC, N
132 DOUBLE PRECISION RESID
133* ..
134* .. Array Arguments ..
135 INTEGER IPIV( * )
136 DOUBLE PRECISION A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
137 $ rwork( * )
138* ..
139*
140* =====================================================================
141*
142* .. Parameters ..
143 DOUBLE PRECISION ZERO, ONE
144 parameter( zero = 0.0d+0, one = 1.0d+0 )
145* ..
146* .. Local Scalars ..
147 INTEGER I, J
148 DOUBLE PRECISION ANORM, EPS
149* ..
150* .. External Functions ..
151 LOGICAL LSAME
152 DOUBLE PRECISION DLAMCH, DLANSY
153 EXTERNAL lsame, dlamch, dlansy
154* ..
155* .. External Subroutines ..
156 EXTERNAL dlaset, dlavsy
157* ..
158* .. Intrinsic Functions ..
159 INTRINSIC dble
160* ..
161* .. Executable Statements ..
162*
163* Quick exit if N = 0.
164*
165 IF( n.LE.0 ) THEN
166 resid = zero
167 RETURN
168 END IF
169*
170* Determine EPS and the norm of A.
171*
172 eps = dlamch( 'Epsilon' )
173 anorm = dlansy( '1', uplo, n, a, lda, rwork )
174*
175* Initialize C to the tridiagonal matrix T.
176*
177 CALL dlaset( 'Full', n, n, zero, zero, c, ldc )
178 CALL dlacpy( 'F', 1, n, afac( 1, 1 ), ldafac+1, c( 1, 1 ), ldc+1 )
179 IF( n.GT.1 ) THEN
180 IF( lsame( uplo, 'U' ) ) THEN
181 CALL dlacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 1, 2 ),
182 $ ldc+1 )
183 CALL dlacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 2, 1 ),
184 $ ldc+1 )
185 ELSE
186 CALL dlacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 1, 2 ),
187 $ ldc+1 )
188 CALL dlacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 2, 1 ),
189 $ ldc+1 )
190 ENDIF
191*
192* Call DTRMM to form the product U' * D (or L * D ).
193*
194 IF( lsame( uplo, 'U' ) ) THEN
195 CALL dtrmm( 'Left', uplo, 'Transpose', 'Unit', n-1, n,
196 $ one, afac( 1, 2 ), ldafac, c( 2, 1 ), ldc )
197 ELSE
198 CALL dtrmm( 'Left', uplo, 'No transpose', 'Unit', n-1, n,
199 $ one, afac( 2, 1 ), ldafac, c( 2, 1 ), ldc )
200 END IF
201*
202* Call DTRMM again to multiply by U (or L ).
203*
204 IF( lsame( uplo, 'U' ) ) THEN
205 CALL dtrmm( 'Right', uplo, 'No transpose', 'Unit', n, n-1,
206 $ one, afac( 1, 2 ), ldafac, c( 1, 2 ), ldc )
207 ELSE
208 CALL dtrmm( 'Right', uplo, 'Transpose', 'Unit', n, n-1,
209 $ one, afac( 2, 1 ), ldafac, c( 1, 2 ), ldc )
210 END IF
211 ENDIF
212*
213* Apply symmetric pivots
214*
215 DO j = n, 1, -1
216 i = ipiv( j )
217 IF( i.NE.j )
218 $ CALL dswap( n, c( j, 1 ), ldc, c( i, 1 ), ldc )
219 END DO
220 DO j = n, 1, -1
221 i = ipiv( j )
222 IF( i.NE.j )
223 $ CALL dswap( n, c( 1, j ), 1, c( 1, i ), 1 )
224 END DO
225*
226*
227* Compute the difference C - A .
228*
229 IF( lsame( uplo, 'U' ) ) THEN
230 DO j = 1, n
231 DO i = 1, j
232 c( i, j ) = c( i, j ) - a( i, j )
233 END DO
234 END DO
235 ELSE
236 DO j = 1, n
237 DO i = j, n
238 c( i, j ) = c( i, j ) - a( i, j )
239 END DO
240 END DO
241 END IF
242*
243* Compute norm( C - A ) / ( N * norm(A) * EPS )
244*
245 resid = dlansy( '1', uplo, n, c, ldc, rwork )
246*
247 IF( anorm.LE.zero ) THEN
248 IF( resid.NE.zero )
249 $ resid = one / eps
250 ELSE
251 resid = ( ( resid / dble( n ) ) / anorm ) / eps
252 END IF
253*
254 RETURN
255*
256* End of DSYT01_AA
257*
258 END
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:103
subroutine dlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: dlaset.f:110
subroutine dswap(N, DX, INCX, DY, INCY)
DSWAP
Definition: dswap.f:82
subroutine dtrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
DTRMM
Definition: dtrmm.f:177
subroutine dlavsy(UPLO, TRANS, DIAG, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
DLAVSY
Definition: dlavsy.f:155
subroutine dsyt01_aa(UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C, LDC, RWORK, RESID)
DSYT01
Definition: dsyt01_aa.f:124