ctplqt()

subroutine ctplqt	(	integer	m,
		integer	n,
		integer	l,
		integer	mb,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		complex, dimension( ldt, * )	t,
		integer	ldt,
		complex, dimension( * )	work,
		integer	info
	)

CTPLQT

Purpose:

 CTPLQT computes a blocked LQ factorization of a complex
 "triangular-pentagonal" matrix C, which is composed of a
 triangular block A and pentagonal block B, using the compact
 WY representation for Q.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix B, and the order of the triangular matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix B. N >= 0.
[in]	L	L is INTEGER The number of rows of the lower trapezoidal part of B. MIN(M,N) >= L >= 0. See Further Details.
[in]	MB	MB is INTEGER The block size to be used in the blocked QR. M >= MB >= 1.
[in,out]	A	A is COMPLEX array, dimension (LDA,M) On entry, the lower triangular M-by-M matrix A. On exit, the elements on and below the diagonal of the array contain the lower triangular matrix L.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in,out]	B	B is COMPLEX array, dimension (LDB,N) On entry, the pentagonal M-by-N matrix B. The first N-L columns are rectangular, and the last L columns are lower trapezoidal. On exit, B contains the pentagonal matrix V. See Further Details.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,M).
[out]	T	T is COMPLEX array, dimension (LDT,N) The lower triangular block reflectors stored in compact form as a sequence of upper triangular blocks. See Further Details.
[in]	LDT	LDT is INTEGER The leading dimension of the array T. LDT >= MB.
[out]	WORK	WORK is COMPLEX array, dimension (MB*M)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  The input matrix C is a M-by-(M+N) matrix

               C = [ A ] [ B ]


  where A is an lower triangular M-by-M matrix, and B is M-by-N pentagonal
  matrix consisting of a M-by-(N-L) rectangular matrix B1 on left of a M-by-L
  upper trapezoidal matrix B2:
          [ B ] = [ B1 ] [ B2 ]
                   [ B1 ]  <- M-by-(N-L) rectangular
                   [ B2 ]  <-     M-by-L lower trapezoidal.

  The lower trapezoidal matrix B2 consists of the first L columns of a
  M-by-M lower triangular matrix, where 0 <= L <= MIN(M,N).  If L=0,
  B is rectangular M-by-N; if M=L=N, B is lower triangular.

  The matrix W stores the elementary reflectors H(i) in the i-th row
  above the diagonal (of A) in the M-by-(M+N) input matrix C
            [ C ] = [ A ] [ B ]
                   [ A ]  <- lower triangular M-by-M
                   [ B ]  <- M-by-N pentagonal

  so that W can be represented as
            [ W ] = [ I ] [ V ]
                   [ I ]  <- identity, M-by-M
                   [ V ]  <- M-by-N, same form as B.

  Thus, all of information needed for W is contained on exit in B, which
  we call V above.  Note that V has the same form as B; that is,
            [ V ] = [ V1 ] [ V2 ]
                   [ V1 ] <- M-by-(N-L) rectangular
                   [ V2 ] <-     M-by-L lower trapezoidal.

  The rows of V represent the vectors which define the H(i)'s.

  The number of blocks is B = ceiling(M/MB), where each
  block is of order MB except for the last block, which is of order
  IB = M - (M-1)*MB.  For each of the B blocks, a upper triangular block
  reflector factor is computed: T1, T2, ..., TB.  The MB-by-MB (and IB-by-IB
  for the last block) T's are stored in the MB-by-N matrix T as

               T = [T1 T2 ... TB].

Definition at line 172 of file ctplqt.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER     INFO, LDA, LDB, LDT, N, M, L, MB
*     ..
*     .. Array Arguments ..
      COMPLEX     A( LDA, * ), B( LDB, * ), T( LDT, * ), WORK( * )
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      INTEGER    I, IB, LB, NB, IINFO
*     ..
*     .. External Subroutines ..
      EXTERNAL   ctplqt2, ctprfb, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( l.LT.0 .OR. (l.GT.min(m,n) .AND. min(m,n).GE.0)) THEN
         info = -3
      ELSE IF( mb.LT.1 .OR. (mb.GT.m .AND. m.GT.0)) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, m ) ) THEN
         info = -8
      ELSE IF( ldt.LT.mb ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CTPLQT', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 ) RETURN
*
      DO i = 1, m, mb
*
*     Compute the QR factorization of the current block
*
         ib = min( m-i+1, mb )
         nb = min( n-l+i+ib-1, n )
         IF( i.GE.l ) THEN
            lb = 0
         ELSE
            lb = nb-n+l-i+1
         END IF
*
         CALL ctplqt2( ib, nb, lb, a(i,i), lda, b( i, 1 ), ldb,
     $                 t(1, i ), ldt, iinfo )
*
*     Update by applying H**T to B(I+IB:M,:) from the right
*
         IF( i+ib.LE.m ) THEN
            CALL ctprfb( 'R', 'N', 'F', 'R', m-i-ib+1, nb, ib, lb,
     $                    b( i, 1 ), ldb, t( 1, i ), ldt,
     $                    a( i+ib, i ), lda, b( i+ib, 1 ), ldb,
     $                    work, m-i-ib+1)
         END IF
      END DO
      RETURN
*
*     End of CTPLQT
*

Here is the call graph for this function:

Here is the caller graph for this function: