crqt02()

subroutine crqt02	(	integer	m,
		integer	n,
		integer	k,
		complex, dimension( lda, * )	a,
		complex, dimension( lda, * )	af,
		complex, dimension( lda, * )	q,
		complex, dimension( lda, * )	r,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result
	)

CRQT02

Purpose:

 CRQT02 tests CUNGRQ, which generates an m-by-n matrix Q with
 orthonormal rows that is defined as the product of k elementary
 reflectors.

 Given the RQ factorization of an m-by-n matrix A, CRQT02 generates
 the orthogonal matrix Q defined by the factorization of the last k
 rows of A; it compares R(m-k+1:m,n-m+1:n) with
 A(m-k+1:m,1:n)*Q(n-m+1:n,1:n)', and checks that the rows of Q are
 orthonormal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q to be generated. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q to be generated. N >= M >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A which was factorized by CRQT01.
[in]	AF	AF is COMPLEX array, dimension (LDA,N) Details of the RQ factorization of A, as returned by CGERQF. See CGERQF for further details.
[out]	Q	Q is COMPLEX array, dimension (LDA,N)
[out]	R	R is COMPLEX array, dimension (LDA,M)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and L. LDA >= N.
[in]	TAU	TAU is COMPLEX array, dimension (M) The scalar factors of the elementary reflectors corresponding to the RQ factorization in AF.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS ) RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 134 of file crqt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( * ), RWORK( * )
      COMPLEX            A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
     $                   R( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            ROGUE
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               CLANGE, CLANSY, SLAMCH
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cherk, clacpy, claset, cungrq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      eps = slamch( 'Epsilon' )
*
*     Copy the last k rows of the factorization to the array Q
*
      CALL claset( 'Full', m, n, rogue, rogue, q, lda )
      IF( k.LT.n )
     $   CALL clacpy( 'Full', k, n-k, af( m-k+1, 1 ), lda,
     $                q( m-k+1, 1 ), lda )
      IF( k.GT.1 )
     $   CALL clacpy( 'Lower', k-1, k-1, af( m-k+2, n-k+1 ), lda,
     $                q( m-k+2, n-k+1 ), lda )
*
*     Generate the last n rows of the matrix Q
*
      srnamt = 'CUNGRQ'
      CALL cungrq( m, n, k, q, lda, tau( m-k+1 ), work, lwork, info )
*
*     Copy R(m-k+1:m,n-m+1:n)
*
      CALL claset( 'Full', k, m, cmplx( zero ), cmplx( zero ),
     $             r( m-k+1, n-m+1 ), lda )
      CALL clacpy( 'Upper', k, k, af( m-k+1, n-k+1 ), lda,
     $             r( m-k+1, n-k+1 ), lda )
*
*     Compute R(m-k+1:m,n-m+1:n) - A(m-k+1:m,1:n) * Q(n-m+1:n,1:n)'
*
      CALL cgemm( 'No transpose', 'Conjugate transpose', k, m, n,
     $            cmplx( -one ), a( m-k+1, 1 ), lda, q, lda,
     $            cmplx( one ), r( m-k+1, n-m+1 ), lda )
*
*     Compute norm( R - A*Q' ) / ( N * norm(A) * EPS ) .
*
      anorm = clange( '1', k, n, a( m-k+1, 1 ), lda, rwork )
      resid = clange( '1', k, m, r( m-k+1, n-m+1 ), lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL claset( 'Full', m, m, cmplx( zero ), cmplx( one ), r, lda )
      CALL cherk( 'Upper', 'No transpose', m, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = clansy( '1', 'Upper', m, r, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of CRQT02
*

Here is the call graph for this function:

Here is the caller graph for this function: