dchkqrtp()

subroutine dchkqrtp	(	double precision	thresh,
		logical	tsterr,
		integer	nm,
		integer, dimension( * )	mval,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer	nout
	)

DCHKQRTP

Purpose:

 DCHKQRTP tests DTPQRT and DTPMQRT.

Parameters

[in]	THRESH	THRESH is DOUBLE PRECISION The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	TSTERR	TSTERR is LOGICAL Flag that indicates whether error exits are to be tested.
[in]	NM	NM is INTEGER The number of values of M contained in the vector MVAL.
[in]	MVAL	MVAL is INTEGER array, dimension (NM) The values of the matrix row dimension M.
[in]	NN	NN is INTEGER The number of values of N contained in the vector NVAL.
[in]	NVAL	NVAL is INTEGER array, dimension (NN) The values of the matrix column dimension N.
[in]	NNB	NNB is INTEGER The number of values of NB contained in the vector NBVAL.
[in]	NBVAL	NBVAL is INTEGER array, dimension (NNB) The values of the blocksize NB.
[in]	NOUT	NOUT is INTEGER The unit number for output.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 100 of file dchkqrtp.f.

      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NM, NN, NNB, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            MVAL( * ), NBVAL( * ), NVAL( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTESTS
      parameter( ntests = 6 )
*     ..
*     .. Local Scalars ..
      CHARACTER*3        PATH
      INTEGER            I, J, K, L, T, M, N, NB, NFAIL, NERRS, NRUN,
     $                   MINMN
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, derrqrtp
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
*     Initialize constants
*
      path( 1: 1 ) = 'D'
      path( 2: 3 ) = 'QX'
      nrun = 0
      nfail = 0
      nerrs = 0
*
*     Test the error exits
*
      IF( tsterr ) CALL derrqrtp( path, nout )
      infot = 0
*
*     Do for each value of M
*
      DO i = 1, nm
         m = mval( i )
*
*        Do for each value of N
*
         DO j = 1, nn
            n = nval( j )
*
*           Do for each value of L
*
            minmn = min( m, n )
            DO l = 0, minmn, max( minmn, 1 )
*
*              Do for each possible value of NB
*
               DO k = 1, nnb
                  nb = nbval( k )
*
*                 Test DTPQRT and DTPMQRT
*
                  IF( (nb.LE.n).AND.(nb.GT.0) ) THEN
                     CALL dqrt05( m, n, l, nb, result )
*
*                    Print information about the tests that did not
*                    pass the threshold.
*
                     DO t = 1, ntests
                     IF( result( t ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                       CALL alahd( nout, path )
                           WRITE( nout, fmt = 9999 )m, n, nb, l,
     $                            t, result( t )
                           nfail = nfail + 1
                        END IF
                     END DO
                     nrun = nrun + ntests
                  END IF
               END DO
            END DO
         END DO
      END DO
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' M=', i5, ', N=', i5, ', NB=', i4,' L=', i4,
     $      ' test(', i2, ')=', g12.5 )
      RETURN
*
*     End of DCHKQRTP
*

Here is the call graph for this function:

Here is the caller graph for this function: