sppequ()

subroutine sppequ	(	character	uplo,
		integer	n,
		real, dimension( * )	ap,
		real, dimension( * )	s,
		real	scond,
		real	amax,
		integer	info )

SPPEQU

Download SPPEQU + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SPPEQU computes row and column scalings intended to equilibrate a
!> symmetric positive definite matrix A in packed storage and reduce
!> its condition number (with respect to the two-norm).  S contains the
!> scale factors, S(i)=1/sqrt(A(i,i)), chosen so that the scaled matrix
!> B with elements B(i,j)=S(i)*A(i,j)*S(j) has ones on the diagonal.
!> This choice of S puts the condition number of B within a factor N of
!> the smallest possible condition number over all possible diagonal
!> scalings.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangle of A is stored; !> = 'L': Lower triangle of A is stored. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	AP	!> AP is REAL array, dimension (N*(N+1)/2) !> The upper or lower triangle of the symmetric matrix A, packed !> columnwise in a linear array. The j-th column of A is stored !> in the array AP as follows: !> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. !>
[out]	S	!> S is REAL array, dimension (N) !> If INFO = 0, S contains the scale factors for A. !>
[out]	SCOND	!> SCOND is REAL !> If INFO = 0, S contains the ratio of the smallest S(i) to !> the largest S(i). If SCOND >= 0.1 and AMAX is neither too !> large nor too small, it is not worth scaling by S. !>
[out]	AMAX	!> AMAX is REAL !> Absolute value of largest matrix element. If AMAX is very !> close to overflow or very close to underflow, the matrix !> should be scaled. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, the i-th diagonal element is nonpositive. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 113 of file sppequ.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, N
      REAL               AMAX, SCOND
*     ..
*     .. Array Arguments ..
      REAL               AP( * ), S( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, JJ
      REAL               SMIN
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SPPEQU', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         scond = one
         amax = zero
         RETURN
      END IF
*
*     Initialize SMIN and AMAX.
*
      s( 1 ) = ap( 1 )
      smin = s( 1 )
      amax = s( 1 )
*
      IF( upper ) THEN
*
*        UPLO = 'U':  Upper triangle of A is stored.
*        Find the minimum and maximum diagonal elements.
*
         jj = 1
         DO 10 i = 2, n
            jj = jj + i
            s( i ) = ap( jj )
            smin = min( smin, s( i ) )
            amax = max( amax, s( i ) )
   10    CONTINUE
*
      ELSE
*
*        UPLO = 'L':  Lower triangle of A is stored.
*        Find the minimum and maximum diagonal elements.
*
         jj = 1
         DO 20 i = 2, n
            jj = jj + n - i + 2
            s( i ) = ap( jj )
            smin = min( smin, s( i ) )
            amax = max( amax, s( i ) )
   20    CONTINUE
      END IF
*
      IF( smin.LE.zero ) THEN
*
*        Find the first non-positive diagonal element and return.
*
         DO 30 i = 1, n
            IF( s( i ).LE.zero ) THEN
               info = i
               RETURN
            END IF
   30    CONTINUE
      ELSE
*
*        Set the scale factors to the reciprocals
*        of the diagonal elements.
*
         DO 40 i = 1, n
            s( i ) = one / sqrt( s( i ) )
   40    CONTINUE
*
*        Compute SCOND = min(S(I)) / max(S(I))
*
         scond = sqrt( smin ) / sqrt( amax )
      END IF
      RETURN
*
*     End of SPPEQU
*

Here is the call graph for this function:

Here is the caller graph for this function: