clauum()

subroutine clauum	(	character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		integer	info )

CLAUUM computes the product UUH or LHL, where U and L are upper or lower triangular matrices (blocked algorithm).

Download CLAUUM + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CLAUUM computes the product U * U**H or L**H * L, where the triangular
!> factor U or L is stored in the upper or lower triangular part of
!> the array A.
!>
!> If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
!> overwriting the factor U in A.
!> If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
!> overwriting the factor L in A.
!>
!> This is the blocked form of the algorithm, calling Level 3 BLAS.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the triangular factor stored in the array A !> is upper or lower triangular: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the triangular factor U or L. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the triangular factor U or L. !> On exit, if UPLO = 'U', the upper triangle of A is !> overwritten with the upper triangle of the product U * U**H; !> if UPLO = 'L', the lower triangle of A is overwritten with !> the lower triangle of the product L**H * L. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -k, the k-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 99 of file clauum.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
      COMPLEX            CONE
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, IB, NB
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      EXTERNAL           lsame, ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cherk, clauu2, ctrmm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CLAUUM', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'CLAUUM', uplo, n, -1, -1, -1 )
*
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code
*
         CALL clauu2( uplo, n, a, lda, info )
      ELSE
*
*        Use blocked code
*
         IF( upper ) THEN
*
*           Compute the product U * U**H.
*
            DO 10 i = 1, n, nb
               ib = min( nb, n-i+1 )
               CALL ctrmm( 'Right', 'Upper', 'Conjugate transpose',
     $                     'Non-unit', i-1, ib, cone, a( i, i ), lda,
     $                     a( 1, i ), lda )
               CALL clauu2( 'Upper', ib, a( i, i ), lda, info )
               IF( i+ib.LE.n ) THEN
                  CALL cgemm( 'No transpose', 'Conjugate transpose',
     $                        i-1, ib, n-i-ib+1, cone, a( 1, i+ib ),
     $                        lda, a( i, i+ib ), lda, cone, a( 1, i ),
     $                        lda )
                  CALL cherk( 'Upper', 'No transpose', ib, n-i-ib+1,
     $                        one, a( i, i+ib ), lda, one, a( i, i ),
     $                        lda )
               END IF
   10       CONTINUE
         ELSE
*
*           Compute the product L**H * L.
*
            DO 20 i = 1, n, nb
               ib = min( nb, n-i+1 )
               CALL ctrmm( 'Left', 'Lower', 'Conjugate transpose',
     $                     'Non-unit', ib, i-1, cone, a( i, i ), lda,
     $                     a( i, 1 ), lda )
               CALL clauu2( 'Lower', ib, a( i, i ), lda, info )
               IF( i+ib.LE.n ) THEN
                  CALL cgemm( 'Conjugate transpose', 'No transpose',
     $                        ib,
     $                        i-1, n-i-ib+1, cone, a( i+ib, i ), lda,
     $                        a( i+ib, 1 ), lda, cone, a( i, 1 ), lda )
                  CALL cherk( 'Lower', 'Conjugate transpose', ib,
     $                        n-i-ib+1, one, a( i+ib, i ), lda, one,
     $                        a( i, i ), lda )
               END IF
   20       CONTINUE
         END IF
      END IF
*
      RETURN
*
*     End of CLAUUM
*

Here is the call graph for this function:

Here is the caller graph for this function: