sgbt02()

subroutine sgbt02	(	character	trans,
		integer	m,
		integer	n,
		integer	kl,
		integer	ku,
		integer	nrhs,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldx, * )	x,
		integer	ldx,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( * )	rwork,
		real	resid )

SGBT02

Purpose:

!>
!> SGBT02 computes the residual for a solution of a banded system of
!> equations op(A)*X = B:
!>    RESID = norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ),
!> where op(A) = A or A**T, depending on TRANS, and EPS is the
!> machine epsilon.
!> The norm used is the 1-norm.
!> 

Parameters

[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the form of the system of equations: !> = 'N': A * X = B (No transpose) !> = 'T': A**T * X = B (Transpose) !> = 'C': A**H * X = B (Conjugate transpose = Transpose) !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	KL	!> KL is INTEGER !> The number of subdiagonals within the band of A. KL >= 0. !>
[in]	KU	!> KU is INTEGER !> The number of superdiagonals within the band of A. KU >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of B. NRHS >= 0. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The original matrix A in band storage, stored in rows 1 to !> KL+KU+1. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,KL+KU+1). !>
[in]	X	!> X is REAL array, dimension (LDX,NRHS) !> The computed solution vectors for the system of linear !> equations. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. If TRANS = 'N', !> LDX >= max(1,N); if TRANS = 'T' or 'C', LDX >= max(1,M). !>
[in,out]	B	!> B is REAL array, dimension (LDB,NRHS) !> On entry, the right hand side vectors for the system of !> linear equations. !> On exit, B is overwritten with the difference B - A*X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. IF TRANS = 'N', !> LDB >= max(1,M); if TRANS = 'T' or 'C', LDB >= max(1,N). !>
[out]	RWORK	!> RWORK is REAL array, dimension (MAX(1,LRWORK)), !> where LRWORK >= M when TRANS = 'T' or 'C'; otherwise, RWORK !> is not referenced. !>
[out]	RESID	!> RESID is REAL !> The maximum over the number of right hand sides of !> norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 147 of file sgbt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            KL, KU, LDA, LDB, LDX, M, N, NRHS
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * ), X( LDX, * ),
     $                   RWORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I1, I2, J, KD, N1
      REAL               ANORM, BNORM, EPS, TEMP, XNORM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, SISNAN
      REAL               SASUM, SLAMCH
      EXTERNAL           lsame, sasum, sisnan, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgbmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if N = 0 pr NRHS = 0
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = zero
      IF( lsame( trans, 'N' ) ) THEN
*
*        Find norm1(A).
*
         kd = ku + 1
         DO 10 j = 1, n
            i1 = max( kd+1-j, 1 )
            i2 = min( kd+m-j, kl+kd )
            IF( i2.GE.i1 ) THEN
               temp = sasum( i2-i1+1, a( i1, j ), 1 )
               IF( anorm.LT.temp .OR. sisnan( temp ) ) anorm = temp
            END IF
   10    CONTINUE
      ELSE
*
*        Find normI(A).
*
         DO 12 i1 = 1, m
            rwork( i1 ) = zero
   12    CONTINUE
         DO 16 j = 1, n
            kd = ku + 1 - j
            DO 14 i1 = max( 1, j-ku ), min( m, j+kl )
               rwork( i1 ) = rwork( i1 ) + abs( a( kd+i1, j ) )
   14       CONTINUE
   16    CONTINUE
         DO 18 i1 = 1, m
            temp = rwork( i1 )
            IF( anorm.LT.temp .OR. sisnan( temp ) ) anorm = temp
   18    CONTINUE
      END IF
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
      IF( lsame( trans, 'T' ) .OR. lsame( trans, 'C' ) ) THEN
         n1 = n
      ELSE
         n1 = m
      END IF
*
*     Compute B - op(A)*X
*
      DO 20 j = 1, nrhs
         CALL sgbmv( trans, m, n, kl, ku, -one, a, lda, x( 1, j ), 1,
     $               one, b( 1, j ), 1 )
   20 CONTINUE
*
*     Compute the maximum over the number of right hand sides of
*        norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ).
*
      resid = zero
      DO 30 j = 1, nrhs
         bnorm = sasum( n1, b( 1, j ), 1 )
         xnorm = sasum( n1, x( 1, j ), 1 )
         IF( xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
         END IF
   30 CONTINUE
*
      RETURN
*
*     End of SGBT02
*

Here is the call graph for this function:

Here is the caller graph for this function: