cqrt01p()

subroutine cqrt01p	(	integer	m,
		integer	n,
		complex, dimension( lda, * )	a,
		complex, dimension( lda, * )	af,
		complex, dimension( lda, * )	q,
		complex, dimension( lda, * )	r,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result
	)

CQRT01P

Purpose:

 CQRT01P tests CGEQRFP, which computes the QR factorization of an m-by-n
 matrix A, and partially tests CUNGQR which forms the m-by-m
 orthogonal matrix Q.

 CQRT01P compares R with Q'*A, and checks that Q is orthogonal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A.
[out]	AF	AF is COMPLEX array, dimension (LDA,N) Details of the QR factorization of A, as returned by CGEQRFP. See CGEQRFP for further details.
[out]	Q	Q is COMPLEX array, dimension (LDA,M) The m-by-m orthogonal matrix Q.
[out]	R	R is COMPLEX array, dimension (LDA,max(M,N))
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and R. LDA >= max(M,N).
[out]	TAU	TAU is COMPLEX array, dimension (min(M,N)) The scalar factors of the elementary reflectors, as returned by CGEQRFP.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file cqrt01p.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( * ), RWORK( * )
      COMPLEX            A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
     $                   R( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            ROGUE
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               CLANGE, CLANSY, SLAMCH
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cgeqrfp, cherk, clacpy, claset, cungqr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL clacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'CGEQRFP'
      CALL cgeqrfp( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL claset( 'Full', m, m, rogue, rogue, q, lda )
      CALL clacpy( 'Lower', m-1, n, af( 2, 1 ), lda, q( 2, 1 ), lda )
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'CUNGQR'
      CALL cungqr( m, m, minmn, q, lda, tau, work, lwork, info )
*
*     Copy R
*
      CALL claset( 'Full', m, n, cmplx( zero ), cmplx( zero ), r, lda )
      CALL clacpy( 'Upper', m, n, af, lda, r, lda )
*
*     Compute R - Q'*A
*
      CALL cgemm( 'Conjugate transpose', 'No transpose', m, n, m,
     $            cmplx( -one ), q, lda, a, lda, cmplx( one ), r, lda )
*
*     Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = clange( '1', m, n, a, lda, rwork )
      resid = clange( '1', m, n, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, m ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL claset( 'Full', m, m, cmplx( zero ), cmplx( one ), r, lda )
      CALL cherk( 'Upper', 'Conjugate transpose', m, m, -one, q, lda,
     $            one, r, lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = clansy( '1', 'Upper', m, r, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, m ) ) ) / eps
*
      RETURN
*
*     End of CQRT01P
*

Here is the call graph for this function:

Here is the caller graph for this function: