dla_porpvgrw()

double precision function dla_porpvgrw	(	character*1	uplo,
		integer	ncols,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldaf, * )	af,
		integer	ldaf,
		double precision, dimension( * )	work
	)

DLA_PORPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a symmetric or Hermitian positive-definite matrix.

Download DLA_PORPVGRW + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DLA_PORPVGRW computes the reciprocal pivot growth factor
 norm(A)/norm(U). The "max absolute element" norm is used. If this is
 much less than 1, the stability of the LU factorization of the
 (equilibrated) matrix A could be poor. This also means that the
 solution X, estimated condition numbers, and error bounds could be
 unreliable.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	NCOLS	NCOLS is INTEGER The number of columns of the matrix A. NCOLS >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the N-by-N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	AF	AF is DOUBLE PRECISION array, dimension (LDAF,N) The triangular factor U or L from the Cholesky factorization A = U**T*U or A = L*L**T, as computed by DPOTRF.
[in]	LDAF	LDAF is INTEGER The leading dimension of the array AF. LDAF >= max(1,N).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (2*N)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 104 of file dla_porpvgrw.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER*1        UPLO
      INTEGER            NCOLS, LDA, LDAF
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   AMAX, UMAX, RPVGRW
      LOGICAL            UPPER
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min
*     ..
*     .. External Functions ..
      EXTERNAL           lsame
      LOGICAL            LSAME
*     ..
*     .. Executable Statements ..
*
      upper = lsame( 'Upper', uplo )
*
*     DPOTRF will have factored only the NCOLSxNCOLS leading submatrix,
*     so we restrict the growth search to that submatrix and use only
*     the first 2*NCOLS workspace entries.
*
      rpvgrw = 1.0d+0
      DO i = 1, 2*ncols
         work( i ) = 0.0d+0
      END DO
*
*     Find the max magnitude entry of each column.
*
      IF ( upper ) THEN
         DO j = 1, ncols
            DO i = 1, j
               work( ncols+j ) =
     $              max( abs( a( i, j ) ), work( ncols+j ) )
            END DO
         END DO
      ELSE
         DO j = 1, ncols
            DO i = j, ncols
               work( ncols+j ) =
     $              max( abs( a( i, j ) ), work( ncols+j ) )
            END DO
         END DO
      END IF
*
*     Now find the max magnitude entry of each column of the factor in
*     AF.  No pivoting, so no permutations.
*
      IF ( lsame( 'Upper', uplo ) ) THEN
         DO j = 1, ncols
            DO i = 1, j
               work( j ) = max( abs( af( i, j ) ), work( j ) )
            END DO
         END DO
      ELSE
         DO j = 1, ncols
            DO i = j, ncols
               work( j ) = max( abs( af( i, j ) ), work( j ) )
            END DO
         END DO
      END IF
*
*     Compute the *inverse* of the max element growth factor.  Dividing
*     by zero would imply the largest entry of the factor's column is
*     zero.  Than can happen when either the column of A is zero or
*     massive pivots made the factor underflow to zero.  Neither counts
*     as growth in itself, so simply ignore terms with zero
*     denominators.
*
      IF ( lsame( 'Upper', uplo ) ) THEN
         DO i = 1, ncols
            umax = work( i )
            amax = work( ncols+i )
            IF ( umax /= 0.0d+0 ) THEN
               rpvgrw = min( amax / umax, rpvgrw )
            END IF
         END DO
      ELSE
         DO i = 1, ncols
            umax = work( i )
            amax = work( ncols+i )
            IF ( umax /= 0.0d+0 ) THEN
               rpvgrw = min( amax / umax, rpvgrw )
            END IF
         END DO
      END IF
 
      dla_porpvgrw = rpvgrw
*
*     End of DLA_PORPVGRW
*

Here is the call graph for this function:

Here is the caller graph for this function: