clarfgp()

subroutine clarfgp	(	integer	N,
		complex	ALPHA,
		complex, dimension( * )	X,
		integer	INCX,
		complex	TAU
	)

CLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.

Download CLARFGP + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLARFGP generates a complex elementary reflector H of order n, such
 that

       H**H * ( alpha ) = ( beta ),   H**H * H = I.
              (   x   )   (   0  )

 where alpha and beta are scalars, beta is real and non-negative, and
 x is an (n-1)-element complex vector.  H is represented in the form

       H = I - tau * ( 1 ) * ( 1 v**H ) ,
                     ( v )

 where tau is a complex scalar and v is a complex (n-1)-element
 vector. Note that H is not hermitian.

 If the elements of x are all zero and alpha is real, then tau = 0
 and H is taken to be the unit matrix.

Parameters

[in]	N	N is INTEGER The order of the elementary reflector.
[in,out]	ALPHA	ALPHA is COMPLEX On entry, the value alpha. On exit, it is overwritten with the value beta.
[in,out]	X	X is COMPLEX array, dimension (1+(N-2)*abs(INCX)) On entry, the vector x. On exit, it is overwritten with the vector v.
[in]	INCX	INCX is INTEGER The increment between elements of X. INCX > 0.
[out]	TAU	TAU is COMPLEX The value tau.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 103 of file clarfgp.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
      COMPLEX            ALPHA, TAU
*     ..
*     .. Array Arguments ..
      COMPLEX            X( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               TWO, ONE, ZERO
      parameter( two = 2.0e+0, one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J, KNT
      REAL               ALPHI, ALPHR, BETA, BIGNUM, SMLNUM, XNORM
      COMPLEX            SAVEALPHA
*     ..
*     .. External Functions ..
      REAL               SCNRM2, SLAMCH, SLAPY3, SLAPY2
      COMPLEX            CLADIV
      EXTERNAL           scnrm2, slamch, slapy3, slapy2, cladiv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, cmplx, real, sign
*     ..
*     .. External Subroutines ..
      EXTERNAL           cscal, csscal
*     ..
*     .. Executable Statements ..
*
      IF( n.LE.0 ) THEN
         tau = zero
         RETURN
      END IF
*
      xnorm = scnrm2( n-1, x, incx )
      alphr = real( alpha )
      alphi = aimag( alpha )
*
      IF( xnorm.EQ.zero ) THEN
*
*        H  =  [1-alpha/abs(alpha) 0; 0 I], sign chosen so ALPHA >= 0.
*
         IF( alphi.EQ.zero ) THEN
            IF( alphr.GE.zero ) THEN
*              When TAU.eq.ZERO, the vector is special-cased to be
*              all zeros in the application routines.  We do not need
*              to clear it.
               tau = zero
            ELSE
*              However, the application routines rely on explicit
*              zero checks when TAU.ne.ZERO, and we must clear X.
               tau = two
               DO j = 1, n-1
                  x( 1 + (j-1)*incx ) = zero
               END DO
               alpha = -alpha
            END IF
         ELSE
*           Only "reflecting" the diagonal entry to be real and non-negative.
            xnorm = slapy2( alphr, alphi )
            tau = cmplx( one - alphr / xnorm, -alphi / xnorm )
            DO j = 1, n-1
               x( 1 + (j-1)*incx ) = zero
            END DO
            alpha = xnorm
         END IF
      ELSE
*
*        general case
*
         beta = sign( slapy3( alphr, alphi, xnorm ), alphr )
         smlnum = slamch( 'S' ) / slamch( 'E' )
         bignum = one / smlnum
*
         knt = 0
         IF( abs( beta ).LT.smlnum ) THEN
*
*           XNORM, BETA may be inaccurate; scale X and recompute them
*
   10       CONTINUE
            knt = knt + 1
            CALL csscal( n-1, bignum, x, incx )
            beta = beta*bignum
            alphi = alphi*bignum
            alphr = alphr*bignum
            IF( (abs( beta ).LT.smlnum) .AND. (knt .LT. 20) )
     $         GO TO 10
*
*           New BETA is at most 1, at least SMLNUM
*
            xnorm = scnrm2( n-1, x, incx )
            alpha = cmplx( alphr, alphi )
            beta = sign( slapy3( alphr, alphi, xnorm ), alphr )
         END IF
         savealpha = alpha
         alpha = alpha + beta
         IF( beta.LT.zero ) THEN
            beta = -beta
            tau = -alpha / beta
         ELSE
            alphr = alphi * (alphi/real( alpha ))
            alphr = alphr + xnorm * (xnorm/real( alpha ))
            tau = cmplx( alphr/beta, -alphi/beta )
            alpha = cmplx( -alphr, alphi )
         END IF
         alpha = cladiv( cmplx( one ), alpha )
*
         IF ( abs(tau).LE.smlnum ) THEN
*
*           In the case where the computed TAU ends up being a denormalized number,
*           it loses relative accuracy. This is a BIG problem. Solution: flush TAU
*           to ZERO (or TWO or whatever makes a nonnegative real number for BETA).
*
*           (Bug report provided by Pat Quillen from MathWorks on Jul 29, 2009.)
*           (Thanks Pat. Thanks MathWorks.)
*
            alphr = real( savealpha )
            alphi = aimag( savealpha )
            IF( alphi.EQ.zero ) THEN
               IF( alphr.GE.zero ) THEN
                  tau = zero
               ELSE
                  tau = two
                  DO j = 1, n-1
                     x( 1 + (j-1)*incx ) = zero
                  END DO
                  beta = real( -savealpha )
               END IF
            ELSE
               xnorm = slapy2( alphr, alphi )
               tau = cmplx( one - alphr / xnorm, -alphi / xnorm )
               DO j = 1, n-1
                  x( 1 + (j-1)*incx ) = zero
               END DO
               beta = xnorm
            END IF
*
         ELSE
*
*           This is the general case.
*
            CALL cscal( n-1, alpha, x, incx )
*
         END IF
*
*        If BETA is subnormal, it may lose relative accuracy
*
         DO 20 j = 1, knt
            beta = beta*smlnum
 20      CONTINUE
         alpha = beta
      END IF
*
      RETURN
*
*     End of CLARFGP
*

Here is the call graph for this function:

Here is the caller graph for this function: