chet01_3()

subroutine chet01_3	(	character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldafac, * )	afac,
		integer	ldafac,
		complex, dimension( * )	e,
		integer, dimension( * )	ipiv,
		complex, dimension( ldc, * )	c,
		integer	ldc,
		real, dimension( * )	rwork,
		real	resid )

CHET01_3

Purpose:

!>
!> CHET01_3 reconstructs a Hermitian indefinite matrix A from its
!> block L*D*L' or U*D*U' factorization computed by CHETRF_RK
!> (or CHETRF_BK) and computes the residual
!>    norm( C - A ) / ( N * norm(A) * EPS ),
!> where C is the reconstructed matrix and EPS is the machine epsilon.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> Hermitian matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The number of rows and columns of the matrix A. N >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> The original Hermitian matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N) !>
[in]	AFAC	!> AFAC is COMPLEX array, dimension (LDAFAC,N) !> Diagonal of the block diagonal matrix D and factors U or L !> as computed by CHETRF_RK and CHETRF_BK: !> a) ONLY diagonal elements of the Hermitian block diagonal !> matrix D on the diagonal of A, i.e. D(k,k) = A(k,k); !> (superdiagonal (or subdiagonal) elements of D !> should be provided on entry in array E), and !> b) If UPLO = 'U': factor U in the superdiagonal part of A. !> If UPLO = 'L': factor L in the subdiagonal part of A. !>
[in]	LDAFAC	!> LDAFAC is INTEGER !> The leading dimension of the array AFAC. !> LDAFAC >= max(1,N). !>
[in]	E	!> E is COMPLEX array, dimension (N) !> On entry, contains the superdiagonal (or subdiagonal) !> elements of the Hermitian block diagonal matrix D !> with 1-by-1 or 2-by-2 diagonal blocks, where !> If UPLO = 'U': E(i) = D(i-1,i),i=2:N, E(1) not referenced; !> If UPLO = 'L': E(i) = D(i+1,i),i=1:N-1, E(N) not referenced. !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N) !> The pivot indices from CHETRF_RK (or CHETRF_BK). !>
[out]	C	!> C is COMPLEX array, dimension (LDC,N) !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,N). !>
[out]	RWORK	!> RWORK is REAL array, dimension (N) !>
[out]	RESID	!> RESID is REAL !> If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS ) !> If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 139 of file chet01_3.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDA, LDAFAC, LDC, N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      REAL               RWORK( * )
      COMPLEX            A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
     $                   E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J
      REAL               ANORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               CLANHE, SLAMCH
      EXTERNAL           lsame, clanhe, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           claset, clavhe_rook, csyconvf_rook
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     a) Revert to multipliers of L
*
      CALL csyconvf_rook( uplo, 'R', n, afac, ldafac, e, ipiv, info )
*
*     1) Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      anorm = clanhe( '1', uplo, n, a, lda, rwork )
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      DO j = 1, n
         IF( aimag( afac( j, j ) ).NE.zero ) THEN
            resid = one / eps
            RETURN
         END IF
      END DO
*
*     2) Initialize C to the identity matrix.
*
      CALL claset( 'Full', n, n, czero, cone, c, ldc )
*
*     3) Call CLAVHE_ROOK to form the product D * U' (or D * L' ).
*
      CALL clavhe_rook( uplo, 'Conjugate', 'Non-unit', n, n, afac,
     $                  ldafac, ipiv, c, ldc, info )
*
*     4) Call ZLAVHE_RK again to multiply by U (or L ).
*
      CALL clavhe_rook( uplo, 'No transpose', 'Unit', n, n, afac,
     $                  ldafac, ipiv, c, ldc, info )
*
*     5) Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO j = 1, n
            DO i = 1, j - 1
               c( i, j ) = c( i, j ) - a( i, j )
            END DO
            c( j, j ) = c( j, j ) - real( a( j, j ) )
         END DO
      ELSE
         DO j = 1, n
            c( j, j ) = c( j, j ) - real( a( j, j ) )
            DO i = j + 1, n
               c( i, j ) = c( i, j ) - a( i, j )
            END DO
         END DO
      END IF
*
*     6) Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = clanhe( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid/real( n ) )/anorm ) / eps
      END IF
*
*     b) Convert to factor of L (or U)
*
      CALL csyconvf_rook( uplo, 'C', n, afac, ldafac, e, ipiv, info )
*
      RETURN
*
*     End of CHET01_3
*

Here is the call graph for this function:

Here is the caller graph for this function: