zposvx()

subroutine zposvx	(	character	fact,
		character	uplo,
		integer	n,
		integer	nrhs,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldaf, * )	af,
		integer	ldaf,
		character	equed,
		double precision, dimension( * )	s,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( ldx, * )	x,
		integer	ldx,
		double precision	rcond,
		double precision, dimension( * )	ferr,
		double precision, dimension( * )	berr,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		integer	info )

ZPOSVX computes the solution to system of linear equations A * X = B for PO matrices

Download ZPOSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZPOSVX uses the Cholesky factorization A = U**H*U or A = L*L**H to
!> compute the solution to a complex system of linear equations
!>    A * X = B,
!> where A is an N-by-N Hermitian positive definite matrix and X and B
!> are N-by-NRHS matrices.
!>
!> Error bounds on the solution and a condition estimate are also
!> provided.
!> 

Description:

!>
!> The following steps are performed:
!>
!> 1. If FACT = 'E', real scaling factors are computed to equilibrate
!>    the system:
!>       diag(S) * A * diag(S) * inv(diag(S)) * X = diag(S) * B
!>    Whether or not the system will be equilibrated depends on the
!>    scaling of the matrix A, but if equilibration is used, A is
!>    overwritten by diag(S)*A*diag(S) and B by diag(S)*B.
!>
!> 2. If FACT = 'N' or 'E', the Cholesky decomposition is used to
!>    factor the matrix A (after equilibration if FACT = 'E') as
!>       A = U**H* U,  if UPLO = 'U', or
!>       A = L * L**H,  if UPLO = 'L',
!>    where U is an upper triangular matrix and L is a lower triangular
!>    matrix.
!>
!> 3. If the leading principal minor of order i is not positive,
!>    then the routine returns with INFO = i. Otherwise, the factored
!>    form of A is used to estimate the condition number of the matrix
!>    A.  If the reciprocal of the condition number is less than machine
!>    precision, INFO = N+1 is returned as a warning, but the routine
!>    still goes on to solve for X and compute error bounds as
!>    described below.
!>
!> 4. The system of equations is solved for X using the factored form
!>    of A.
!>
!> 5. Iterative refinement is applied to improve the computed solution
!>    matrix and calculate error bounds and backward error estimates
!>    for it.
!>
!> 6. If equilibration was used, the matrix X is premultiplied by
!>    diag(S) so that it solves the original system before
!>    equilibration.
!> 

Parameters

[in]	FACT	!> FACT is CHARACTER*1 !> Specifies whether or not the factored form of the matrix A is !> supplied on entry, and if not, whether the matrix A should be !> equilibrated before it is factored. !> = 'F': On entry, AF contains the factored form of A. !> If EQUED = 'Y', the matrix A has been equilibrated !> with scaling factors given by S. A and AF will not !> be modified. !> = 'N': The matrix A will be copied to AF and factored. !> = 'E': The matrix A will be equilibrated if necessary, then !> copied to AF and factored. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangle of A is stored; !> = 'L': Lower triangle of A is stored. !>
[in]	N	!> N is INTEGER !> The number of linear equations, i.e., the order of the !> matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices B and X. NRHS >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the Hermitian matrix A, except if FACT = 'F' and !> EQUED = 'Y', then A must contain the equilibrated matrix !> diag(S)*A*diag(S). If UPLO = 'U', the leading !> N-by-N upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading N-by-N lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. A is not modified if !> FACT = 'F' or 'N', or if FACT = 'E' and EQUED = 'N' on exit. !> !> On exit, if FACT = 'E' and EQUED = 'Y', A is overwritten by !> diag(S)*A*diag(S). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in,out]	AF	!> AF is COMPLEX*16 array, dimension (LDAF,N) !> If FACT = 'F', then AF is an input argument and on entry !> contains the triangular factor U or L from the Cholesky !> factorization A = U**H *U or A = L*L**H, in the same storage !> format as A. If EQUED .ne. 'N', then AF is the factored form !> of the equilibrated matrix diag(S)*A*diag(S). !> !> If FACT = 'N', then AF is an output argument and on exit !> returns the triangular factor U or L from the Cholesky !> factorization A = U**H *U or A = L*L**H of the original !> matrix A. !> !> If FACT = 'E', then AF is an output argument and on exit !> returns the triangular factor U or L from the Cholesky !> factorization A = U**H *U or A = L*L**H of the equilibrated !> matrix A (see the description of A for the form of the !> equilibrated matrix). !>
[in]	LDAF	!> LDAF is INTEGER !> The leading dimension of the array AF. LDAF >= max(1,N). !>
[in,out]	EQUED	!> EQUED is CHARACTER*1 !> Specifies the form of equilibration that was done. !> = 'N': No equilibration (always true if FACT = 'N'). !> = 'Y': Equilibration was done, i.e., A has been replaced by !> diag(S) * A * diag(S). !> EQUED is an input argument if FACT = 'F'; otherwise, it is an !> output argument. !>
[in,out]	S	!> S is DOUBLE PRECISION array, dimension (N) !> The scale factors for A; not accessed if EQUED = 'N'. S is !> an input argument if FACT = 'F'; otherwise, S is an output !> argument. If FACT = 'F' and EQUED = 'Y', each element of S !> must be positive. !>
[in,out]	B	!> B is COMPLEX*16 array, dimension (LDB,NRHS) !> On entry, the N-by-NRHS righthand side matrix B. !> On exit, if EQUED = 'N', B is not modified; if EQUED = 'Y', !> B is overwritten by diag(S) * B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	X	!> X is COMPLEX*16 array, dimension (LDX,NRHS) !> If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X to !> the original system of equations. Note that if EQUED = 'Y', !> A and B are modified on exit, and the solution to the !> equilibrated system is inv(diag(S))*X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[out]	RCOND	!> RCOND is DOUBLE PRECISION !> The estimate of the reciprocal condition number of the matrix !> A after equilibration (if done). If RCOND is less than the !> machine precision (in particular, if RCOND = 0), the matrix !> is singular to working precision. This condition is !> indicated by a return code of INFO > 0. !>
[out]	FERR	!> FERR is DOUBLE PRECISION array, dimension (NRHS) !> The estimated forward error bound for each solution vector !> X(j) (the j-th column of the solution matrix X). !> If XTRUE is the true solution corresponding to X(j), FERR(j) !> is an estimated upper bound for the magnitude of the largest !> element in (X(j) - XTRUE) divided by the magnitude of the !> largest element in X(j). The estimate is as reliable as !> the estimate for RCOND, and is almost always a slight !> overestimate of the true error. !>
[out]	BERR	!> BERR is DOUBLE PRECISION array, dimension (NRHS) !> The componentwise relative backward error of each solution !> vector X(j) (i.e., the smallest relative change in !> any element of A or B that makes X(j) an exact solution). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (2*N) !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, and i is !> <= N: the leading principal minor of order i of A !> is not positive, so the factorization could not !> be completed, and the solution has not been !> computed. RCOND = 0 is returned. !> = N+1: U is nonsingular, but RCOND is less than machine !> precision, meaning that the matrix is singular !> to working precision. Nevertheless, the !> solution and error bounds are computed because !> there are a number of situations where the !> computed solution can be more accurate than the !> value of RCOND would suggest. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 301 of file zposvx.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          EQUED, FACT, UPLO
      INTEGER            INFO, LDA, LDAF, LDB, LDX, N, NRHS
      DOUBLE PRECISION   RCOND
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   BERR( * ), FERR( * ), RWORK( * ), S( * )
      COMPLEX*16         A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
     $                   WORK( * ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            EQUIL, NOFACT, RCEQU
      INTEGER            I, INFEQU, J
      DOUBLE PRECISION   AMAX, ANORM, BIGNUM, SCOND, SMAX, SMIN, SMLNUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, ZLANHE
      EXTERNAL           lsame, dlamch, zlanhe
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zlacpy, zlaqhe, zpocon, zpoequ,
     $                   zporfs,
     $                   zpotrf, zpotrs
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
      info = 0
      nofact = lsame( fact, 'N' )
      equil = lsame( fact, 'E' )
      IF( nofact .OR. equil ) THEN
         equed = 'N'
         rcequ = .false.
      ELSE
         rcequ = lsame( equed, 'Y' )
         smlnum = dlamch( 'Safe minimum' )
         bignum = one / smlnum
      END IF
*
*     Test the input parameters.
*
      IF( .NOT.nofact .AND.
     $    .NOT.equil .AND.
     $    .NOT.lsame( fact, 'F' ) )
     $     THEN
         info = -1
      ELSE IF( .NOT.lsame( uplo, 'U' ) .AND.
     $         .NOT.lsame( uplo, 'L' ) )
     $          THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( nrhs.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( ldaf.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
     $         ( rcequ .OR. lsame( equed, 'N' ) ) ) THEN
         info = -9
      ELSE
         IF( rcequ ) THEN
            smin = bignum
            smax = zero
            DO 10 j = 1, n
               smin = min( smin, s( j ) )
               smax = max( smax, s( j ) )
   10       CONTINUE
            IF( smin.LE.zero ) THEN
               info = -10
            ELSE IF( n.GT.0 ) THEN
               scond = max( smin, smlnum ) / min( smax, bignum )
            ELSE
               scond = one
            END IF
         END IF
         IF( info.EQ.0 ) THEN
            IF( ldb.LT.max( 1, n ) ) THEN
               info = -12
            ELSE IF( ldx.LT.max( 1, n ) ) THEN
               info = -14
            END IF
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPOSVX', -info )
         RETURN
      END IF
*
      IF( equil ) THEN
*
*        Compute row and column scalings to equilibrate the matrix A.
*
         CALL zpoequ( n, a, lda, s, scond, amax, infequ )
         IF( infequ.EQ.0 ) THEN
*
*           Equilibrate the matrix.
*
            CALL zlaqhe( uplo, n, a, lda, s, scond, amax, equed )
            rcequ = lsame( equed, 'Y' )
         END IF
      END IF
*
*     Scale the right hand side.
*
      IF( rcequ ) THEN
         DO 30 j = 1, nrhs
            DO 20 i = 1, n
               b( i, j ) = s( i )*b( i, j )
   20       CONTINUE
   30    CONTINUE
      END IF
*
      IF( nofact .OR. equil ) THEN
*
*        Compute the Cholesky factorization A = U**H *U or A = L*L**H.
*
         CALL zlacpy( uplo, n, n, a, lda, af, ldaf )
         CALL zpotrf( uplo, n, af, ldaf, info )
*
*        Return if INFO is non-zero.
*
         IF( info.GT.0 )THEN
            rcond = zero
            RETURN
         END IF
      END IF
*
*     Compute the norm of the matrix A.
*
      anorm = zlanhe( '1', uplo, n, a, lda, rwork )
*
*     Compute the reciprocal of the condition number of A.
*
      CALL zpocon( uplo, n, af, ldaf, anorm, rcond, work, rwork,
     $             info )
*
*     Compute the solution matrix X.
*
      CALL zlacpy( 'Full', n, nrhs, b, ldb, x, ldx )
      CALL zpotrs( uplo, n, nrhs, af, ldaf, x, ldx, info )
*
*     Use iterative refinement to improve the computed solution and
*     compute error bounds and backward error estimates for it.
*
      CALL zporfs( uplo, n, nrhs, a, lda, af, ldaf, b, ldb, x, ldx,
     $             ferr, berr, work, rwork, info )
*
*     Transform the solution matrix X to a solution of the original
*     system.
*
      IF( rcequ ) THEN
         DO 50 j = 1, nrhs
            DO 40 i = 1, n
               x( i, j ) = s( i )*x( i, j )
   40       CONTINUE
   50    CONTINUE
         DO 60 j = 1, nrhs
            ferr( j ) = ferr( j ) / scond
   60    CONTINUE
      END IF
*
*     Set INFO = N+1 if the matrix is singular to working precision.
*
      IF( rcond.LT.dlamch( 'Epsilon' ) )
     $   info = n + 1
*
      RETURN
*
*     End of ZPOSVX
*

Here is the call graph for this function:

Here is the caller graph for this function: