schkgk()

subroutine schkgk	(	integer	nin,
		integer	nout
	)

SCHKGK

Purpose:

 SCHKGK tests SGGBAK, a routine for backward balancing  of
 a matrix pair (A, B).

Parameters

[in]	NIN	NIN is INTEGER The logical unit number for input. NIN > 0.
[in]	NOUT	NOUT is INTEGER The logical unit number for output. NOUT > 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 53 of file schkgk.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NIN, NOUT
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            LDA, LDB, LDVL, LDVR
      parameter( lda = 50, ldb = 50, ldvl = 50, ldvr = 50 )
      INTEGER            LDE, LDF, LDWORK
      parameter( lde = 50, ldf = 50, ldwork = 50 )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IHI, ILO, INFO, J, KNT, M, N, NINFO
      REAL               ANORM, BNORM, EPS, RMAX, VMAX
*     ..
*     .. Local Arrays ..
      INTEGER            LMAX( 4 )
      REAL               A( LDA, LDA ), AF( LDA, LDA ), B( LDB, LDB ),
     $                   BF( LDB, LDB ), E( LDE, LDE ), F( LDF, LDF ),
     $                   LSCALE( LDA ), RSCALE( LDA ), VL( LDVL, LDVL ),
     $                   VLF( LDVL, LDVL ), VR( LDVR, LDVR ),
     $                   VRF( LDVR, LDVR ), WORK( LDWORK, LDWORK )
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, sggbak, sggbal, slacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
*     Initialization
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      lmax( 3 ) = 0
      lmax( 4 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
*
      eps = slamch( 'Precision' )
*
   10 CONTINUE
      READ( nin, fmt = * )n, m
      IF( n.EQ.0 )
     $   GO TO 100
*
      DO 20 i = 1, n
         READ( nin, fmt = * )( a( i, j ), j = 1, n )
   20 CONTINUE
*
      DO 30 i = 1, n
         READ( nin, fmt = * )( b( i, j ), j = 1, n )
   30 CONTINUE
*
      DO 40 i = 1, n
         READ( nin, fmt = * )( vl( i, j ), j = 1, m )
   40 CONTINUE
*
      DO 50 i = 1, n
         READ( nin, fmt = * )( vr( i, j ), j = 1, m )
   50 CONTINUE
*
      knt = knt + 1
*
      anorm = slange( 'M', n, n, a, lda, work )
      bnorm = slange( 'M', n, n, b, ldb, work )
*
      CALL slacpy( 'FULL', n, n, a, lda, af, lda )
      CALL slacpy( 'FULL', n, n, b, ldb, bf, ldb )
*
      CALL sggbal( 'B', n, a, lda, b, ldb, ilo, ihi, lscale, rscale,
     $             work, info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      CALL slacpy( 'FULL', n, m, vl, ldvl, vlf, ldvl )
      CALL slacpy( 'FULL', n, m, vr, ldvr, vrf, ldvr )
*
      CALL sggbak( 'B', 'L', n, ilo, ihi, lscale, rscale, m, vl, ldvl,
     $             info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 2 ) = knt
      END IF
*
      CALL sggbak( 'B', 'R', n, ilo, ihi, lscale, rscale, m, vr, ldvr,
     $             info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 3 ) = knt
      END IF
*
*     Test of SGGBAK
*
*     Check tilde(VL)'*A*tilde(VR) - VL'*tilde(A)*VR
*     where tilde(A) denotes the transformed matrix.
*
      CALL sgemm( 'N', 'N', n, m, n, one, af, lda, vr, ldvr, zero, work,
     $            ldwork )
      CALL sgemm( 'T', 'N', m, m, n, one, vl, ldvl, work, ldwork, zero,
     $            e, lde )
*
      CALL sgemm( 'N', 'N', n, m, n, one, a, lda, vrf, ldvr, zero, work,
     $            ldwork )
      CALL sgemm( 'T', 'N', m, m, n, one, vlf, ldvl, work, ldwork, zero,
     $            f, ldf )
*
      vmax = zero
      DO 70 j = 1, m
         DO 60 i = 1, m
            vmax = max( vmax, abs( e( i, j )-f( i, j ) ) )
   60    CONTINUE
   70 CONTINUE
      vmax = vmax / ( eps*max( anorm, bnorm ) )
      IF( vmax.GT.rmax ) THEN
         lmax( 4 ) = knt
         rmax = vmax
      END IF
*
*     Check tilde(VL)'*B*tilde(VR) - VL'*tilde(B)*VR
*
      CALL sgemm( 'N', 'N', n, m, n, one, bf, ldb, vr, ldvr, zero, work,
     $            ldwork )
      CALL sgemm( 'T', 'N', m, m, n, one, vl, ldvl, work, ldwork, zero,
     $            e, lde )
*
      CALL sgemm( 'N', 'N', n, m, n, one, b, ldb, vrf, ldvr, zero, work,
     $            ldwork )
      CALL sgemm( 'T', 'N', m, m, n, one, vlf, ldvl, work, ldwork, zero,
     $            f, ldf )
*
      vmax = zero
      DO 90 j = 1, m
         DO 80 i = 1, m
            vmax = max( vmax, abs( e( i, j )-f( i, j ) ) )
   80    CONTINUE
   90 CONTINUE
      vmax = vmax / ( eps*max( anorm, bnorm ) )
      IF( vmax.GT.rmax ) THEN
         lmax( 4 ) = knt
         rmax = vmax
      END IF
*
      GO TO 10
*
  100 CONTINUE
*
      WRITE( nout, fmt = 9999 )
 9999 FORMAT( 1x, '.. test output of SGGBAK .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 FORMAT( ' value of largest test error                  =', e12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 FORMAT( ' example number where SGGBAL info is not 0    =', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 FORMAT( ' example number where SGGBAK(L) info is not 0 =', i4 )
      WRITE( nout, fmt = 9995 )lmax( 3 )
 9995 FORMAT( ' example number where SGGBAK(R) info is not 0 =', i4 )
      WRITE( nout, fmt = 9994 )lmax( 4 )
 9994 FORMAT( ' example number having largest error          =', i4 )
      WRITE( nout, fmt = 9992 )ninfo
 9992 FORMAT( ' number of examples where info is not 0       =', i4 )
      WRITE( nout, fmt = 9991 )knt
 9991 FORMAT( ' total number of examples tested              =', i4 )
*
      RETURN
*
*     End of SCHKGK
*

Here is the call graph for this function:

Here is the caller graph for this function: