LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
chetrd.f
Go to the documentation of this file.
1*> \brief \b CHETRD
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download CHETRD + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chetrd.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chetrd.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chetrd.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE CHETRD( UPLO, N, A, LDA, D, E, TAU, WORK, LWORK, INFO )
22*
23* .. Scalar Arguments ..
24* CHARACTER UPLO
25* INTEGER INFO, LDA, LWORK, N
26* ..
27* .. Array Arguments ..
28* REAL D( * ), E( * )
29* COMPLEX A( LDA, * ), TAU( * ), WORK( * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> CHETRD reduces a complex Hermitian matrix A to real symmetric
39*> tridiagonal form T by a unitary similarity transformation:
40*> Q**H * A * Q = T.
41*> \endverbatim
42*
43* Arguments:
44* ==========
45*
46*> \param[in] UPLO
47*> \verbatim
48*> UPLO is CHARACTER*1
49*> = 'U': Upper triangle of A is stored;
50*> = 'L': Lower triangle of A is stored.
51*> \endverbatim
52*>
53*> \param[in] N
54*> \verbatim
55*> N is INTEGER
56*> The order of the matrix A. N >= 0.
57*> \endverbatim
58*>
59*> \param[in,out] A
60*> \verbatim
61*> A is COMPLEX array, dimension (LDA,N)
62*> On entry, the Hermitian matrix A. If UPLO = 'U', the leading
63*> N-by-N upper triangular part of A contains the upper
64*> triangular part of the matrix A, and the strictly lower
65*> triangular part of A is not referenced. If UPLO = 'L', the
66*> leading N-by-N lower triangular part of A contains the lower
67*> triangular part of the matrix A, and the strictly upper
68*> triangular part of A is not referenced.
69*> On exit, if UPLO = 'U', the diagonal and first superdiagonal
70*> of A are overwritten by the corresponding elements of the
71*> tridiagonal matrix T, and the elements above the first
72*> superdiagonal, with the array TAU, represent the unitary
73*> matrix Q as a product of elementary reflectors; if UPLO
74*> = 'L', the diagonal and first subdiagonal of A are over-
75*> written by the corresponding elements of the tridiagonal
76*> matrix T, and the elements below the first subdiagonal, with
77*> the array TAU, represent the unitary matrix Q as a product
78*> of elementary reflectors. See Further Details.
79*> \endverbatim
80*>
81*> \param[in] LDA
82*> \verbatim
83*> LDA is INTEGER
84*> The leading dimension of the array A. LDA >= max(1,N).
85*> \endverbatim
86*>
87*> \param[out] D
88*> \verbatim
89*> D is REAL array, dimension (N)
90*> The diagonal elements of the tridiagonal matrix T:
91*> D(i) = A(i,i).
92*> \endverbatim
93*>
94*> \param[out] E
95*> \verbatim
96*> E is REAL array, dimension (N-1)
97*> The off-diagonal elements of the tridiagonal matrix T:
98*> E(i) = A(i,i+1) if UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'.
99*> \endverbatim
100*>
101*> \param[out] TAU
102*> \verbatim
103*> TAU is COMPLEX array, dimension (N-1)
104*> The scalar factors of the elementary reflectors (see Further
105*> Details).
106*> \endverbatim
107*>
108*> \param[out] WORK
109*> \verbatim
110*> WORK is COMPLEX array, dimension (MAX(1,LWORK))
111*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
112*> \endverbatim
113*>
114*> \param[in] LWORK
115*> \verbatim
116*> LWORK is INTEGER
117*> The dimension of the array WORK. LWORK >= 1.
118*> For optimum performance LWORK >= N*NB, where NB is the
119*> optimal blocksize.
120*>
121*> If LWORK = -1, then a workspace query is assumed; the routine
122*> only calculates the optimal size of the WORK array, returns
123*> this value as the first entry of the WORK array, and no error
124*> message related to LWORK is issued by XERBLA.
125*> \endverbatim
126*>
127*> \param[out] INFO
128*> \verbatim
129*> INFO is INTEGER
130*> = 0: successful exit
131*> < 0: if INFO = -i, the i-th argument had an illegal value
132*> \endverbatim
133*
134* Authors:
135* ========
136*
137*> \author Univ. of Tennessee
138*> \author Univ. of California Berkeley
139*> \author Univ. of Colorado Denver
140*> \author NAG Ltd.
141*
142*> \ingroup hetrd
143*
144*> \par Further Details:
145* =====================
146*>
147*> \verbatim
148*>
149*> If UPLO = 'U', the matrix Q is represented as a product of elementary
150*> reflectors
151*>
152*> Q = H(n-1) . . . H(2) H(1).
153*>
154*> Each H(i) has the form
155*>
156*> H(i) = I - tau * v * v**H
157*>
158*> where tau is a complex scalar, and v is a complex vector with
159*> v(i+1:n) = 0 and v(i) = 1; v(1:i-1) is stored on exit in
160*> A(1:i-1,i+1), and tau in TAU(i).
161*>
162*> If UPLO = 'L', the matrix Q is represented as a product of elementary
163*> reflectors
164*>
165*> Q = H(1) H(2) . . . H(n-1).
166*>
167*> Each H(i) has the form
168*>
169*> H(i) = I - tau * v * v**H
170*>
171*> where tau is a complex scalar, and v is a complex vector with
172*> v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in A(i+2:n,i),
173*> and tau in TAU(i).
174*>
175*> The contents of A on exit are illustrated by the following examples
176*> with n = 5:
177*>
178*> if UPLO = 'U': if UPLO = 'L':
179*>
180*> ( d e v2 v3 v4 ) ( d )
181*> ( d e v3 v4 ) ( e d )
182*> ( d e v4 ) ( v1 e d )
183*> ( d e ) ( v1 v2 e d )
184*> ( d ) ( v1 v2 v3 e d )
185*>
186*> where d and e denote diagonal and off-diagonal elements of T, and vi
187*> denotes an element of the vector defining H(i).
188*> \endverbatim
189*>
190* =====================================================================
191 SUBROUTINE chetrd( UPLO, N, A, LDA, D, E, TAU, WORK, LWORK, INFO )
192*
193* -- LAPACK computational routine --
194* -- LAPACK is a software package provided by Univ. of Tennessee, --
195* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
196*
197* .. Scalar Arguments ..
198 CHARACTER UPLO
199 INTEGER INFO, LDA, LWORK, N
200* ..
201* .. Array Arguments ..
202 REAL D( * ), E( * )
203 COMPLEX A( LDA, * ), TAU( * ), WORK( * )
204* ..
205*
206* =====================================================================
207*
208* .. Parameters ..
209 REAL ONE
210 parameter( one = 1.0e+0 )
211 COMPLEX CONE
212 parameter( cone = ( 1.0e+0, 0.0e+0 ) )
213* ..
214* .. Local Scalars ..
215 LOGICAL LQUERY, UPPER
216 INTEGER I, IINFO, IWS, J, KK, LDWORK, LWKOPT, NB,
217 $ NBMIN, NX
218* ..
219* .. External Subroutines ..
220 EXTERNAL cher2k, chetd2, clatrd, xerbla
221* ..
222* .. Intrinsic Functions ..
223 INTRINSIC max
224* ..
225* .. External Functions ..
226 LOGICAL LSAME
227 INTEGER ILAENV
228 REAL SROUNDUP_LWORK
229 EXTERNAL lsame, ilaenv, sroundup_lwork
230* ..
231* .. Executable Statements ..
232*
233* Test the input parameters
234*
235 info = 0
236 upper = lsame( uplo, 'U' )
237 lquery = ( lwork.EQ.-1 )
238 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
239 info = -1
240 ELSE IF( n.LT.0 ) THEN
241 info = -2
242 ELSE IF( lda.LT.max( 1, n ) ) THEN
243 info = -4
244 ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
245 info = -9
246 END IF
247*
248 IF( info.EQ.0 ) THEN
249*
250* Determine the block size.
251*
252 nb = ilaenv( 1, 'CHETRD', uplo, n, -1, -1, -1 )
253 lwkopt = n*nb
254 work( 1 ) = sroundup_lwork(lwkopt)
255 END IF
256*
257 IF( info.NE.0 ) THEN
258 CALL xerbla( 'CHETRD', -info )
259 RETURN
260 ELSE IF( lquery ) THEN
261 RETURN
262 END IF
263*
264* Quick return if possible
265*
266 IF( n.EQ.0 ) THEN
267 work( 1 ) = 1
268 RETURN
269 END IF
270*
271 nx = n
272 iws = 1
273 IF( nb.GT.1 .AND. nb.LT.n ) THEN
274*
275* Determine when to cross over from blocked to unblocked code
276* (last block is always handled by unblocked code).
277*
278 nx = max( nb, ilaenv( 3, 'CHETRD', uplo, n, -1, -1, -1 ) )
279 IF( nx.LT.n ) THEN
280*
281* Determine if workspace is large enough for blocked code.
282*
283 ldwork = n
284 iws = ldwork*nb
285 IF( lwork.LT.iws ) THEN
286*
287* Not enough workspace to use optimal NB: determine the
288* minimum value of NB, and reduce NB or force use of
289* unblocked code by setting NX = N.
290*
291 nb = max( lwork / ldwork, 1 )
292 nbmin = ilaenv( 2, 'CHETRD', uplo, n, -1, -1, -1 )
293 IF( nb.LT.nbmin )
294 $ nx = n
295 END IF
296 ELSE
297 nx = n
298 END IF
299 ELSE
300 nb = 1
301 END IF
302*
303 IF( upper ) THEN
304*
305* Reduce the upper triangle of A.
306* Columns 1:kk are handled by the unblocked method.
307*
308 kk = n - ( ( n-nx+nb-1 ) / nb )*nb
309 DO 20 i = n - nb + 1, kk + 1, -nb
310*
311* Reduce columns i:i+nb-1 to tridiagonal form and form the
312* matrix W which is needed to update the unreduced part of
313* the matrix
314*
315 CALL clatrd( uplo, i+nb-1, nb, a, lda, e, tau, work,
316 $ ldwork )
317*
318* Update the unreduced submatrix A(1:i-1,1:i-1), using an
319* update of the form: A := A - V*W**H - W*V**H
320*
321 CALL cher2k( uplo, 'No transpose', i-1, nb, -cone,
322 $ a( 1, i ), lda, work, ldwork, one, a, lda )
323*
324* Copy superdiagonal elements back into A, and diagonal
325* elements into D
326*
327 DO 10 j = i, i + nb - 1
328 a( j-1, j ) = e( j-1 )
329 d( j ) = real( a( j, j ) )
330 10 CONTINUE
331 20 CONTINUE
332*
333* Use unblocked code to reduce the last or only block
334*
335 CALL chetd2( uplo, kk, a, lda, d, e, tau, iinfo )
336 ELSE
337*
338* Reduce the lower triangle of A
339*
340 DO 40 i = 1, n - nx, nb
341*
342* Reduce columns i:i+nb-1 to tridiagonal form and form the
343* matrix W which is needed to update the unreduced part of
344* the matrix
345*
346 CALL clatrd( uplo, n-i+1, nb, a( i, i ), lda, e( i ),
347 $ tau( i ), work, ldwork )
348*
349* Update the unreduced submatrix A(i+nb:n,i+nb:n), using
350* an update of the form: A := A - V*W**H - W*V**H
351*
352 CALL cher2k( uplo, 'No transpose', n-i-nb+1, nb, -cone,
353 $ a( i+nb, i ), lda, work( nb+1 ), ldwork, one,
354 $ a( i+nb, i+nb ), lda )
355*
356* Copy subdiagonal elements back into A, and diagonal
357* elements into D
358*
359 DO 30 j = i, i + nb - 1
360 a( j+1, j ) = e( j )
361 d( j ) = real( a( j, j ) )
362 30 CONTINUE
363 40 CONTINUE
364*
365* Use unblocked code to reduce the last or only block
366*
367 CALL chetd2( uplo, n-i+1, a( i, i ), lda, d( i ), e( i ),
368 $ tau( i ), iinfo )
369 END IF
370*
371 work( 1 ) = sroundup_lwork(lwkopt)
372 RETURN
373*
374* End of CHETRD
375*
376 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine cher2k(uplo, trans, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
CHER2K
Definition cher2k.f:197
subroutine chetd2(uplo, n, a, lda, d, e, tau, info)
CHETD2 reduces a Hermitian matrix to real symmetric tridiagonal form by an unitary similarity transfo...
Definition chetd2.f:175
subroutine chetrd(uplo, n, a, lda, d, e, tau, work, lwork, info)
CHETRD
Definition chetrd.f:192
subroutine clatrd(uplo, n, nb, a, lda, e, tau, w, ldw)
CLATRD reduces the first nb rows and columns of a symmetric/Hermitian matrix A to real tridiagonal fo...
Definition clatrd.f:199