clantb.f

Go to the documentation of this file.

*> \brief \b CLANTB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a triangular band matrix.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CLANTB + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clantb.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clantb.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clantb.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION CLANTB( NORM, UPLO, DIAG, N, K, AB,
*                        LDAB, WORK )
*
*       .. Scalar Arguments ..
*       CHARACTER          DIAG, NORM, UPLO
*       INTEGER            K, LDAB, N
*       ..
*       .. Array Arguments ..
*       REAL               WORK( * )
*       COMPLEX            AB( LDAB, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLANTB  returns the value of the one norm,  or the Frobenius norm, or
*> the  infinity norm,  or the element of  largest absolute value  of an
*> n by n triangular band matrix A,  with ( k + 1 ) diagonals.
*> \endverbatim
*>
*> \return CLANTB
*> \verbatim
*>
*>    CLANTB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
*>             (
*>             ( norm1(A),         NORM = '1', 'O' or 'o'
*>             (
*>             ( normI(A),         NORM = 'I' or 'i'
*>             (
*>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
*>
*> where  norm1  denotes the  one norm of a matrix (maximum column sum),
*> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
*> normF  denotes the  Frobenius norm of a matrix (square root of sum of
*> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NORM
*> \verbatim
*>          NORM is CHARACTER*1
*>          Specifies the value to be returned in CLANTB as described
*>          above.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the matrix A is upper or lower triangular.
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] DIAG
*> \verbatim
*>          DIAG is CHARACTER*1
*>          Specifies whether or not the matrix A is unit triangular.
*>          = 'N':  Non-unit triangular
*>          = 'U':  Unit triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.  When N = 0, CLANTB is
*>          set to zero.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of super-diagonals of the matrix A if UPLO = 'U',
*>          or the number of sub-diagonals of the matrix A if UPLO = 'L'.
*>          K >= 0.
*> \endverbatim
*>
*> \param[in] AB
*> \verbatim
*>          AB is COMPLEX array, dimension (LDAB,N)
*>          The upper or lower triangular band matrix A, stored in the
*>          first k+1 rows of AB.  The j-th column of A is stored
*>          in the j-th column of the array AB as follows:
*>          if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
*>          if UPLO = 'L', AB(1+i-j,j)   = A(i,j) for j<=i<=min(n,j+k).
*>          Note that when DIAG = 'U', the elements of the array AB
*>          corresponding to the diagonal elements of the matrix A are
*>          not referenced, but are assumed to be one.
*> \endverbatim
*>
*> \param[in] LDAB
*> \verbatim
*>          LDAB is INTEGER
*>          The leading dimension of the array AB.  LDAB >= K+1.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (MAX(1,LWORK)),
*>          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
*>          referenced.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup lantb
*
*  =====================================================================
      REAL             function clantb( norm, uplo, diag, n, k, ab,
     $                 ldab, work )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          diag, norm, uplo
      INTEGER            k, ldab, n
*     ..
*     .. Array Arguments ..
      REAL               work( * )
      COMPLEX            ab( ldab, * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            udiag
      INTEGER            i, j, l
      REAL               scale, sum, value
*     ..
*     .. External Functions ..
      LOGICAL            lsame, sisnan
      EXTERNAL           lsame, sisnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           classq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.EQ.0 ) THEN
         VALUE = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         IF( lsame( diag, 'U' ) ) THEN
            VALUE = one
            IF( lsame( uplo, 'U' ) ) THEN
               DO 20 j = 1, n
                  DO 10 i = max( k+2-j, 1 ), k
                     sum = abs( ab( i, j ) )
                     IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
   10             CONTINUE
   20          CONTINUE
            ELSE
               DO 40 j = 1, n
                  DO 30 i = 2, min( n+1-j, k+1 )
                     sum = abs( ab( i, j ) )
                     IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
   30             CONTINUE
   40          CONTINUE
            END IF
         ELSE
            VALUE = zero
            IF( lsame( uplo, 'U' ) ) THEN
               DO 60 j = 1, n
                  DO 50 i = max( k+2-j, 1 ), k + 1
                     sum = abs( ab( i, j ) )
                     IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
   50             CONTINUE
   60          CONTINUE
            ELSE
               DO 80 j = 1, n
                  DO 70 i = 1, min( n+1-j, k+1 )
                     sum = abs( ab( i, j ) )
                     IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
   70             CONTINUE
   80          CONTINUE
            END IF
         END IF
      ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
*
*        Find norm1(A).
*
         VALUE = zero
         udiag = lsame( diag, 'U' )
         IF( lsame( uplo, 'U' ) ) THEN
            DO 110 j = 1, n
               IF( udiag ) THEN
                  sum = one
                  DO 90 i = max( k+2-j, 1 ), k
                     sum = sum + abs( ab( i, j ) )
   90             CONTINUE
               ELSE
                  sum = zero
                  DO 100 i = max( k+2-j, 1 ), k + 1
                     sum = sum + abs( ab( i, j ) )
  100             CONTINUE
               END IF
               IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
  110       CONTINUE
         ELSE
            DO 140 j = 1, n
               IF( udiag ) THEN
                  sum = one
                  DO 120 i = 2, min( n+1-j, k+1 )
                     sum = sum + abs( ab( i, j ) )
  120             CONTINUE
               ELSE
                  sum = zero
                  DO 130 i = 1, min( n+1-j, k+1 )
                     sum = sum + abs( ab( i, j ) )
  130             CONTINUE
               END IF
               IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
  140       CONTINUE
         END IF
      ELSE IF( lsame( norm, 'I' ) ) THEN
*
*        Find normI(A).
*
         VALUE = zero
         IF( lsame( uplo, 'U' ) ) THEN
            IF( lsame( diag, 'U' ) ) THEN
               DO 150 i = 1, n
                  work( i ) = one
  150          CONTINUE
               DO 170 j = 1, n
                  l = k + 1 - j
                  DO 160 i = max( 1, j-k ), j - 1
                     work( i ) = work( i ) + abs( ab( l+i, j ) )
  160             CONTINUE
  170          CONTINUE
            ELSE
               DO 180 i = 1, n
                  work( i ) = zero
  180          CONTINUE
               DO 200 j = 1, n
                  l = k + 1 - j
                  DO 190 i = max( 1, j-k ), j
                     work( i ) = work( i ) + abs( ab( l+i, j ) )
  190             CONTINUE
  200          CONTINUE
            END IF
         ELSE
            IF( lsame( diag, 'U' ) ) THEN
               DO 210 i = 1, n
                  work( i ) = one
  210          CONTINUE
               DO 230 j = 1, n
                  l = 1 - j
                  DO 220 i = j + 1, min( n, j+k )
                     work( i ) = work( i ) + abs( ab( l+i, j ) )
  220             CONTINUE
  230          CONTINUE
            ELSE
               DO 240 i = 1, n
                  work( i ) = zero
  240          CONTINUE
               DO 260 j = 1, n
                  l = 1 - j
                  DO 250 i = j, min( n, j+k )
                     work( i ) = work( i ) + abs( ab( l+i, j ) )
  250             CONTINUE
  260          CONTINUE
            END IF
         END IF
         DO 270 i = 1, n
            sum = work( i )
            IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
  270    CONTINUE
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         IF( lsame( uplo, 'U' ) ) THEN
            IF( lsame( diag, 'U' ) ) THEN
               scale = one
               sum = n
               IF( k.GT.0 ) THEN
                  DO 280 j = 2, n
                     CALL classq( min( j-1, k ),
     $                            ab( max( k+2-j, 1 ), j ), 1, scale,
     $                            sum )
  280             CONTINUE
               END IF
            ELSE
               scale = zero
               sum = one
               DO 290 j = 1, n
                  CALL classq( min( j, k+1 ), ab( max( k+2-j, 1 ), j ),
     $                         1, scale, sum )
  290          CONTINUE
            END IF
         ELSE
            IF( lsame( diag, 'U' ) ) THEN
               scale = one
               sum = n
               IF( k.GT.0 ) THEN
                  DO 300 j = 1, n - 1
                     CALL classq( min( n-j, k ), ab( 2, j ), 1, scale,
     $                            sum )
  300             CONTINUE
               END IF
            ELSE
               scale = zero
               sum = one
               DO 310 j = 1, n
                  CALL classq( min( n-j+1, k+1 ), ab( 1, j ), 1, scale,
     $                         sum )
  310          CONTINUE
            END IF
         END IF
         VALUE = scale*sqrt( sum )
      END IF
*
      clantb = VALUE
      RETURN
*
*     End of CLANTB
*
      END