cgemlq.f

Go to the documentation of this file.

*> \brief \b CGEMLQ
*
*  Definition:
*  ===========
*
*      SUBROUTINE CGEMLQ( SIDE, TRANS, M, N, K, A, LDA, T,
*     $                   TSIZE, C, LDC, WORK, LWORK, INFO )
*
*
*     .. Scalar Arguments ..
*     CHARACTER         SIDE, TRANS
*     INTEGER           INFO, LDA, M, N, K, LDT, TSIZE, LWORK, LDC
*     ..
*     .. Array Arguments ..
*     COMPLEX           A( LDA, * ), T( * ), C(LDC, * ), WORK( * )
*     ..
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>     CGEMLQ overwrites the general real M-by-N matrix C with
*>
*>                      SIDE = 'L'     SIDE = 'R'
*>      TRANS = 'N':      Q * C          C * Q
*>      TRANS = 'C':      Q**H * C       C * Q**H
*>      where Q is a complex unitary matrix defined as the product
*>      of blocked elementary reflectors computed by short wide
*>      LQ factorization (CGELQ)
*>
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] SIDE
*> \verbatim
*>          SIDE is CHARACTER*1
*>          = 'L': apply Q or Q**H from the Left;
*>          = 'R': apply Q or Q**H from the Right.
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          = 'N':  No transpose, apply Q;
*>          = 'C':  Conjugate transpose, apply Q**H.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >=0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix C. N >= 0.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of elementary reflectors whose product defines
*>          the matrix Q.
*>          If SIDE = 'L', M >= K >= 0;
*>          if SIDE = 'R', N >= K >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension
*>                               (LDA,M) if SIDE = 'L',
*>                               (LDA,N) if SIDE = 'R'
*>          Part of the data structure to represent Q as returned by CGELQ.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A. LDA >= max(1,K).
*> \endverbatim
*>
*> \param[in] T
*> \verbatim
*>          T is COMPLEX array, dimension (MAX(5,TSIZE)).
*>          Part of the data structure to represent Q as returned by CGELQ.
*> \endverbatim
*>
*> \param[in] TSIZE
*> \verbatim
*>          TSIZE is INTEGER
*>          The dimension of the array T. TSIZE >= 5.
*> \endverbatim
*>
*> \param[in,out] C
*> \verbatim
*>          C is COMPLEX array, dimension (LDC,N)
*>          On entry, the M-by-N matrix C.
*>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*>          LDC is INTEGER
*>          The leading dimension of the array C. LDC >= max(1,M).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          (workspace) COMPLEX array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the minimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK. LWORK >= 1.
*>          If LWORK = -1, then a workspace query is assumed. The routine
*>          only calculates the size of the WORK array, returns this
*>          value as WORK(1), and no error message related to WORK
*>          is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \par Further Details
*  ====================
*>
*> \verbatim
*>
*> These details are particular for this LAPACK implementation. Users should not
*> take them for granted. These details may change in the future, and are not likely
*> true for another LAPACK implementation. These details are relevant if one wants
*> to try to understand the code. They are not part of the interface.
*>
*> In this version,
*>
*>          T(2): row block size (MB)
*>          T(3): column block size (NB)
*>          T(6:TSIZE): data structure needed for Q, computed by
*>                           CLASWQR or CGELQT
*>
*>  Depending on the matrix dimensions M and N, and row and column
*>  block sizes MB and NB returned by ILAENV, CGELQ will use either
*>  CLASWLQ (if the matrix is wide-and-short) or CGELQT to compute
*>  the LQ factorization.
*>  This version of CGEMLQ will use either CLAMSWLQ or CGEMLQT to
*>  multiply matrix Q by another matrix.
*>  Further Details in CLAMSWLQ or CGEMLQT.
*> \endverbatim
*>
*> \ingroup gemlq
*>
*  =====================================================================
      SUBROUTINE cgemlq( SIDE, TRANS, M, N, K, A, LDA, T, TSIZE,
     $                   C, LDC, WORK, LWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, LDA, M, N, K, TSIZE, LWORK, LDC
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, RIGHT, TRAN, NOTRAN, LQUERY
      INTEGER            MB, NB, LW, NBLCKS, MN, MINMNK, LWMIN
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SROUNDUP_LWORK
      EXTERNAL           lsame, sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           clamswlq, cgemlqt, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          int, max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      lquery  = ( lwork.EQ.-1 )
      notran  = lsame( trans, 'N' )
      tran    = lsame( trans, 'C' )
      left    = lsame( side, 'L' )
      right   = lsame( side, 'R' )
*
      mb = int( t( 2 ) )
      nb = int( t( 3 ) )
      IF( left ) THEN
        lw = n * mb
        mn = m
      ELSE
        lw = m * mb
        mn = n
      END IF
*
      minmnk = min( m, n, k )
      IF( minmnk.EQ.0 ) THEN
         lwmin = 1
      ELSE
         lwmin = max( 1, lw )
      END IF
*
      IF( ( nb.GT.k ) .AND. ( mn.GT.k ) ) THEN
        IF( mod( mn - k, nb - k ) .EQ. 0 ) THEN
          nblcks = ( mn - k ) / ( nb - k )
        ELSE
          nblcks = ( mn - k ) / ( nb - k ) + 1
        END IF
      ELSE
        nblcks = 1
      END IF
*
      info = 0
      IF( .NOT.left .AND. .NOT.right ) THEN
        info = -1
      ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
        info = -2
      ELSE IF( m.LT.0 ) THEN
        info = -3
      ELSE IF( n.LT.0 ) THEN
        info = -4
      ELSE IF( k.LT.0 .OR. k.GT.mn ) THEN
        info = -5
      ELSE IF( lda.LT.max( 1, k ) ) THEN
        info = -7
      ELSE IF( tsize.LT.5 ) THEN
        info = -9
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
        info = -11
      ELSE IF( ( lwork.LT.lwmin ) .AND. ( .NOT.lquery ) ) THEN
        info = -13
      END IF
*
      IF( info.EQ.0 ) THEN
        work( 1 ) = sroundup_lwork( lwmin )
      END IF
*
      IF( info.NE.0 ) THEN
        CALL xerbla( 'CGEMLQ', -info )
        RETURN
      ELSE IF( lquery ) THEN
        RETURN
      END IF
*
*     Quick return if possible
*
      IF( minmnk.EQ.0 ) THEN
        RETURN
      END IF
*
      IF( ( left .AND. m.LE.k ) .OR. ( right .AND. n.LE.k )
     $     .OR. ( nb.LE.k ) .OR. ( nb.GE.max( m, n, k ) ) ) THEN
        CALL cgemlqt( side, trans, m, n, k, mb, a, lda,
     $                t( 6 ), mb, c, ldc, work, info )
      ELSE
        CALL clamswlq( side, trans, m, n, k, mb, nb, a, lda, t( 6 ),
     $                 mb, c, ldc, work, lwork, info )
      END IF
*
      work( 1 ) = sroundup_lwork( lwmin )
*
      RETURN
*
*     End of CGEMLQ
*
      SUBROUTINE cgemlq( SIDE, TRANS, M, N, K, A, LDA, T, TSIZE, …
      END