dorgtsqr_row()

subroutine dorgtsqr_row	(	integer	m,
		integer	n,
		integer	mb,
		integer	nb,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldt, * )	t,
		integer	ldt,
		double precision, dimension( * )	work,
		integer	lwork,
		integer	info )

DORGTSQR_ROW

Download DORGTSQR_ROW + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DORGTSQR_ROW generates an M-by-N real matrix Q_out with
!> orthonormal columns from the output of DLATSQR. These N orthonormal
!> columns are the first N columns of a product of complex unitary
!> matrices Q(k)_in of order M, which are returned by DLATSQR in
!> a special format.
!>
!>      Q_out = first_N_columns_of( Q(1)_in * Q(2)_in * ... * Q(k)_in ).
!>
!> The input matrices Q(k)_in are stored in row and column blocks in A.
!> See the documentation of DLATSQR for more details on the format of
!> Q(k)_in, where each Q(k)_in is represented by block Householder
!> transformations. This routine calls an auxiliary routine DLARFB_GETT,
!> where the computation is performed on each individual block. The
!> algorithm first sweeps NB-sized column blocks from the right to left
!> starting in the bottom row block and continues to the top row block
!> (hence _ROW in the routine name). This sweep is in reverse order of
!> the order in which DLATSQR generates the output blocks.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. M >= N >= 0. !>
[in]	MB	!> MB is INTEGER !> The row block size used by DLATSQR to return !> arrays A and T. MB > N. !> (Note that if MB > M, then M is used instead of MB !> as the row block size). !>
[in]	NB	!> NB is INTEGER !> The column block size used by DLATSQR to return !> arrays A and T. NB >= 1. !> (Note that if NB > N, then N is used instead of NB !> as the column block size). !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> !> On entry: !> !> The elements on and above the diagonal are not used as !> input. The elements below the diagonal represent the unit !> lower-trapezoidal blocked matrix V computed by DLATSQR !> that defines the input matrices Q_in(k) (ones on the !> diagonal are not stored). See DLATSQR for more details. !> !> On exit: !> !> The array A contains an M-by-N orthonormal matrix Q_out, !> i.e the columns of A are orthogonal unit vectors. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in]	T	!> T is DOUBLE PRECISION array, !> dimension (LDT, N * NIRB) !> where NIRB = Number_of_input_row_blocks !> = MAX( 1, CEIL((M-N)/(MB-N)) ) !> Let NICB = Number_of_input_col_blocks !> = CEIL(N/NB) !> !> The upper-triangular block reflectors used to define the !> input matrices Q_in(k), k=(1:NIRB*NICB). The block !> reflectors are stored in compact form in NIRB block !> reflector sequences. Each of the NIRB block reflector !> sequences is stored in a larger NB-by-N column block of T !> and consists of NICB smaller NB-by-NB upper-triangular !> column blocks. See DLATSQR for more details on the format !> of T. !>
[in]	LDT	!> LDT is INTEGER !> The leading dimension of the array T. !> LDT >= max(1,min(NB,N)). !>
[out]	WORK	!> (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> LWORK >= NBLOCAL * MAX(NBLOCAL,(N-NBLOCAL)), !> where NBLOCAL=MIN(NB,N). !> If LWORK = -1, then a workspace query is assumed. !> The routine only calculates the optimal size of the WORK !> array, returns this value as the first entry of the WORK !> array, and no error message related to LWORK is issued !> by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

!>
!> November 2020, Igor Kozachenko,
!>                Computer Science Division,
!>                University of California, Berkeley
!>
!> 

Definition at line 185 of file dorgtsqr_row.f.

      IMPLICIT NONE
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER           INFO, LDA, LDT, LWORK, M, N, MB, NB
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION  A( LDA, * ), T( LDT, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            NBLOCAL, MB2, M_PLUS_ONE, ITMP, IB_BOTTOM,
     $                   LWORKOPT, NUM_ALL_ROW_BLOCKS, JB_T, IB, IMB,
     $                   KB, KB_LAST, KNB, MB1
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DUMMY( 1, 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlarfb_gett, dlaset, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      lquery  = lwork.EQ.-1
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. m.LT.n ) THEN
         info = -2
      ELSE IF( mb.LE.n ) THEN
         info = -3
      ELSE IF( nb.LT.1 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -6
      ELSE IF( ldt.LT.max( 1, min( nb, n ) ) ) THEN
         info = -8
      ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
         info = -10
      END IF
*
      nblocal = min( nb, n )
*
*     Determine the workspace size.
*
      IF( info.EQ.0 ) THEN
         lworkopt = nblocal * max( nblocal, ( n - nblocal ) )
      END IF
*
*     Handle error in the input parameters and handle the workspace query.
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DORGTSQR_ROW', -info )
         RETURN
      ELSE IF ( lquery ) THEN
         work( 1 ) = dble( lworkopt )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( min( m, n ).EQ.0 ) THEN
         work( 1 ) = dble( lworkopt )
         RETURN
      END IF
*
*     (0) Set the upper-triangular part of the matrix A to zero and
*     its diagonal elements to one.
*
      CALL dlaset('U', m, n, zero, one, a, lda )
*
*     KB_LAST is the column index of the last column block reflector
*     in the matrices T and V.
*
      kb_last = ( ( n-1 ) / nblocal ) * nblocal + 1
*
*
*     (1) Bottom-up loop over row blocks of A, except the top row block.
*     NOTE: If MB>=M, then the loop is never executed.
*
      IF ( mb.LT.m ) THEN
*
*        MB2 is the row blocking size for the row blocks before the
*        first top row block in the matrix A. IB is the row index for
*        the row blocks in the matrix A before the first top row block.
*        IB_BOTTOM is the row index for the last bottom row block
*        in the matrix A. JB_T is the column index of the corresponding
*        column block in the matrix T.
*
*        Initialize variables.
*
*        NUM_ALL_ROW_BLOCKS is the number of row blocks in the matrix A
*        including the first row block.
*
         mb2 = mb - n
         m_plus_one = m + 1
         itmp = ( m - mb - 1 ) / mb2
         ib_bottom = itmp * mb2 + mb + 1
         num_all_row_blocks = itmp + 2
         jb_t = num_all_row_blocks * n + 1
*
         DO ib = ib_bottom, mb+1, -mb2
*
*           Determine the block size IMB for the current row block
*           in the matrix A.
*
            imb = min( m_plus_one - ib, mb2 )
*
*           Determine the column index JB_T for the current column block
*           in the matrix T.
*
            jb_t = jb_t - n
*
*           Apply column blocks of H in the row block from right to left.
*
*           KB is the column index of the current column block reflector
*           in the matrices T and V.
*
            DO kb = kb_last, 1, -nblocal
*
*              Determine the size of the current column block KNB in
*              the matrices T and V.
*
               knb = min( nblocal, n - kb + 1 )
*
               CALL dlarfb_gett( 'I', imb, n-kb+1, knb,
     $                     t( 1, jb_t+kb-1 ), ldt, a( kb, kb ), lda,
     $                     a( ib, kb ), lda, work, knb )
*
            END DO
*
         END DO
*
      END IF
*
*     (2) Top row block of A.
*     NOTE: If MB>=M, then we have only one row block of A of size M
*     and we work on the entire matrix A.
*
      mb1 = min( mb, m )
*
*     Apply column blocks of H in the top row block from right to left.
*
*     KB is the column index of the current block reflector in
*     the matrices T and V.
*
      DO kb = kb_last, 1, -nblocal
*
*        Determine the size of the current column block KNB in
*        the matrices T and V.
*
         knb = min( nblocal, n - kb + 1 )
*
         IF( mb1-kb-knb+1.EQ.0 ) THEN
*
*           In SLARFB_GETT parameters, when M=0, then the matrix B
*           does not exist, hence we need to pass a dummy array
*           reference DUMMY(1,1) to B with LDDUMMY=1.
*
            CALL dlarfb_gett( 'N', 0, n-kb+1, knb,
     $                        t( 1, kb ), ldt, a( kb, kb ), lda,
     $                        dummy( 1, 1 ), 1, work, knb )
         ELSE
            CALL dlarfb_gett( 'N', mb1-kb-knb+1, n-kb+1, knb,
     $                        t( 1, kb ), ldt, a( kb, kb ), lda,
     $                        a( kb+knb, kb), lda, work, knb )
 
         END IF
*
      END DO
*
      work( 1 ) = dble( lworkopt )
      RETURN
*
*     End of DORGTSQR_ROW
*

Here is the call graph for this function:

Here is the caller graph for this function: