 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ cherfsx()

 subroutine cherfsx ( character UPLO, character EQUED, integer N, integer NRHS, complex, dimension( lda, * ) A, integer LDA, complex, dimension( ldaf, * ) AF, integer LDAF, integer, dimension( * ) IPIV, real, dimension( * ) S, complex, dimension( ldb, * ) B, integer LDB, complex, dimension( ldx, * ) X, integer LDX, real RCOND, real, dimension( * ) BERR, integer N_ERR_BNDS, real, dimension( nrhs, * ) ERR_BNDS_NORM, real, dimension( nrhs, * ) ERR_BNDS_COMP, integer NPARAMS, real, dimension( * ) PARAMS, complex, dimension( * ) WORK, real, dimension( * ) RWORK, integer INFO )

CHERFSX

Purpose:
```    CHERFSX improves the computed solution to a system of linear
equations when the coefficient matrix is Hermitian indefinite, and
provides error bounds and backward error estimates for the
solution.  In addition to normwise error bound, the code provides
maximum componentwise error bound if possible.  See comments for
ERR_BNDS_NORM and ERR_BNDS_COMP for details of the error bounds.

The original system of linear equations may have been equilibrated
before calling this routine, as described by arguments EQUED and S
below. In this case, the solution and error bounds returned are
for the original unequilibrated system.```
```     Some optional parameters are bundled in the PARAMS array.  These
settings determine how refinement is performed, but often the
defaults are acceptable.  If the defaults are acceptable, users
can pass NPARAMS = 0 which prevents the source code from accessing
the PARAMS argument.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.``` [in] EQUED ``` EQUED is CHARACTER*1 Specifies the form of equilibration that was done to A before calling this routine. This is needed to compute the solution and error bounds correctly. = 'N': No equilibration = 'Y': Both row and column equilibration, i.e., A has been replaced by diag(S) * A * diag(S). The right hand side B has been changed accordingly.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in] NRHS ``` NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices B and X. NRHS >= 0.``` [in] A ``` A is COMPLEX array, dimension (LDA,N) The Hermitian matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [in] AF ``` AF is COMPLEX array, dimension (LDAF,N) The factored form of the matrix A. AF contains the block diagonal matrix D and the multipliers used to obtain the factor U or L from the factorization A = U*D*U**H or A = L*D*L**H as computed by CHETRF.``` [in] LDAF ``` LDAF is INTEGER The leading dimension of the array AF. LDAF >= max(1,N).``` [in] IPIV ``` IPIV is INTEGER array, dimension (N) Details of the interchanges and the block structure of D as determined by CHETRF.``` [in,out] S ``` S is REAL array, dimension (N) The scale factors for A. If EQUED = 'Y', A is multiplied on the left and right by diag(S). S is an input argument if FACT = 'F'; otherwise, S is an output argument. If FACT = 'F' and EQUED = 'Y', each element of S must be positive. If S is output, each element of S is a power of the radix. If S is input, each element of S should be a power of the radix to ensure a reliable solution and error estimates. Scaling by powers of the radix does not cause rounding errors unless the result underflows or overflows. Rounding errors during scaling lead to refining with a matrix that is not equivalent to the input matrix, producing error estimates that may not be reliable.``` [in] B ``` B is COMPLEX array, dimension (LDB,NRHS) The right hand side matrix B.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [in,out] X ``` X is COMPLEX array, dimension (LDX,NRHS) On entry, the solution matrix X, as computed by CHETRS. On exit, the improved solution matrix X.``` [in] LDX ``` LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).``` [out] RCOND ``` RCOND is REAL Reciprocal scaled condition number. This is an estimate of the reciprocal Skeel condition number of the matrix A after equilibration (if done). If this is less than the machine precision (in particular, if it is zero), the matrix is singular to working precision. Note that the error may still be small even if this number is very small and the matrix appears ill- conditioned.``` [out] BERR ``` BERR is REAL array, dimension (NRHS) Componentwise relative backward error. This is the componentwise relative backward error of each solution vector X(j) (i.e., the smallest relative change in any element of A or B that makes X(j) an exact solution).``` [in] N_ERR_BNDS ``` N_ERR_BNDS is INTEGER Number of error bounds to return for each right hand side and each type (normwise or componentwise). See ERR_BNDS_NORM and ERR_BNDS_COMP below.``` [out] ERR_BNDS_NORM ``` ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS) For each right-hand side, this array contains information about various error bounds and condition numbers corresponding to the normwise relative error, which is defined as follows: Normwise relative error in the ith solution vector: max_j (abs(XTRUE(j,i) - X(j,i))) ------------------------------ max_j abs(X(j,i)) The array is indexed by the type of error information as described below. There currently are up to three pieces of information returned. The first index in ERR_BNDS_NORM(i,:) corresponds to the ith right-hand side. The second index in ERR_BNDS_NORM(:,err) contains the following three fields: err = 1 "Trust/don't trust" boolean. Trust the answer if the reciprocal condition number is less than the threshold sqrt(n) * slamch('Epsilon'). err = 2 "Guaranteed" error bound: The estimated forward error, almost certainly within a factor of 10 of the true error so long as the next entry is greater than the threshold sqrt(n) * slamch('Epsilon'). This error bound should only be trusted if the previous boolean is true. err = 3 Reciprocal condition number: Estimated normwise reciprocal condition number. Compared with the threshold sqrt(n) * slamch('Epsilon') to determine if the error estimate is "guaranteed". These reciprocal condition numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some appropriately scaled matrix Z. Let Z = S*A, where S scales each row by a power of the radix so all absolute row sums of Z are approximately 1. See Lapack Working Note 165 for further details and extra cautions.``` [out] ERR_BNDS_COMP ``` ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS) For each right-hand side, this array contains information about various error bounds and condition numbers corresponding to the componentwise relative error, which is defined as follows: Componentwise relative error in the ith solution vector: abs(XTRUE(j,i) - X(j,i)) max_j ---------------------- abs(X(j,i)) The array is indexed by the right-hand side i (on which the componentwise relative error depends), and the type of error information as described below. There currently are up to three pieces of information returned for each right-hand side. If componentwise accuracy is not requested (PARAMS(3) = 0.0), then ERR_BNDS_COMP is not accessed. If N_ERR_BNDS < 3, then at most the first (:,N_ERR_BNDS) entries are returned. The first index in ERR_BNDS_COMP(i,:) corresponds to the ith right-hand side. The second index in ERR_BNDS_COMP(:,err) contains the following three fields: err = 1 "Trust/don't trust" boolean. Trust the answer if the reciprocal condition number is less than the threshold sqrt(n) * slamch('Epsilon'). err = 2 "Guaranteed" error bound: The estimated forward error, almost certainly within a factor of 10 of the true error so long as the next entry is greater than the threshold sqrt(n) * slamch('Epsilon'). This error bound should only be trusted if the previous boolean is true. err = 3 Reciprocal condition number: Estimated componentwise reciprocal condition number. Compared with the threshold sqrt(n) * slamch('Epsilon') to determine if the error estimate is "guaranteed". These reciprocal condition numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some appropriately scaled matrix Z. Let Z = S*(A*diag(x)), where x is the solution for the current right-hand side and S scales each row of A*diag(x) by a power of the radix so all absolute row sums of Z are approximately 1. See Lapack Working Note 165 for further details and extra cautions.``` [in] NPARAMS ``` NPARAMS is INTEGER Specifies the number of parameters set in PARAMS. If <= 0, the PARAMS array is never referenced and default values are used.``` [in,out] PARAMS ``` PARAMS is REAL array, dimension NPARAMS Specifies algorithm parameters. If an entry is < 0.0, then that entry will be filled with default value used for that parameter. Only positions up to NPARAMS are accessed; defaults are used for higher-numbered parameters. PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative refinement or not. Default: 1.0 = 0.0: No refinement is performed, and no error bounds are computed. = 1.0: Use the double-precision refinement algorithm, possibly with doubled-single computations if the compilation environment does not support DOUBLE PRECISION. (other values are reserved for future use) PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual computations allowed for refinement. Default: 10 Aggressive: Set to 100 to permit convergence using approximate factorizations or factorizations other than LU. If the factorization uses a technique other than Gaussian elimination, the guarantees in err_bnds_norm and err_bnds_comp may no longer be trustworthy. PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code will attempt to find a solution with small componentwise relative error in the double-precision algorithm. Positive is true, 0.0 is false. Default: 1.0 (attempt componentwise convergence)``` [out] WORK ` WORK is COMPLEX array, dimension (2*N)` [out] RWORK ` RWORK is REAL array, dimension (2*N)` [out] INFO ``` INFO is INTEGER = 0: Successful exit. The solution to every right-hand side is guaranteed. < 0: If INFO = -i, the i-th argument had an illegal value > 0 and <= N: U(INFO,INFO) is exactly zero. The factorization has been completed, but the factor U is exactly singular, so the solution and error bounds could not be computed. RCOND = 0 is returned. = N+J: The solution corresponding to the Jth right-hand side is not guaranteed. The solutions corresponding to other right- hand sides K with K > J may not be guaranteed as well, but only the first such right-hand side is reported. If a small componentwise error is not requested (PARAMS(3) = 0.0) then the Jth right-hand side is the first with a normwise error bound that is not guaranteed (the smallest J such that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0) the Jth right-hand side is the first with either a normwise or componentwise error bound that is not guaranteed (the smallest J such that either ERR_BNDS_NORM(J,1) = 0.0 or ERR_BNDS_COMP(J,1) = 0.0). See the definition of ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information about all of the right-hand sides check ERR_BNDS_NORM or ERR_BNDS_COMP.```

Definition at line 397 of file cherfsx.f.

401 *
402 * -- LAPACK computational routine --
403 * -- LAPACK is a software package provided by Univ. of Tennessee, --
404 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
405 *
406 * .. Scalar Arguments ..
407  CHARACTER UPLO, EQUED
408  INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS, NPARAMS,
409  \$ N_ERR_BNDS
410  REAL RCOND
411 * ..
412 * .. Array Arguments ..
413  INTEGER IPIV( * )
414  COMPLEX A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
415  \$ X( LDX, * ), WORK( * )
416  REAL S( * ), PARAMS( * ), BERR( * ), RWORK( * ),
417  \$ ERR_BNDS_NORM( NRHS, * ),
418  \$ ERR_BNDS_COMP( NRHS, * )
419 *
420 * ==================================================================
421 *
422 * .. Parameters ..
423  REAL ZERO, ONE
424  parameter( zero = 0.0e+0, one = 1.0e+0 )
425  REAL ITREF_DEFAULT, ITHRESH_DEFAULT,
426  \$ COMPONENTWISE_DEFAULT
427  REAL RTHRESH_DEFAULT, DZTHRESH_DEFAULT
428  parameter( itref_default = 1.0 )
429  parameter( ithresh_default = 10.0 )
430  parameter( componentwise_default = 1.0 )
431  parameter( rthresh_default = 0.5 )
432  parameter( dzthresh_default = 0.25 )
433  INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
434  \$ LA_LINRX_CWISE_I
435  parameter( la_linrx_itref_i = 1,
436  \$ la_linrx_ithresh_i = 2 )
437  parameter( la_linrx_cwise_i = 3 )
438  INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
439  \$ LA_LINRX_RCOND_I
440  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
441  parameter( la_linrx_rcond_i = 3 )
442 * ..
443 * .. Local Scalars ..
444  CHARACTER(1) NORM
445  LOGICAL RCEQU
446  INTEGER J, PREC_TYPE, REF_TYPE
447  INTEGER N_NORMS
448  REAL ANORM, RCOND_TMP
449  REAL ILLRCOND_THRESH, ERR_LBND, CWISE_WRONG
450  LOGICAL IGNORE_CWISE
451  INTEGER ITHRESH
452  REAL RTHRESH, UNSTABLE_THRESH
453 * ..
454 * .. External Subroutines ..
456 * ..
457 * .. Intrinsic Functions ..
458  INTRINSIC max, sqrt, transfer
459 * ..
460 * .. External Functions ..
461  EXTERNAL lsame, ilaprec
463  REAL SLAMCH, CLANHE, CLA_HERCOND_X, CLA_HERCOND_C
464  LOGICAL LSAME
465  INTEGER ILAPREC
466 * ..
467 * .. Executable Statements ..
468 *
469 * Check the input parameters.
470 *
471  info = 0
472  ref_type = int( itref_default )
473  IF ( nparams .GE. la_linrx_itref_i ) THEN
474  IF ( params( la_linrx_itref_i ) .LT. 0.0 ) THEN
475  params( la_linrx_itref_i ) = itref_default
476  ELSE
477  ref_type = params( la_linrx_itref_i )
478  END IF
479  END IF
480 *
481 * Set default parameters.
482 *
483  illrcond_thresh = real( n ) * slamch( 'Epsilon' )
484  ithresh = int( ithresh_default )
485  rthresh = rthresh_default
486  unstable_thresh = dzthresh_default
487  ignore_cwise = componentwise_default .EQ. 0.0
488 *
489  IF ( nparams.GE.la_linrx_ithresh_i ) THEN
490  IF ( params( la_linrx_ithresh_i ).LT.0.0 ) THEN
491  params( la_linrx_ithresh_i ) = ithresh
492  ELSE
493  ithresh = int( params( la_linrx_ithresh_i ) )
494  END IF
495  END IF
496  IF ( nparams.GE.la_linrx_cwise_i ) THEN
497  IF ( params(la_linrx_cwise_i ).LT.0.0 ) THEN
498  IF ( ignore_cwise ) THEN
499  params( la_linrx_cwise_i ) = 0.0
500  ELSE
501  params( la_linrx_cwise_i ) = 1.0
502  END IF
503  ELSE
504  ignore_cwise = params( la_linrx_cwise_i ) .EQ. 0.0
505  END IF
506  END IF
507  IF ( ref_type .EQ. 0 .OR. n_err_bnds .EQ. 0 ) THEN
508  n_norms = 0
509  ELSE IF ( ignore_cwise ) THEN
510  n_norms = 1
511  ELSE
512  n_norms = 2
513  END IF
514 *
515  rcequ = lsame( equed, 'Y' )
516 *
517 * Test input parameters.
518 *
519  IF (.NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
520  info = -1
521  ELSE IF( .NOT.rcequ .AND. .NOT.lsame( equed, 'N' ) ) THEN
522  info = -2
523  ELSE IF( n.LT.0 ) THEN
524  info = -3
525  ELSE IF( nrhs.LT.0 ) THEN
526  info = -4
527  ELSE IF( lda.LT.max( 1, n ) ) THEN
528  info = -6
529  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
530  info = -8
531  ELSE IF( ldb.LT.max( 1, n ) ) THEN
532  info = -12
533  ELSE IF( ldx.LT.max( 1, n ) ) THEN
534  info = -14
535  END IF
536  IF( info.NE.0 ) THEN
537  CALL xerbla( 'CHERFSX', -info )
538  RETURN
539  END IF
540 *
541 * Quick return if possible.
542 *
543  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
544  rcond = 1.0
545  DO j = 1, nrhs
546  berr( j ) = 0.0
547  IF ( n_err_bnds .GE. 1 ) THEN
548  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
549  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
550  END IF
551  IF ( n_err_bnds .GE. 2 ) THEN
552  err_bnds_norm( j, la_linrx_err_i ) = 0.0
553  err_bnds_comp( j, la_linrx_err_i ) = 0.0
554  END IF
555  IF ( n_err_bnds .GE. 3 ) THEN
556  err_bnds_norm( j, la_linrx_rcond_i ) = 1.0
557  err_bnds_comp( j, la_linrx_rcond_i ) = 1.0
558  END IF
559  END DO
560  RETURN
561  END IF
562 *
563 * Default to failure.
564 *
565  rcond = 0.0
566  DO j = 1, nrhs
567  berr( j ) = 1.0
568  IF ( n_err_bnds .GE. 1 ) THEN
569  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
570  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
571  END IF
572  IF ( n_err_bnds .GE. 2 ) THEN
573  err_bnds_norm( j, la_linrx_err_i ) = 1.0
574  err_bnds_comp( j, la_linrx_err_i ) = 1.0
575  END IF
576  IF ( n_err_bnds .GE. 3 ) THEN
577  err_bnds_norm( j, la_linrx_rcond_i ) = 0.0
578  err_bnds_comp( j, la_linrx_rcond_i ) = 0.0
579  END IF
580  END DO
581 *
582 * Compute the norm of A and the reciprocal of the condition
583 * number of A.
584 *
585  norm = 'I'
586  anorm = clanhe( norm, uplo, n, a, lda, rwork )
587  CALL checon( uplo, n, af, ldaf, ipiv, anorm, rcond, work,
588  \$ info )
589 *
590 * Perform refinement on each right-hand side
591 *
592  IF ( ref_type .NE. 0 ) THEN
593
594  prec_type = ilaprec( 'D' )
595
596  CALL cla_herfsx_extended( prec_type, uplo, n,
597  \$ nrhs, a, lda, af, ldaf, ipiv, rcequ, s, b,
598  \$ ldb, x, ldx, berr, n_norms, err_bnds_norm, err_bnds_comp,
599  \$ work, rwork, work(n+1),
600  \$ transfer(rwork(1:2*n), (/ (zero, zero) /), n), rcond,
601  \$ ithresh, rthresh, unstable_thresh, ignore_cwise,
602  \$ info )
603  END IF
604
605  err_lbnd = max( 10.0, sqrt( real( n ) ) ) * slamch( 'Epsilon' )
606  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 1 ) THEN
607 *
608 * Compute scaled normwise condition number cond(A*C).
609 *
610  IF ( rcequ ) THEN
611  rcond_tmp = cla_hercond_c( uplo, n, a, lda, af, ldaf, ipiv,
612  \$ s, .true., info, work, rwork )
613  ELSE
614  rcond_tmp = cla_hercond_c( uplo, n, a, lda, af, ldaf, ipiv,
615  \$ s, .false., info, work, rwork )
616  END IF
617  DO j = 1, nrhs
618 *
619 * Cap the error at 1.0.
620 *
621  IF ( n_err_bnds .GE. la_linrx_err_i
622  \$ .AND. err_bnds_norm( j, la_linrx_err_i ) .GT. 1.0 )
623  \$ err_bnds_norm( j, la_linrx_err_i ) = 1.0
624 *
625 * Threshold the error (see LAWN).
626 *
627  IF (rcond_tmp .LT. illrcond_thresh) THEN
628  err_bnds_norm( j, la_linrx_err_i ) = 1.0
629  err_bnds_norm( j, la_linrx_trust_i ) = 0.0
630  IF ( info .LE. n ) info = n + j
631  ELSE IF ( err_bnds_norm( j, la_linrx_err_i ) .LT. err_lbnd )
632  \$ THEN
633  err_bnds_norm( j, la_linrx_err_i ) = err_lbnd
634  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
635  END IF
636 *
637 * Save the condition number.
638 *
639  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
640  err_bnds_norm( j, la_linrx_rcond_i ) = rcond_tmp
641  END IF
642  END DO
643  END IF
644
645  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 2 ) THEN
646 *
647 * Compute componentwise condition number cond(A*diag(Y(:,J))) for
648 * each right-hand side using the current solution as an estimate of
649 * the true solution. If the componentwise error estimate is too
650 * large, then the solution is a lousy estimate of truth and the
651 * estimated RCOND may be too optimistic. To avoid misleading users,
652 * the inverse condition number is set to 0.0 when the estimated
653 * cwise error is at least CWISE_WRONG.
654 *
655  cwise_wrong = sqrt( slamch( 'Epsilon' ) )
656  DO j = 1, nrhs
657  IF ( err_bnds_comp( j, la_linrx_err_i ) .LT. cwise_wrong )
658  \$ THEN
659  rcond_tmp = cla_hercond_x( uplo, n, a, lda, af, ldaf,
660  \$ ipiv, x( 1, j ), info, work, rwork )
661  ELSE
662  rcond_tmp = 0.0
663  END IF
664 *
665 * Cap the error at 1.0.
666 *
667  IF ( n_err_bnds .GE. la_linrx_err_i
668  \$ .AND. err_bnds_comp( j, la_linrx_err_i ) .GT. 1.0 )
669  \$ err_bnds_comp( j, la_linrx_err_i ) = 1.0
670 *
671 * Threshold the error (see LAWN).
672 *
673  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
674  err_bnds_comp( j, la_linrx_err_i ) = 1.0
675  err_bnds_comp( j, la_linrx_trust_i ) = 0.0
676  IF ( .NOT. ignore_cwise
677  \$ .AND. info.LT.n + j ) info = n + j
678  ELSE IF ( err_bnds_comp( j, la_linrx_err_i )
679  \$ .LT. err_lbnd ) THEN
680  err_bnds_comp( j, la_linrx_err_i ) = err_lbnd
681  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
682  END IF
683 *
684 * Save the condition number.
685 *
686  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
687  err_bnds_comp( j, la_linrx_rcond_i ) = rcond_tmp
688  END IF
689
690  END DO
691  END IF
692 *
693  RETURN
694 *
695 * End of CHERFSX
696 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
integer function ilaprec(PREC)
ILAPREC
Definition: ilaprec.f:58
real function clanhe(NORM, UPLO, N, A, LDA, WORK)
CLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clanhe.f:124
subroutine checon(UPLO, N, A, LDA, IPIV, ANORM, RCOND, WORK, INFO)
CHECON
Definition: checon.f:125
real function cla_hercond_x(UPLO, N, A, LDA, AF, LDAF, IPIV, X, INFO, WORK, RWORK)
CLA_HERCOND_X computes the infinity norm condition number of op(A)*diag(x) for Hermitian indefinite m...
subroutine cla_herfsx_extended(PREC_TYPE, UPLO, N, NRHS, A, LDA, AF, LDAF, IPIV, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
CLA_HERFSX_EXTENDED improves the computed solution to a system of linear equations for Hermitian inde...
real function cla_hercond_c(UPLO, N, A, LDA, AF, LDAF, IPIV, C, CAPPLY, INFO, WORK, RWORK)
CLA_HERCOND_C computes the infinity norm condition number of op(A)*inv(diag(c)) for Hermitian indefin...
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: