LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ claqgb()

 subroutine claqgb ( integer M, integer N, integer KL, integer KU, complex, dimension( ldab, * ) AB, integer LDAB, real, dimension( * ) R, real, dimension( * ) C, real ROWCND, real COLCND, real AMAX, character EQUED )

CLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ.

Purpose:
``` CLAQGB equilibrates a general M by N band matrix A with KL
subdiagonals and KU superdiagonals using the row and scaling factors
in the vectors R and C.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix A. N >= 0.``` [in] KL ``` KL is INTEGER The number of subdiagonals within the band of A. KL >= 0.``` [in] KU ``` KU is INTEGER The number of superdiagonals within the band of A. KU >= 0.``` [in,out] AB ``` AB is COMPLEX array, dimension (LDAB,N) On entry, the matrix A in band storage, in rows 1 to KL+KU+1. The j-th column of A is stored in the j-th column of the array AB as follows: AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(m,j+kl) On exit, the equilibrated matrix, in the same storage format as A. See EQUED for the form of the equilibrated matrix.``` [in] LDAB ``` LDAB is INTEGER The leading dimension of the array AB. LDA >= KL+KU+1.``` [in] R ``` R is REAL array, dimension (M) The row scale factors for A.``` [in] C ``` C is REAL array, dimension (N) The column scale factors for A.``` [in] ROWCND ``` ROWCND is REAL Ratio of the smallest R(i) to the largest R(i).``` [in] COLCND ``` COLCND is REAL Ratio of the smallest C(i) to the largest C(i).``` [in] AMAX ``` AMAX is REAL Absolute value of largest matrix entry.``` [out] EQUED ``` EQUED is CHARACTER*1 Specifies the form of equilibration that was done. = 'N': No equilibration = 'R': Row equilibration, i.e., A has been premultiplied by diag(R). = 'C': Column equilibration, i.e., A has been postmultiplied by diag(C). = 'B': Both row and column equilibration, i.e., A has been replaced by diag(R) * A * diag(C).```
Internal Parameters:
```  THRESH is a threshold value used to decide if row or column scaling
should be done based on the ratio of the row or column scaling
factors.  If ROWCND < THRESH, row scaling is done, and if
COLCND < THRESH, column scaling is done.

LARGE and SMALL are threshold values used to decide if row scaling
should be done based on the absolute size of the largest matrix
element.  If AMAX > LARGE or AMAX < SMALL, row scaling is done.```

Definition at line 158 of file claqgb.f.

160*
161* -- LAPACK auxiliary routine --
162* -- LAPACK is a software package provided by Univ. of Tennessee, --
163* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
164*
165* .. Scalar Arguments ..
166 CHARACTER EQUED
167 INTEGER KL, KU, LDAB, M, N
168 REAL AMAX, COLCND, ROWCND
169* ..
170* .. Array Arguments ..
171 REAL C( * ), R( * )
172 COMPLEX AB( LDAB, * )
173* ..
174*
175* =====================================================================
176*
177* .. Parameters ..
178 REAL ONE, THRESH
179 parameter( one = 1.0e+0, thresh = 0.1e+0 )
180* ..
181* .. Local Scalars ..
182 INTEGER I, J
183 REAL CJ, LARGE, SMALL
184* ..
185* .. External Functions ..
186 REAL SLAMCH
187 EXTERNAL slamch
188* ..
189* .. Intrinsic Functions ..
190 INTRINSIC max, min
191* ..
192* .. Executable Statements ..
193*
194* Quick return if possible
195*
196 IF( m.LE.0 .OR. n.LE.0 ) THEN
197 equed = 'N'
198 RETURN
199 END IF
200*
201* Initialize LARGE and SMALL.
202*
203 small = slamch( 'Safe minimum' ) / slamch( 'Precision' )
204 large = one / small
205*
206 IF( rowcnd.GE.thresh .AND. amax.GE.small .AND. amax.LE.large )
207 \$ THEN
208*
209* No row scaling
210*
211 IF( colcnd.GE.thresh ) THEN
212*
213* No column scaling
214*
215 equed = 'N'
216 ELSE
217*
218* Column scaling
219*
220 DO 20 j = 1, n
221 cj = c( j )
222 DO 10 i = max( 1, j-ku ), min( m, j+kl )
223 ab( ku+1+i-j, j ) = cj*ab( ku+1+i-j, j )
224 10 CONTINUE
225 20 CONTINUE
226 equed = 'C'
227 END IF
228 ELSE IF( colcnd.GE.thresh ) THEN
229*
230* Row scaling, no column scaling
231*
232 DO 40 j = 1, n
233 DO 30 i = max( 1, j-ku ), min( m, j+kl )
234 ab( ku+1+i-j, j ) = r( i )*ab( ku+1+i-j, j )
235 30 CONTINUE
236 40 CONTINUE
237 equed = 'R'
238 ELSE
239*
240* Row and column scaling
241*
242 DO 60 j = 1, n
243 cj = c( j )
244 DO 50 i = max( 1, j-ku ), min( m, j+kl )
245 ab( ku+1+i-j, j ) = cj*r( i )*ab( ku+1+i-j, j )
246 50 CONTINUE
247 60 CONTINUE
248 equed = 'B'
249 END IF
250*
251 RETURN
252*
253* End of CLAQGB
254*
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the caller graph for this function: