zgesc2()

subroutine zgesc2	(	integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	rhs,
		integer, dimension( * )	ipiv,
		integer, dimension( * )	jpiv,
		double precision	scale )

ZGESC2 solves a system of linear equations using the LU factorization with complete pivoting computed by sgetc2.

Download ZGESC2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZGESC2 solves a system of linear equations
!>
!>           A * X = scale* RHS
!>
!> with a general N-by-N matrix A using the LU factorization with
!> complete pivoting computed by ZGETC2.
!>
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of columns of the matrix A. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA, N) !> On entry, the LU part of the factorization of the n-by-n !> matrix A computed by ZGETC2: A = P * L * U * Q !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1, N). !>
[in,out]	RHS	!> RHS is COMPLEX*16 array, dimension N. !> On entry, the right hand side vector b. !> On exit, the solution vector X. !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N). !> The pivot indices; for 1 <= i <= N, row i of the !> matrix has been interchanged with row IPIV(i). !>
[in]	JPIV	!> JPIV is INTEGER array, dimension (N). !> The pivot indices; for 1 <= j <= N, column j of the !> matrix has been interchanged with column JPIV(j). !>
[out]	SCALE	!> SCALE is DOUBLE PRECISION !> On exit, SCALE contains the scale factor. SCALE is chosen !> 0 <= SCALE <= 1 to prevent overflow in the solution. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Bo Kagstrom and Peter Poromaa, Department of Computing Science, Umea University, S-901 87 Umea, Sweden.

Definition at line 112 of file zgesc2.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, N
      DOUBLE PRECISION   SCALE
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * ), JPIV( * )
      COMPLEX*16         A( LDA, * ), RHS( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE, TWO
      parameter( zero = 0.0d+0, one = 1.0d+0, two = 2.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   BIGNUM, EPS, SMLNUM
      COMPLEX*16         TEMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           zlaswp, zscal
*     ..
*     .. External Functions ..
      INTEGER            IZAMAX
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           izamax, dlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx
*     ..
*     .. Executable Statements ..
*
*     Set constant to control overflow
*
      eps = dlamch( 'P' )
      smlnum = dlamch( 'S' ) / eps
      bignum = one / smlnum
*
*     Apply permutations IPIV to RHS
*
      CALL zlaswp( 1, rhs, lda, 1, n-1, ipiv, 1 )
*
*     Solve for L part
*
      DO 20 i = 1, n - 1
         DO 10 j = i + 1, n
            rhs( j ) = rhs( j ) - a( j, i )*rhs( i )
   10    CONTINUE
   20 CONTINUE
*
*     Solve for U part
*
      scale = one
*
*     Check for scaling
*
      i = izamax( n, rhs, 1 )
      IF( two*smlnum*abs( rhs( i ) ).GT.abs( a( n, n ) ) ) THEN
         temp = dcmplx( one / two, zero ) / abs( rhs( i ) )
         CALL zscal( n, temp, rhs( 1 ), 1 )
         scale = scale*dble( temp )
      END IF
      DO 40 i = n, 1, -1
         temp = dcmplx( one, zero ) / a( i, i )
         rhs( i ) = rhs( i )*temp
         DO 30 j = i + 1, n
            rhs( i ) = rhs( i ) - rhs( j )*( a( i, j )*temp )
   30    CONTINUE
   40 CONTINUE
*
*     Apply permutations JPIV to the solution (RHS)
*
      CALL zlaswp( 1, rhs, lda, 1, n-1, jpiv, -1 )
      RETURN
*
*     End of ZGESC2
*

Here is the call graph for this function:

Here is the caller graph for this function: