 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ chetd2()

 subroutine chetd2 ( character UPLO, integer N, complex, dimension( lda, * ) A, integer LDA, real, dimension( * ) D, real, dimension( * ) E, complex, dimension( * ) TAU, integer INFO )

CHETD2 reduces a Hermitian matrix to real symmetric tridiagonal form by an unitary similarity transformation (unblocked algorithm).

Purpose:
``` CHETD2 reduces a complex Hermitian matrix A to real symmetric
tridiagonal form T by a unitary similarity transformation:
Q**H * A * Q = T.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in,out] A ``` A is COMPLEX array, dimension (LDA,N) On entry, the Hermitian matrix A. If UPLO = 'U', the leading n-by-n upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n-by-n lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if UPLO = 'U', the diagonal and first superdiagonal of A are overwritten by the corresponding elements of the tridiagonal matrix T, and the elements above the first superdiagonal, with the array TAU, represent the unitary matrix Q as a product of elementary reflectors; if UPLO = 'L', the diagonal and first subdiagonal of A are over- written by the corresponding elements of the tridiagonal matrix T, and the elements below the first subdiagonal, with the array TAU, represent the unitary matrix Q as a product of elementary reflectors. See Further Details.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [out] D ``` D is REAL array, dimension (N) The diagonal elements of the tridiagonal matrix T: D(i) = A(i,i).``` [out] E ``` E is REAL array, dimension (N-1) The off-diagonal elements of the tridiagonal matrix T: E(i) = A(i,i+1) if UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'.``` [out] TAU ``` TAU is COMPLEX array, dimension (N-1) The scalar factors of the elementary reflectors (see Further Details).``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value.```
Further Details:
```  If UPLO = 'U', the matrix Q is represented as a product of elementary
reflectors

Q = H(n-1) . . . H(2) H(1).

Each H(i) has the form

H(i) = I - tau * v * v**H

where tau is a complex scalar, and v is a complex vector with
v(i+1:n) = 0 and v(i) = 1; v(1:i-1) is stored on exit in
A(1:i-1,i+1), and tau in TAU(i).

If UPLO = 'L', the matrix Q is represented as a product of elementary
reflectors

Q = H(1) H(2) . . . H(n-1).

Each H(i) has the form

H(i) = I - tau * v * v**H

where tau is a complex scalar, and v is a complex vector with
v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in A(i+2:n,i),
and tau in TAU(i).

The contents of A on exit are illustrated by the following examples
with n = 5:

if UPLO = 'U':                       if UPLO = 'L':

(  d   e   v2  v3  v4 )              (  d                  )
(      d   e   v3  v4 )              (  e   d              )
(          d   e   v4 )              (  v1  e   d          )
(              d   e  )              (  v1  v2  e   d      )
(                  d  )              (  v1  v2  v3  e   d  )

where d and e denote diagonal and off-diagonal elements of T, and vi
denotes an element of the vector defining H(i).```

Definition at line 174 of file chetd2.f.

175 *
176 * -- LAPACK computational routine --
177 * -- LAPACK is a software package provided by Univ. of Tennessee, --
178 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
179 *
180 * .. Scalar Arguments ..
181  CHARACTER UPLO
182  INTEGER INFO, LDA, N
183 * ..
184 * .. Array Arguments ..
185  REAL D( * ), E( * )
186  COMPLEX A( LDA, * ), TAU( * )
187 * ..
188 *
189 * =====================================================================
190 *
191 * .. Parameters ..
192  COMPLEX ONE, ZERO, HALF
193  parameter( one = ( 1.0e+0, 0.0e+0 ),
194  \$ zero = ( 0.0e+0, 0.0e+0 ),
195  \$ half = ( 0.5e+0, 0.0e+0 ) )
196 * ..
197 * .. Local Scalars ..
198  LOGICAL UPPER
199  INTEGER I
200  COMPLEX ALPHA, TAUI
201 * ..
202 * .. External Subroutines ..
203  EXTERNAL caxpy, chemv, cher2, clarfg, xerbla
204 * ..
205 * .. External Functions ..
206  LOGICAL LSAME
207  COMPLEX CDOTC
208  EXTERNAL lsame, cdotc
209 * ..
210 * .. Intrinsic Functions ..
211  INTRINSIC max, min, real
212 * ..
213 * .. Executable Statements ..
214 *
215 * Test the input parameters
216 *
217  info = 0
218  upper = lsame( uplo, 'U' )
219  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
220  info = -1
221  ELSE IF( n.LT.0 ) THEN
222  info = -2
223  ELSE IF( lda.LT.max( 1, n ) ) THEN
224  info = -4
225  END IF
226  IF( info.NE.0 ) THEN
227  CALL xerbla( 'CHETD2', -info )
228  RETURN
229  END IF
230 *
231 * Quick return if possible
232 *
233  IF( n.LE.0 )
234  \$ RETURN
235 *
236  IF( upper ) THEN
237 *
238 * Reduce the upper triangle of A
239 *
240  a( n, n ) = real( a( n, n ) )
241  DO 10 i = n - 1, 1, -1
242 *
243 * Generate elementary reflector H(i) = I - tau * v * v**H
244 * to annihilate A(1:i-1,i+1)
245 *
246  alpha = a( i, i+1 )
247  CALL clarfg( i, alpha, a( 1, i+1 ), 1, taui )
248  e( i ) = real( alpha )
249 *
250  IF( taui.NE.zero ) THEN
251 *
252 * Apply H(i) from both sides to A(1:i,1:i)
253 *
254  a( i, i+1 ) = one
255 *
256 * Compute x := tau * A * v storing x in TAU(1:i)
257 *
258  CALL chemv( uplo, i, taui, a, lda, a( 1, i+1 ), 1, zero,
259  \$ tau, 1 )
260 *
261 * Compute w := x - 1/2 * tau * (x**H * v) * v
262 *
263  alpha = -half*taui*cdotc( i, tau, 1, a( 1, i+1 ), 1 )
264  CALL caxpy( i, alpha, a( 1, i+1 ), 1, tau, 1 )
265 *
266 * Apply the transformation as a rank-2 update:
267 * A := A - v * w**H - w * v**H
268 *
269  CALL cher2( uplo, i, -one, a( 1, i+1 ), 1, tau, 1, a,
270  \$ lda )
271 *
272  ELSE
273  a( i, i ) = real( a( i, i ) )
274  END IF
275  a( i, i+1 ) = e( i )
276  d( i+1 ) = real( a( i+1, i+1 ) )
277  tau( i ) = taui
278  10 CONTINUE
279  d( 1 ) = real( a( 1, 1 ) )
280  ELSE
281 *
282 * Reduce the lower triangle of A
283 *
284  a( 1, 1 ) = real( a( 1, 1 ) )
285  DO 20 i = 1, n - 1
286 *
287 * Generate elementary reflector H(i) = I - tau * v * v**H
288 * to annihilate A(i+2:n,i)
289 *
290  alpha = a( i+1, i )
291  CALL clarfg( n-i, alpha, a( min( i+2, n ), i ), 1, taui )
292  e( i ) = real( alpha )
293 *
294  IF( taui.NE.zero ) THEN
295 *
296 * Apply H(i) from both sides to A(i+1:n,i+1:n)
297 *
298  a( i+1, i ) = one
299 *
300 * Compute x := tau * A * v storing y in TAU(i:n-1)
301 *
302  CALL chemv( uplo, n-i, taui, a( i+1, i+1 ), lda,
303  \$ a( i+1, i ), 1, zero, tau( i ), 1 )
304 *
305 * Compute w := x - 1/2 * tau * (x**H * v) * v
306 *
307  alpha = -half*taui*cdotc( n-i, tau( i ), 1, a( i+1, i ),
308  \$ 1 )
309  CALL caxpy( n-i, alpha, a( i+1, i ), 1, tau( i ), 1 )
310 *
311 * Apply the transformation as a rank-2 update:
312 * A := A - v * w**H - w * v**H
313 *
314  CALL cher2( uplo, n-i, -one, a( i+1, i ), 1, tau( i ), 1,
315  \$ a( i+1, i+1 ), lda )
316 *
317  ELSE
318  a( i+1, i+1 ) = real( a( i+1, i+1 ) )
319  END IF
320  a( i+1, i ) = e( i )
321  d( i ) = real( a( i, i ) )
322  tau( i ) = taui
323  20 CONTINUE
324  d( n ) = real( a( n, n ) )
325  END IF
326 *
327  RETURN
328 *
329 * End of CHETD2
330 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
complex function cdotc(N, CX, INCX, CY, INCY)
CDOTC
Definition: cdotc.f:83
subroutine caxpy(N, CA, CX, INCX, CY, INCY)
CAXPY
Definition: caxpy.f:88
subroutine cher2(UPLO, N, ALPHA, X, INCX, Y, INCY, A, LDA)
CHER2
Definition: cher2.f:150
subroutine chemv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CHEMV
Definition: chemv.f:154
subroutine clarfg(N, ALPHA, X, INCX, TAU)
CLARFG generates an elementary reflector (Householder matrix).
Definition: clarfg.f:106
Here is the call graph for this function:
Here is the caller graph for this function: