sbdt05()

subroutine sbdt05	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	s,
		integer	ns,
		real, dimension( ldu, * )	u,
		integer	ldu,
		real, dimension( ldvt, * )	vt,
		integer	ldvt,
		real, dimension( * )	work,
		real	resid )

SBDT05

Purpose:

!>
!> SBDT05 reconstructs a bidiagonal matrix B from its (partial) SVD:
!>    S = U' * B * V
!> where U and V are orthogonal matrices and S is diagonal.
!>
!> The test ratio to test the singular value decomposition is
!>    RESID = norm( S - U' * B * V ) / ( n * norm(B) * EPS )
!> where VT = V' and EPS is the machine precision.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrices A and U. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrices A and VT. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The m by n matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in]	S	!> S is REAL array, dimension (NS) !> The singular values from the (partial) SVD of B, sorted in !> decreasing order. !>
[in]	NS	!> NS is INTEGER !> The number of singular values/vectors from the (partial) !> SVD of B. !>
[in]	U	!> U is REAL array, dimension (LDU,NS) !> The n by ns orthogonal matrix U in S = U' * B * V. !>
[in]	LDU	!> LDU is INTEGER !> The leading dimension of the array U. LDU >= max(1,N) !>
[in]	VT	!> VT is REAL array, dimension (LDVT,N) !> The n by ns orthogonal matrix V in S = U' * B * V. !>
[in]	LDVT	!> LDVT is INTEGER !> The leading dimension of the array VT. !>
[out]	WORK	!> WORK is REAL array, dimension (M,N) !>
[out]	RESID	!> RESID is REAL !> The test ratio: norm(S - U' * A * V) / ( n * norm(A) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 125 of file sbdt05.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDU, LDVT, M, N, NS
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), S( * ), U( LDU, * ),
     $                   VT( LDVT, * ), WORK( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               ANORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ISAMAX
      REAL               SASUM, SLAMCH, SLANGE
      EXTERNAL           lsame, isamax, sasum, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      resid = zero
      IF( min( m, n ).LE.0 .OR. ns.LE.0 )
     $   RETURN
*
      eps = slamch( 'Precision' )
      anorm = slange( 'M', m, n, a, lda, work )
*
*     Compute U' * A * V.
*
      CALL sgemm( 'N', 'T', m, ns, n, one, a, lda, vt,
     $            ldvt, zero, work( 1+ns*ns ), m )
      CALL sgemm( 'T', 'N', ns, ns, m, -one, u, ldu, work( 1+ns*ns ),
     $            m, zero, work, ns )
*
*     norm(S - U' * B * V)
*
      j = 0
      DO 10 i = 1, ns
         work( j+i ) =  work( j+i ) + s( i )
         resid = max( resid, sasum( ns, work( j+1 ), 1 ) )
         j = j + ns
   10 CONTINUE
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( anorm.GE.resid ) THEN
            resid = ( resid / anorm ) / ( real( n )*eps )
         ELSE
            IF( anorm.LT.one ) THEN
               resid = ( min( resid, real( n )*anorm ) / anorm ) /
     $                 ( real( n )*eps )
            ELSE
               resid = min( resid / anorm, real( n ) ) /
     $                 ( real( n )*eps )
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of SBDT05
*

Here is the call graph for this function:

Here is the caller graph for this function: