strrfs()

subroutine strrfs	(	character	uplo,
		character	trans,
		character	diag,
		integer	n,
		integer	nrhs,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( ldx, * )	x,
		integer	ldx,
		real, dimension( * )	ferr,
		real, dimension( * )	berr,
		real, dimension( * )	work,
		integer, dimension( * )	iwork,
		integer	info
	)

STRRFS

Download STRRFS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 STRRFS provides error bounds and backward error estimates for the
 solution to a system of linear equations with a triangular
 coefficient matrix.

 The solution matrix X must be computed by STRTRS or some other
 means before entering this routine.  STRRFS does not do iterative
 refinement because doing so cannot improve the backward error.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': A is upper triangular; = 'L': A is lower triangular.
[in]	TRANS	TRANS is CHARACTER*1 Specifies the form of the system of equations: = 'N': A * X = B (No transpose) = 'T': A**T * X = B (Transpose) = 'C': A**H * X = B (Conjugate transpose = Transpose)
[in]	DIAG	DIAG is CHARACTER*1 = 'N': A is non-unit triangular; = 'U': A is unit triangular.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices B and X. NRHS >= 0.
[in]	A	A is REAL array, dimension (LDA,N) The triangular matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of the array A contains the upper triangular matrix, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of the array A contains the lower triangular matrix, and the strictly upper triangular part of A is not referenced. If DIAG = 'U', the diagonal elements of A are also not referenced and are assumed to be 1.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	B	B is REAL array, dimension (LDB,NRHS) The right hand side matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[in]	X	X is REAL array, dimension (LDX,NRHS) The solution matrix X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).
[out]	FERR	FERR is REAL array, dimension (NRHS) The estimated forward error bound for each solution vector X(j) (the j-th column of the solution matrix X). If XTRUE is the true solution corresponding to X(j), FERR(j) is an estimated upper bound for the magnitude of the largest element in (X(j) - XTRUE) divided by the magnitude of the largest element in X(j). The estimate is as reliable as the estimate for RCOND, and is almost always a slight overestimate of the true error.
[out]	BERR	BERR is REAL array, dimension (NRHS) The componentwise relative backward error of each solution vector X(j) (i.e., the smallest relative change in any element of A or B that makes X(j) an exact solution).
[out]	WORK	WORK is REAL array, dimension (3*N)
[out]	IWORK	IWORK is INTEGER array, dimension (N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 180 of file strrfs.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, TRANS, UPLO
      INTEGER            INFO, LDA, LDB, LDX, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * )
      REAL               A( LDA, * ), B( LDB, * ), BERR( * ), FERR( * ),
     $                   WORK( * ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRAN, NOUNIT, UPPER
      CHARACTER          TRANST
      INTEGER            I, J, K, KASE, NZ
      REAL               EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
*     ..
*     .. Local Arrays ..
      INTEGER            ISAVE( 3 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, scopy, slacn2, strmv, strsv, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH
      EXTERNAL           lsame, slamch
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      notran = lsame( trans, 'N' )
      nounit = lsame( diag, 'N' )
*
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
     $         lsame( trans, 'C' ) ) THEN
         info = -2
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( nrhs.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -7
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -9
      ELSE IF( ldx.LT.max( 1, n ) ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'STRRFS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
         DO 10 j = 1, nrhs
            ferr( j ) = zero
            berr( j ) = zero
   10    CONTINUE
         RETURN
      END IF
*
      IF( notran ) THEN
         transt = 'T'
      ELSE
         transt = 'N'
      END IF
*
*     NZ = maximum number of nonzero elements in each row of A, plus 1
*
      nz = n + 1
      eps = slamch( 'Epsilon' )
      safmin = slamch( 'Safe minimum' )
      safe1 = nz*safmin
      safe2 = safe1 / eps
*
*     Do for each right hand side
*
      DO 250 j = 1, nrhs
*
*        Compute residual R = B - op(A) * X,
*        where op(A) = A or A**T, depending on TRANS.
*
         CALL scopy( n, x( 1, j ), 1, work( n+1 ), 1 )
         CALL strmv( uplo, trans, diag, n, a, lda, work( n+1 ), 1 )
         CALL saxpy( n, -one, b( 1, j ), 1, work( n+1 ), 1 )
*
*        Compute componentwise relative backward error from formula
*
*        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
*
*        where abs(Z) is the componentwise absolute value of the matrix
*        or vector Z.  If the i-th component of the denominator is less
*        than SAFE2, then SAFE1 is added to the i-th components of the
*        numerator and denominator before dividing.
*
         DO 20 i = 1, n
            work( i ) = abs( b( i, j ) )
   20    CONTINUE
*
         IF( notran ) THEN
*
*           Compute abs(A)*abs(X) + abs(B).
*
            IF( upper ) THEN
               IF( nounit ) THEN
                  DO 40 k = 1, n
                     xk = abs( x( k, j ) )
                     DO 30 i = 1, k
                        work( i ) = work( i ) + abs( a( i, k ) )*xk
   30                CONTINUE
   40             CONTINUE
               ELSE
                  DO 60 k = 1, n
                     xk = abs( x( k, j ) )
                     DO 50 i = 1, k - 1
                        work( i ) = work( i ) + abs( a( i, k ) )*xk
   50                CONTINUE
                     work( k ) = work( k ) + xk
   60             CONTINUE
               END IF
            ELSE
               IF( nounit ) THEN
                  DO 80 k = 1, n
                     xk = abs( x( k, j ) )
                     DO 70 i = k, n
                        work( i ) = work( i ) + abs( a( i, k ) )*xk
   70                CONTINUE
   80             CONTINUE
               ELSE
                  DO 100 k = 1, n
                     xk = abs( x( k, j ) )
                     DO 90 i = k + 1, n
                        work( i ) = work( i ) + abs( a( i, k ) )*xk
   90                CONTINUE
                     work( k ) = work( k ) + xk
  100             CONTINUE
               END IF
            END IF
         ELSE
*
*           Compute abs(A**T)*abs(X) + abs(B).
*
            IF( upper ) THEN
               IF( nounit ) THEN
                  DO 120 k = 1, n
                     s = zero
                     DO 110 i = 1, k
                        s = s + abs( a( i, k ) )*abs( x( i, j ) )
  110                CONTINUE
                     work( k ) = work( k ) + s
  120             CONTINUE
               ELSE
                  DO 140 k = 1, n
                     s = abs( x( k, j ) )
                     DO 130 i = 1, k - 1
                        s = s + abs( a( i, k ) )*abs( x( i, j ) )
  130                CONTINUE
                     work( k ) = work( k ) + s
  140             CONTINUE
               END IF
            ELSE
               IF( nounit ) THEN
                  DO 160 k = 1, n
                     s = zero
                     DO 150 i = k, n
                        s = s + abs( a( i, k ) )*abs( x( i, j ) )
  150                CONTINUE
                     work( k ) = work( k ) + s
  160             CONTINUE
               ELSE
                  DO 180 k = 1, n
                     s = abs( x( k, j ) )
                     DO 170 i = k + 1, n
                        s = s + abs( a( i, k ) )*abs( x( i, j ) )
  170                CONTINUE
                     work( k ) = work( k ) + s
  180             CONTINUE
               END IF
            END IF
         END IF
         s = zero
         DO 190 i = 1, n
            IF( work( i ).GT.safe2 ) THEN
               s = max( s, abs( work( n+i ) ) / work( i ) )
            ELSE
               s = max( s, ( abs( work( n+i ) )+safe1 ) /
     $             ( work( i )+safe1 ) )
            END IF
  190    CONTINUE
         berr( j ) = s
*
*        Bound error from formula
*
*        norm(X - XTRUE) / norm(X) .le. FERR =
*        norm( abs(inv(op(A)))*
*           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
*
*        where
*          norm(Z) is the magnitude of the largest component of Z
*          inv(op(A)) is the inverse of op(A)
*          abs(Z) is the componentwise absolute value of the matrix or
*             vector Z
*          NZ is the maximum number of nonzeros in any row of A, plus 1
*          EPS is machine epsilon
*
*        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
*        is incremented by SAFE1 if the i-th component of
*        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
*
*        Use SLACN2 to estimate the infinity-norm of the matrix
*           inv(op(A)) * diag(W),
*        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
*
         DO 200 i = 1, n
            IF( work( i ).GT.safe2 ) THEN
               work( i ) = abs( work( n+i ) ) + nz*eps*work( i )
            ELSE
               work( i ) = abs( work( n+i ) ) + nz*eps*work( i ) + safe1
            END IF
  200    CONTINUE
*
         kase = 0
  210    CONTINUE
         CALL slacn2( n, work( 2*n+1 ), work( n+1 ), iwork, ferr( j ),
     $                kase, isave )
         IF( kase.NE.0 ) THEN
            IF( kase.EQ.1 ) THEN
*
*              Multiply by diag(W)*inv(op(A)**T).
*
               CALL strsv( uplo, transt, diag, n, a, lda, work( n+1 ),
     $                     1 )
               DO 220 i = 1, n
                  work( n+i ) = work( i )*work( n+i )
  220          CONTINUE
            ELSE
*
*              Multiply by inv(op(A))*diag(W).
*
               DO 230 i = 1, n
                  work( n+i ) = work( i )*work( n+i )
  230          CONTINUE
               CALL strsv( uplo, trans, diag, n, a, lda, work( n+1 ),
     $                     1 )
            END IF
            GO TO 210
         END IF
*
*        Normalize error.
*
         lstres = zero
         DO 240 i = 1, n
            lstres = max( lstres, abs( x( i, j ) ) )
  240    CONTINUE
         IF( lstres.NE.zero )
     $      ferr( j ) = ferr( j ) / lstres
*
  250 CONTINUE
*
      RETURN
*
*     End of STRRFS
*

Here is the call graph for this function:

Here is the caller graph for this function: