slqt01()

subroutine slqt01	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		real, dimension( lda, * )	af,
		real, dimension( lda, * )	q,
		real, dimension( lda, * )	l,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result )

SLQT01

Purpose:

!>
!> SLQT01 tests SGELQF, which computes the LQ factorization of an m-by-n
!> matrix A, and partially tests SORGLQ which forms the n-by-n
!> orthogonal matrix Q.
!>
!> SLQT01 compares L with A*Q', and checks that Q is orthogonal.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The m-by-n matrix A. !>
[out]	AF	!> AF is REAL array, dimension (LDA,N) !> Details of the LQ factorization of A, as returned by SGELQF. !> See SGELQF for further details. !>
[out]	Q	!> Q is REAL array, dimension (LDA,N) !> The n-by-n orthogonal matrix Q. !>
[out]	L	!> L is REAL array, dimension (LDA,max(M,N)) !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A, AF, Q and L. !> LDA >= max(M,N). !>
[out]	TAU	!> TAU is REAL array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors, as returned !> by SGELQF. !>
[out]	WORK	!> WORK is REAL array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !>
[out]	RWORK	!> RWORK is REAL array, dimension (max(M,N)) !>
[out]	RESULT	!> RESULT is REAL array, dimension (2) !> The test ratios: !> RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS ) !> RESULT(2) = norm( I - Q*Q' ) / ( N * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file slqt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), AF( LDA, * ), L( LDA, * ),
     $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               ROGUE
      parameter( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE, SLANSY
      EXTERNAL           slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgelqf, sgemm, slacpy, slaset, sorglq, ssyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL slacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'SGELQF'
      CALL sgelqf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL slaset( 'Full', n, n, rogue, rogue, q, lda )
      IF( n.GT.1 )
     $   CALL slacpy( 'Upper', m, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'SORGLQ'
      CALL sorglq( n, n, minmn, q, lda, tau, work, lwork, info )
*
*     Copy L
*
      CALL slaset( 'Full', m, n, zero, zero, l, lda )
      CALL slacpy( 'Lower', m, n, af, lda, l, lda )
*
*     Compute L - A*Q'
*
      CALL sgemm( 'No transpose', 'Transpose', m, n, n, -one, a, lda, q,
     $            lda, one, l, lda )
*
*     Compute norm( L - Q'*A ) / ( N * norm(A) * EPS ) .
*
      anorm = slange( '1', m, n, a, lda, rwork )
      resid = slange( '1', m, n, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL slaset( 'Full', n, n, zero, one, l, lda )
      CALL ssyrk( 'Upper', 'No transpose', n, n, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = slansy( '1', 'Upper', n, l, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of SLQT01
*

Here is the call graph for this function:

Here is the caller graph for this function: