zdrvab()

subroutine zdrvab	(	logical, dimension( * )	dotype,
		integer	nm,
		integer, dimension( * )	mval,
		integer	nns,
		integer, dimension( * )	nsval,
		double precision	thresh,
		integer	nmax,
		complex*16, dimension( * )	a,
		complex*16, dimension( * )	afac,
		complex*16, dimension( * )	b,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		complex, dimension( * )	swork,
		integer, dimension( * )	iwork,
		integer	nout
	)

ZDRVAB

Purpose:

 ZDRVAB tests ZCGESV

Parameters

[in]	DOTYPE	DOTYPE is LOGICAL array, dimension (NTYPES) The matrix types to be used for testing. Matrices of type j (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
[in]	NM	NM is INTEGER The number of values of M contained in the vector MVAL.
[in]	MVAL	MVAL is INTEGER array, dimension (NM) The values of the matrix row dimension M.
[in]	NNS	NNS is INTEGER The number of values of NRHS contained in the vector NSVAL.
[in]	NSVAL	NSVAL is INTEGER array, dimension (NNS) The values of the number of right hand sides NRHS.
[in]	THRESH	THRESH is DOUBLE PRECISION The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	NMAX	NMAX is INTEGER The maximum value permitted for M or N, used in dimensioning the work arrays.
[out]	A	A is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	AFAC	AFAC is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	B	B is COMPLEX*16 array, dimension (NMAX*NSMAX) where NSMAX is the largest entry in NSVAL.
[out]	X	X is COMPLEX*16 array, dimension (NMAX*NSMAX)
[out]	WORK	WORK is COMPLEX*16 array, dimension (NMAX*max(3,NSMAX*2))
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension NMAX
[out]	SWORK	SWORK is COMPLEX array, dimension (NMAX*(NSMAX+NMAX))
[out]	IWORK	IWORK is INTEGER array, dimension NMAX
[in]	NOUT	NOUT is INTEGER The unit number for output.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 149 of file zdrvab.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NM, NMAX, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            MVAL( * ), NSVAL( * ), IWORK( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX            SWORK( * )
      COMPLEX*16         A( * ), AFAC( * ), B( * ),
     $                   WORK( * ), X( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
      INTEGER            NTYPES
      parameter( ntypes = 11 )
      INTEGER            NTESTS
      parameter( ntests = 1 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, TRANS, TYPE, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IM, IMAT, INFO, IOFF, IRHS,
     $                   IZERO, KL, KU, LDA, M, MODE, N,
     $                   NERRS, NFAIL, NIMAT, NRHS, NRUN
      DOUBLE PRECISION   ANORM, CNDNUM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. Local Variables ..
      INTEGER            ITER, KASE
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, zget08, zlacpy, zlarhs, zlaset,
     $                   zlatb4, zlatms
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dcmplx, dble, max, min, sqrt
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 2006, 2007, 2008, 2009 /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      kase = 0
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'GE'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
      infot = 0
*
*     Do for each value of M in MVAL
*
      DO 120 im = 1, nm
         m = mval( im )
         lda = max( 1, m )
*
         n = m
         nimat = ntypes
         IF( m.LE.0 .OR. n.LE.0 )
     $      nimat = 1
*
         DO 100 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 100
*
*           Skip types 5, 6, or 7 if the matrix size is too small.
*
            zerot = imat.GE.5 .AND. imat.LE.7
            IF( zerot .AND. n.LT.imat-4 )
     $         GO TO 100
*
*           Set up parameters with ZLATB4 and generate a test matrix
*           with ZLATMS.
*
            CALL zlatb4( path, imat, m, n, TYPE, KL, KU, ANORM, MODE,
     $                   CNDNUM, DIST )
*
            srnamt = 'ZLATMS'
            CALL zlatms( m, n, dist, iseed, TYPE, RWORK, MODE,
     $                   CNDNUM, ANORM, KL, KU, 'No packing', A, LDA,
     $                   WORK, INFO )
*
*           Check error code from ZLATMS.
*
            IF( info.NE.0 ) THEN
               CALL alaerh( path, 'ZLATMS', info, 0, ' ', m, n, -1,
     $                      -1, -1, imat, nfail, nerrs, nout )
               GO TO 100
            END IF
*
*           For types 5-7, zero one or more columns of the matrix to
*           test that INFO is returned correctly.
*
            IF( zerot ) THEN
               IF( imat.EQ.5 ) THEN
                  izero = 1
               ELSE IF( imat.EQ.6 ) THEN
                  izero = min( m, n )
               ELSE
                  izero = min( m, n ) / 2 + 1
               END IF
               ioff = ( izero-1 )*lda
               IF( imat.LT.7 ) THEN
                  DO 20 i = 1, m
                     a( ioff+i ) = zero
   20             CONTINUE
               ELSE
                  CALL zlaset( 'Full', m, n-izero+1, dcmplx(zero),
     $                         dcmplx(zero), a( ioff+1 ), lda )
               END IF
            ELSE
               izero = 0
            END IF
*
            DO 60 irhs = 1, nns
               nrhs = nsval( irhs )
               xtype = 'N'
               trans = 'N'
*
               srnamt = 'ZLARHS'
               CALL zlarhs( path, xtype, ' ', trans, n, n, kl,
     $                      ku, nrhs, a, lda, x, lda, b,
     $                      lda, iseed, info )
*
               srnamt = 'ZCGESV'
*
               kase = kase + 1
*
               CALL zlacpy( 'Full', m, n, a, lda, afac, lda )
*
               CALL zcgesv( n, nrhs, a, lda, iwork, b, lda, x, lda,
     $                      work, swork, rwork, iter, info)
*
               IF (iter.LT.0) THEN
                   CALL zlacpy( 'Full', m, n, afac, lda, a, lda )
               ENDIF
*
*              Check error code from ZCGESV. This should be the same as
*              the one of DGETRF.
*
               IF( info.NE.izero ) THEN
*
                  IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $               CALL alahd( nout, path )
                  nerrs = nerrs + 1
*
                  IF( info.NE.izero .AND. izero.NE.0 ) THEN
                     WRITE( nout, fmt = 9988 )'ZCGESV',info,
     $                         izero,m,imat
                  ELSE
                     WRITE( nout, fmt = 9975 )'ZCGESV',info,
     $                         m, imat
                  END IF
               END IF
*
*              Skip the remaining test if the matrix is singular.
*
               IF( info.NE.0 )
     $            GO TO 100
*
*              Check the quality of the solution
*
               CALL zlacpy( 'Full', n, nrhs, b, lda, work, lda )
*
               CALL zget08( trans, n, n, nrhs, a, lda, x, lda, work,
     $                      lda, rwork, result( 1 ) )
*
*              Check if the test passes the testing.
*              Print information about the tests that did not
*              pass the testing.
*
*              If iterative refinement has been used and claimed to
*              be successful (ITER>0), we want
*                NORMI(B - A*X)/(NORMI(A)*NORMI(X)*EPS*SRQT(N)) < 1
*
*              If double precision has been used (ITER<0), we want
*                NORMI(B - A*X)/(NORMI(A)*NORMI(X)*EPS) < THRES
*              (Cf. the linear solver testing routines)
*
               IF ((thresh.LE.0.0e+00)
     $            .OR.((iter.GE.0).AND.(n.GT.0)
     $                 .AND.(result(1).GE.sqrt(dble(n))))
     $            .OR.((iter.LT.0).AND.(result(1).GE.thresh))) THEN
*
                  IF( nfail.EQ.0 .AND. nerrs.EQ.0 ) THEN
                     WRITE( nout, fmt = 8999 )'DGE'
                     WRITE( nout, fmt = '( '' Matrix types:'' )' )
                     WRITE( nout, fmt = 8979 )
                     WRITE( nout, fmt = '( '' Test ratios:'' )' )
                     WRITE( nout, fmt = 8960 )1
                     WRITE( nout, fmt = '( '' Messages:'' )' )
                  END IF
*
                  WRITE( nout, fmt = 9998 )trans, n, nrhs,
     $               imat, 1, result( 1 )
                  nfail = nfail + 1
               END IF
               nrun = nrun + 1
   60       CONTINUE
  100    CONTINUE
  120 CONTINUE
*
*     Print a summary of the results.
*
      IF( nfail.GT.0 ) THEN
         WRITE( nout, fmt = 9996 )'ZCGESV', nfail, nrun
      ELSE
         WRITE( nout, fmt = 9995 )'ZCGESV', nrun
      END IF
      IF( nerrs.GT.0 ) THEN
         WRITE( nout, fmt = 9994 )nerrs
      END IF
*
 9998 FORMAT( ' TRANS=''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9996 FORMAT( 1x, a6, ': ', i6, ' out of ', i6,
     $      ' tests failed to pass the threshold' )
 9995 FORMAT( /1x, 'All tests for ', a6,
     $      ' routines passed the threshold ( ', i6, ' tests run)' )
 9994 FORMAT( 6x, i6, ' error messages recorded' )
*
*     SUBNAM, INFO, INFOE, M, IMAT
*
 9988 FORMAT( ' *** ', a6, ' returned with INFO =', i5, ' instead of ',
     $      i5, / ' ==> M =', i5, ', type ',
     $      i2 )
*
*     SUBNAM, INFO, M, IMAT
*
 9975 FORMAT( ' *** Error code from ', a6, '=', i5, ' for M=', i5,
     $      ', type ', i2 )
 8999 FORMAT( / 1x, a3, ':  General dense matrices' )
 8979 FORMAT( 4x, '1. Diagonal', 24x, '7. Last n/2 columns zero', / 4x,
     $      '2. Upper triangular', 16x,
     $      '8. Random, CNDNUM = sqrt(0.1/EPS)', / 4x,
     $      '3. Lower triangular', 16x, '9. Random, CNDNUM = 0.1/EPS',
     $      / 4x, '4. Random, CNDNUM = 2', 13x,
     $      '10. Scaled near underflow', / 4x, '5. First column zero',
     $      14x, '11. Scaled near overflow', / 4x,
     $      '6. Last column zero' )
 8960 FORMAT( 3x, i2, ': norm_1( B - A * X )  / ',
     $      '( norm_1(A) * norm_1(X) * EPS * SQRT(N) ) > 1 if ITERREF',
     $      / 4x, 'or norm_1( B - A * X )  / ',
     $      '( norm_1(A) * norm_1(X) * EPS ) > THRES if DGETRF' )
      RETURN
*
*     End of ZDRVAB
*

Here is the call graph for this function:

Here is the caller graph for this function: