zpotf2.f

Go to the documentation of this file.

*> \brief \b ZPOTF2 computes the Cholesky factorization of a symmetric/Hermitian positive definite matrix (unblocked algorithm).
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download ZPOTF2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zpotf2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zpotf2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zpotf2.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZPOTF2( UPLO, N, A, LDA, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDA, N
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZPOTF2 computes the Cholesky factorization of a complex Hermitian
*> positive definite matrix A.
*>
*> The factorization has the form
*>    A = U**H * U ,  if UPLO = 'U', or
*>    A = L  * L**H,  if UPLO = 'L',
*> where U is an upper triangular matrix and L is lower triangular.
*>
*> This is the unblocked version of the algorithm, calling Level 2 BLAS.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          Hermitian matrix A is stored.
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
*>          n by n upper triangular part of A contains the upper
*>          triangular part of the matrix A, and the strictly lower
*>          triangular part of A is not referenced.  If UPLO = 'L', the
*>          leading n by n lower triangular part of A contains the lower
*>          triangular part of the matrix A, and the strictly upper
*>          triangular part of A is not referenced.
*>
*>          On exit, if INFO = 0, the factor U or L from the Cholesky
*>          factorization A = U**H *U  or A = L*L**H.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -k, the k-th argument had an illegal value
*>          > 0: if INFO = k, the leading principal minor of order k
*>               is not positive, and the factorization could not be
*>               completed.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup potf2
*
*  =====================================================================
      SUBROUTINE zpotf2( UPLO, N, A, LDA, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J
      DOUBLE PRECISION   AJJ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, DISNAN
      COMPLEX*16         ZDOTC
      EXTERNAL           lsame, zdotc, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zdscal, zgemv, zlacgv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPOTF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Compute the Cholesky factorization A = U**H *U.
*
         DO 10 j = 1, n
*
*           Compute U(J,J) and test for non-positive-definiteness.
*
            ajj = dble( a( j, j ) ) - dble( zdotc( j-1, a( 1, j ), 1,
     $            a( 1, j ), 1 ) )
            IF( ajj.LE.zero.OR.disnan( ajj ) ) THEN
               a( j, j ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of row J.
*
            IF( j.LT.n ) THEN
               CALL zlacgv( j-1, a( 1, j ), 1 )
               CALL zgemv( 'Transpose', j-1, n-j, -cone, a( 1, j+1 ),
     $                     lda, a( 1, j ), 1, cone, a( j, j+1 ), lda )
               CALL zlacgv( j-1, a( 1, j ), 1 )
               CALL zdscal( n-j, one / ajj, a( j, j+1 ), lda )
            END IF
   10    CONTINUE
      ELSE
*
*        Compute the Cholesky factorization A = L*L**H.
*
         DO 20 j = 1, n
*
*           Compute L(J,J) and test for non-positive-definiteness.
*
            ajj = dble( a( j, j ) ) - dble( zdotc( j-1, a( j, 1 ),
     $                  lda,
     $            a( j, 1 ), lda ) )
            IF( ajj.LE.zero.OR.disnan( ajj ) ) THEN
               a( j, j ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of column J.
*
            IF( j.LT.n ) THEN
               CALL zlacgv( j-1, a( j, 1 ), lda )
               CALL zgemv( 'No transpose', n-j, j-1, -cone, a( j+1,
     $                     1 ),
     $                     lda, a( j, 1 ), lda, cone, a( j+1, j ), 1 )
               CALL zlacgv( j-1, a( j, 1 ), lda )
               CALL zdscal( n-j, one / ajj, a( j+1, j ), 1 )
            END IF
   20    CONTINUE
      END IF
      GO TO 40
*
   30 CONTINUE
      info = j
*
   40 CONTINUE
      RETURN
*
*     End of ZPOTF2
*
      END