cpst01.f

Go to the documentation of this file.

*> \brief \b CPST01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CPST01( UPLO, N, A, LDA, AFAC, LDAFAC, PERM, LDPERM,
*                          PIV, RWORK, RESID, RANK )
*
*       .. Scalar Arguments ..
*       REAL               RESID
*       INTEGER            LDA, LDAFAC, LDPERM, N, RANK
*       CHARACTER          UPLO
*       ..
*       .. Array Arguments ..
*       COMPLEX            A( LDA, * ), AFAC( LDAFAC, * ),
*      $                   PERM( LDPERM, * )
*       REAL               RWORK( * )
*       INTEGER            PIV( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CPST01 reconstructs an Hermitian positive semidefinite matrix A
*> from its L or U factors and the permutation matrix P and computes
*> the residual
*>    norm( P*L*L'*P' - A ) / ( N * norm(A) * EPS ) or
*>    norm( P*U'*U*P' - A ) / ( N * norm(A) * EPS ),
*> where EPS is the machine epsilon, L' is the conjugate transpose of L,
*> and U' is the conjugate transpose of U.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          Hermitian matrix A is stored:
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows and columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          The original Hermitian matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N)
*> \endverbatim
*>
*> \param[in] AFAC
*> \verbatim
*>          AFAC is COMPLEX array, dimension (LDAFAC,N)
*>          The factor L or U from the L*L' or U'*U
*>          factorization of A.
*> \endverbatim
*>
*> \param[in] LDAFAC
*> \verbatim
*>          LDAFAC is INTEGER
*>          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
*> \endverbatim
*>
*> \param[out] PERM
*> \verbatim
*>          PERM is COMPLEX array, dimension (LDPERM,N)
*>          Overwritten with the reconstructed matrix, and then with the
*>          difference P*L*L'*P' - A (or P*U'*U*P' - A)
*> \endverbatim
*>
*> \param[in] LDPERM
*> \verbatim
*>          LDPERM is INTEGER
*>          The leading dimension of the array PERM.
*>          LDAPERM >= max(1,N).
*> \endverbatim
*>
*> \param[in] PIV
*> \verbatim
*>          PIV is INTEGER array, dimension (N)
*>          PIV is such that the nonzero entries are
*>          P( PIV( K ), K ) = 1.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (N)
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*>          RESID is REAL
*>          If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS )
*>          If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )
*> \endverbatim
*>
*> \param[in] RANK
*> \verbatim
*>          RANK is INTEGER
*>          number of nonzero singular values of A.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cpst01( UPLO, N, A, LDA, AFAC, LDAFAC, PERM, LDPERM,
     $                   PIV, RWORK, RESID, RANK )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      REAL               RESID
      INTEGER            LDA, LDAFAC, LDPERM, N, RANK
      CHARACTER          UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), AFAC( LDAFAC, * ),
     $                   perm( ldperm, * )
      REAL               RWORK( * )
      INTEGER            PIV( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      COMPLEX            TC
      REAL               ANORM, EPS, TR
      INTEGER            I, J, K
*     ..
*     .. External Functions ..
      COMPLEX            CDOTC
      REAL               CLANHE, SLAMCH
      LOGICAL            LSAME
      EXTERNAL           cdotc, clanhe, slamch, lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cher, cscal, ctrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, conjg, real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = clanhe( '1', uplo, n, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      DO 100 j = 1, n
         IF( aimag( afac( j, j ) ).NE.zero ) THEN
            resid = one / eps
            RETURN
         END IF
  100 CONTINUE
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
*
         IF( rank.LT.n ) THEN
            DO 120 j = rank + 1, n
               DO 110 i = rank + 1, j
                  afac( i, j ) = czero
  110          CONTINUE
  120       CONTINUE
         END IF
*
         DO 130 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            tr = real( cdotc( k, afac( 1, k ), 1, afac( 1, k ), 1 ) )
            afac( k, k ) = tr
*
*           Compute the rest of column K.
*
            CALL ctrmv( 'Upper', 'Conjugate', 'Non-unit', k-1, afac,
     $                  ldafac, afac( 1, k ), 1 )
*
  130    CONTINUE
*
*     Compute the product L*L', overwriting L.
*
      ELSE
*
         IF( rank.LT.n ) THEN
            DO 150 j = rank + 1, n
               DO 140 i = j, n
                  afac( i, j ) = czero
  140          CONTINUE
  150       CONTINUE
         END IF
*
         DO 160 k = n, 1, -1
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k+1.LE.n )
     $         CALL cher( 'Lower', n-k, one, afac( k+1, k ), 1,
     $                    afac( k+1, k+1 ), ldafac )
*
*           Scale column K by the diagonal element.
*
            tc = afac( k, k )
            CALL cscal( n-k+1, tc, afac( k, k ), 1 )
  160    CONTINUE
*
      END IF
*
*        Form P*L*L'*P' or P*U'*U*P'
*
      IF( lsame( uplo, 'U' ) ) THEN
*
         DO 180 j = 1, n
            DO 170 i = 1, n
               IF( piv( i ).LE.piv( j ) ) THEN
                  IF( i.LE.j ) THEN
                     perm( piv( i ), piv( j ) ) = afac( i, j )
                  ELSE
                     perm( piv( i ), piv( j ) ) = conjg( afac( j, i ) )
                  END IF
               END IF
  170       CONTINUE
  180    CONTINUE
*
*
      ELSE
*
         DO 200 j = 1, n
            DO 190 i = 1, n
               IF( piv( i ).GE.piv( j ) ) THEN
                  IF( i.GE.j ) THEN
                     perm( piv( i ), piv( j ) ) = afac( i, j )
                  ELSE
                     perm( piv( i ), piv( j ) ) = conjg( afac( j, i ) )
                  END IF
               END IF
  190       CONTINUE
  200    CONTINUE
*
      END IF
*
*     Compute the difference  P*L*L'*P' - A (or P*U'*U*P' - A).
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 220 j = 1, n
            DO 210 i = 1, j - 1
               perm( i, j ) = perm( i, j ) - a( i, j )
  210       CONTINUE
            perm( j, j ) = perm( j, j ) - real( a( j, j ) )
  220    CONTINUE
      ELSE
         DO 240 j = 1, n
            perm( j, j ) = perm( j, j ) - real( a( j, j ) )
            DO 230 i = j + 1, n
               perm( i, j ) = perm( i, j ) - a( i, j )
  230       CONTINUE
  240    CONTINUE
      END IF
*
*     Compute norm( P*L*L'P - A ) / ( N * norm(A) * EPS ), or
*     ( P*U'*U*P' - A )/ ( N * norm(A) * EPS ).
*
      resid = clanhe( '1', uplo, n, perm, ldafac, rwork )
*
      resid = ( ( resid / real( n ) ) / anorm ) / eps
*
      RETURN
*
*     End of CPST01
*
      END