LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ sgges3()

 subroutine sgges3 ( character JOBVSL, character JOBVSR, character SORT, external SELCTG, integer N, real, dimension( lda, * ) A, integer LDA, real, dimension( ldb, * ) B, integer LDB, integer SDIM, real, dimension( * ) ALPHAR, real, dimension( * ) ALPHAI, real, dimension( * ) BETA, real, dimension( ldvsl, * ) VSL, integer LDVSL, real, dimension( ldvsr, * ) VSR, integer LDVSR, real, dimension( * ) WORK, integer LWORK, logical, dimension( * ) BWORK, integer INFO )

SGGES3 computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices (blocked algorithm)

Purpose:
``` SGGES3 computes for a pair of N-by-N real nonsymmetric matrices (A,B),
the generalized eigenvalues, the generalized real Schur form (S,T),
optionally, the left and/or right matrices of Schur vectors (VSL and
VSR). This gives the generalized Schur factorization

(A,B) = ( (VSL)*S*(VSR)**T, (VSL)*T*(VSR)**T )

Optionally, it also orders the eigenvalues so that a selected cluster
of eigenvalues appears in the leading diagonal blocks of the upper
quasi-triangular matrix S and the upper triangular matrix T.The
leading columns of VSL and VSR then form an orthonormal basis for the
corresponding left and right eigenspaces (deflating subspaces).

(If only the generalized eigenvalues are needed, use the driver

A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
or a ratio alpha/beta = w, such that  A - w*B is singular.  It is
usually represented as the pair (alpha,beta), as there is a
reasonable interpretation for beta=0 or both being zero.

A pair of matrices (S,T) is in generalized real Schur form if T is
upper triangular with non-negative diagonal and S is block upper
triangular with 1-by-1 and 2-by-2 blocks.  1-by-1 blocks correspond
to real generalized eigenvalues, while 2-by-2 blocks of S will be
"standardized" by making the corresponding elements of T have the
form:
[  a  0  ]
[  0  b  ]

and the pair of corresponding 2-by-2 blocks in S and T will have a
complex conjugate pair of generalized eigenvalues.```
Parameters
 [in] JOBVSL ``` JOBVSL is CHARACTER*1 = 'N': do not compute the left Schur vectors; = 'V': compute the left Schur vectors.``` [in] JOBVSR ``` JOBVSR is CHARACTER*1 = 'N': do not compute the right Schur vectors; = 'V': compute the right Schur vectors.``` [in] SORT ``` SORT is CHARACTER*1 Specifies whether or not to order the eigenvalues on the diagonal of the generalized Schur form. = 'N': Eigenvalues are not ordered; = 'S': Eigenvalues are ordered (see SELCTG);``` [in] SELCTG ``` SELCTG is a LOGICAL FUNCTION of three REAL arguments SELCTG must be declared EXTERNAL in the calling subroutine. If SORT = 'N', SELCTG is not referenced. If SORT = 'S', SELCTG is used to select eigenvalues to sort to the top left of the Schur form. An eigenvalue (ALPHAR(j)+ALPHAI(j))/BETA(j) is selected if SELCTG(ALPHAR(j),ALPHAI(j),BETA(j)) is true; i.e. if either one of a complex conjugate pair of eigenvalues is selected, then both complex eigenvalues are selected. Note that in the ill-conditioned case, a selected complex eigenvalue may no longer satisfy SELCTG(ALPHAR(j),ALPHAI(j), BETA(j)) = .TRUE. after ordering. INFO is to be set to N+2 in this case.``` [in] N ``` N is INTEGER The order of the matrices A, B, VSL, and VSR. N >= 0.``` [in,out] A ``` A is REAL array, dimension (LDA, N) On entry, the first of the pair of matrices. On exit, A has been overwritten by its generalized Schur form S.``` [in] LDA ``` LDA is INTEGER The leading dimension of A. LDA >= max(1,N).``` [in,out] B ``` B is REAL array, dimension (LDB, N) On entry, the second of the pair of matrices. On exit, B has been overwritten by its generalized Schur form T.``` [in] LDB ``` LDB is INTEGER The leading dimension of B. LDB >= max(1,N).``` [out] SDIM ``` SDIM is INTEGER If SORT = 'N', SDIM = 0. If SORT = 'S', SDIM = number of eigenvalues (after sorting) for which SELCTG is true. (Complex conjugate pairs for which SELCTG is true for either eigenvalue count as 2.)``` [out] ALPHAR ` ALPHAR is REAL array, dimension (N)` [out] ALPHAI ` ALPHAI is REAL array, dimension (N)` [out] BETA ``` BETA is REAL array, dimension (N) On exit, (ALPHAR(j) + ALPHAI(j)*i)/BETA(j), j=1,...,N, will be the generalized eigenvalues. ALPHAR(j) + ALPHAI(j)*i, and BETA(j),j=1,...,N are the diagonals of the complex Schur form (S,T) that would result if the 2-by-2 diagonal blocks of the real Schur form of (A,B) were further reduced to triangular form using 2-by-2 complex unitary transformations. If ALPHAI(j) is zero, then the j-th eigenvalue is real; if positive, then the j-th and (j+1)-st eigenvalues are a complex conjugate pair, with ALPHAI(j+1) negative. Note: the quotients ALPHAR(j)/BETA(j) and ALPHAI(j)/BETA(j) may easily over- or underflow, and BETA(j) may even be zero. Thus, the user should avoid naively computing the ratio. However, ALPHAR and ALPHAI will be always less than and usually comparable with norm(A) in magnitude, and BETA always less than and usually comparable with norm(B).``` [out] VSL ``` VSL is REAL array, dimension (LDVSL,N) If JOBVSL = 'V', VSL will contain the left Schur vectors. Not referenced if JOBVSL = 'N'.``` [in] LDVSL ``` LDVSL is INTEGER The leading dimension of the matrix VSL. LDVSL >=1, and if JOBVSL = 'V', LDVSL >= N.``` [out] VSR ``` VSR is REAL array, dimension (LDVSR,N) If JOBVSR = 'V', VSR will contain the right Schur vectors. Not referenced if JOBVSR = 'N'.``` [in] LDVSR ``` LDVSR is INTEGER The leading dimension of the matrix VSR. LDVSR >= 1, and if JOBVSR = 'V', LDVSR >= N.``` [out] WORK ``` WORK is REAL array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.``` [in] LWORK ``` LWORK is INTEGER The dimension of the array WORK. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.``` [out] BWORK ``` BWORK is LOGICAL array, dimension (N) Not referenced if SORT = 'N'.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value. = 1,...,N: The QZ iteration failed. (A,B) are not in Schur form, but ALPHAR(j), ALPHAI(j), and BETA(j) should be correct for j=INFO+1,...,N. > N: =N+1: other than QZ iteration failed in SLAQZ0. =N+2: after reordering, roundoff changed values of some complex eigenvalues so that leading eigenvalues in the Generalized Schur form no longer satisfy SELCTG=.TRUE. This could also be caused due to scaling. =N+3: reordering failed in STGSEN.```

Definition at line 279 of file sgges3.f.

282*
283* -- LAPACK driver routine --
284* -- LAPACK is a software package provided by Univ. of Tennessee, --
285* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
286*
287* .. Scalar Arguments ..
288 CHARACTER JOBVSL, JOBVSR, SORT
289 INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
290* ..
291* .. Array Arguments ..
292 LOGICAL BWORK( * )
293 REAL A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
294 \$ B( LDB, * ), BETA( * ), VSL( LDVSL, * ),
295 \$ VSR( LDVSR, * ), WORK( * )
296* ..
297* .. Function Arguments ..
298 LOGICAL SELCTG
299 EXTERNAL selctg
300* ..
301*
302* =====================================================================
303*
304* .. Parameters ..
305 REAL ZERO, ONE
306 parameter( zero = 0.0e+0, one = 1.0e+0 )
307* ..
308* .. Local Scalars ..
309 LOGICAL CURSL, ILASCL, ILBSCL, ILVSL, ILVSR, LASTSL,
310 \$ LQUERY, LST2SL, WANTST
311 INTEGER I, ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT,
312 \$ ILO, IP, IRIGHT, IROWS, ITAU, IWRK, LWKOPT
313 REAL ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS, PVSL,
314 \$ PVSR, SAFMAX, SAFMIN, SMLNUM
315* ..
316* .. Local Arrays ..
317 INTEGER IDUM( 1 )
318 REAL DIF( 2 )
319* ..
320* .. External Subroutines ..
321 EXTERNAL sgeqrf, sggbak, sggbal, sgghd3, slaqz0, slabad,
323 \$ xerbla
324* ..
325* .. External Functions ..
326 LOGICAL LSAME
327 REAL SLAMCH, SLANGE
328 EXTERNAL lsame, slamch, slange
329* ..
330* .. Intrinsic Functions ..
331 INTRINSIC abs, max, sqrt
332* ..
333* .. Executable Statements ..
334*
335* Decode the input arguments
336*
337 IF( lsame( jobvsl, 'N' ) ) THEN
338 ijobvl = 1
339 ilvsl = .false.
340 ELSE IF( lsame( jobvsl, 'V' ) ) THEN
341 ijobvl = 2
342 ilvsl = .true.
343 ELSE
344 ijobvl = -1
345 ilvsl = .false.
346 END IF
347*
348 IF( lsame( jobvsr, 'N' ) ) THEN
349 ijobvr = 1
350 ilvsr = .false.
351 ELSE IF( lsame( jobvsr, 'V' ) ) THEN
352 ijobvr = 2
353 ilvsr = .true.
354 ELSE
355 ijobvr = -1
356 ilvsr = .false.
357 END IF
358*
359 wantst = lsame( sort, 'S' )
360*
361* Test the input arguments
362*
363 info = 0
364 lquery = ( lwork.EQ.-1 )
365 IF( ijobvl.LE.0 ) THEN
366 info = -1
367 ELSE IF( ijobvr.LE.0 ) THEN
368 info = -2
369 ELSE IF( ( .NOT.wantst ) .AND. ( .NOT.lsame( sort, 'N' ) ) ) THEN
370 info = -3
371 ELSE IF( n.LT.0 ) THEN
372 info = -5
373 ELSE IF( lda.LT.max( 1, n ) ) THEN
374 info = -7
375 ELSE IF( ldb.LT.max( 1, n ) ) THEN
376 info = -9
377 ELSE IF( ldvsl.LT.1 .OR. ( ilvsl .AND. ldvsl.LT.n ) ) THEN
378 info = -15
379 ELSE IF( ldvsr.LT.1 .OR. ( ilvsr .AND. ldvsr.LT.n ) ) THEN
380 info = -17
381 ELSE IF( lwork.LT.6*n+16 .AND. .NOT.lquery ) THEN
382 info = -19
383 END IF
384*
385* Compute workspace
386*
387 IF( info.EQ.0 ) THEN
388 CALL sgeqrf( n, n, b, ldb, work, work, -1, ierr )
389 lwkopt = max( 6*n+16, 3*n+int( work( 1 ) ) )
390 CALL sormqr( 'L', 'T', n, n, n, b, ldb, work, a, lda, work,
391 \$ -1, ierr )
392 lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
393 IF( ilvsl ) THEN
394 CALL sorgqr( n, n, n, vsl, ldvsl, work, work, -1, ierr )
395 lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
396 END IF
397 CALL sgghd3( jobvsl, jobvsr, n, 1, n, a, lda, b, ldb, vsl,
398 \$ ldvsl, vsr, ldvsr, work, -1, ierr )
399 lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
400 CALL slaqz0( 'S', jobvsl, jobvsr, n, 1, n, a, lda, b, ldb,
401 \$ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
402 \$ work, -1, 0, ierr )
403 lwkopt = max( lwkopt, 2*n+int( work( 1 ) ) )
404 IF( wantst ) THEN
405 CALL stgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb,
406 \$ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
407 \$ sdim, pvsl, pvsr, dif, work, -1, idum, 1,
408 \$ ierr )
409 lwkopt = max( lwkopt, 2*n+int( work( 1 ) ) )
410 END IF
411 work( 1 ) = lwkopt
412 END IF
413*
414 IF( info.NE.0 ) THEN
415 CALL xerbla( 'SGGES3 ', -info )
416 RETURN
417 ELSE IF( lquery ) THEN
418 RETURN
419 END IF
420*
421* Quick return if possible
422*
423 IF( n.EQ.0 ) THEN
424 sdim = 0
425 RETURN
426 END IF
427*
428* Get machine constants
429*
430 eps = slamch( 'P' )
431 safmin = slamch( 'S' )
432 safmax = one / safmin
433 CALL slabad( safmin, safmax )
434 smlnum = sqrt( safmin ) / eps
435 bignum = one / smlnum
436*
437* Scale A if max element outside range [SMLNUM,BIGNUM]
438*
439 anrm = slange( 'M', n, n, a, lda, work )
440 ilascl = .false.
441 IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
442 anrmto = smlnum
443 ilascl = .true.
444 ELSE IF( anrm.GT.bignum ) THEN
445 anrmto = bignum
446 ilascl = .true.
447 END IF
448 IF( ilascl )
449 \$ CALL slascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
450*
451* Scale B if max element outside range [SMLNUM,BIGNUM]
452*
453 bnrm = slange( 'M', n, n, b, ldb, work )
454 ilbscl = .false.
455 IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
456 bnrmto = smlnum
457 ilbscl = .true.
458 ELSE IF( bnrm.GT.bignum ) THEN
459 bnrmto = bignum
460 ilbscl = .true.
461 END IF
462 IF( ilbscl )
463 \$ CALL slascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
464*
465* Permute the matrix to make it more nearly triangular
466*
467 ileft = 1
468 iright = n + 1
469 iwrk = iright + n
470 CALL sggbal( 'P', n, a, lda, b, ldb, ilo, ihi, work( ileft ),
471 \$ work( iright ), work( iwrk ), ierr )
472*
473* Reduce B to triangular form (QR decomposition of B)
474*
475 irows = ihi + 1 - ilo
476 icols = n + 1 - ilo
477 itau = iwrk
478 iwrk = itau + irows
479 CALL sgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
480 \$ work( iwrk ), lwork+1-iwrk, ierr )
481*
482* Apply the orthogonal transformation to matrix A
483*
484 CALL sormqr( 'L', 'T', irows, icols, irows, b( ilo, ilo ), ldb,
485 \$ work( itau ), a( ilo, ilo ), lda, work( iwrk ),
486 \$ lwork+1-iwrk, ierr )
487*
488* Initialize VSL
489*
490 IF( ilvsl ) THEN
491 CALL slaset( 'Full', n, n, zero, one, vsl, ldvsl )
492 IF( irows.GT.1 ) THEN
493 CALL slacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
494 \$ vsl( ilo+1, ilo ), ldvsl )
495 END IF
496 CALL sorgqr( irows, irows, irows, vsl( ilo, ilo ), ldvsl,
497 \$ work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
498 END IF
499*
500* Initialize VSR
501*
502 IF( ilvsr )
503 \$ CALL slaset( 'Full', n, n, zero, one, vsr, ldvsr )
504*
505* Reduce to generalized Hessenberg form
506*
507 CALL sgghd3( jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb, vsl,
508 \$ ldvsl, vsr, ldvsr, work( iwrk ), lwork+1-iwrk, ierr )
509*
510* Perform QZ algorithm, computing Schur vectors if desired
511*
512 iwrk = itau
513 CALL slaqz0( 'S', jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb,
514 \$ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
515 \$ work( iwrk ), lwork+1-iwrk, 0, ierr )
516 IF( ierr.NE.0 ) THEN
517 IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
518 info = ierr
519 ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
520 info = ierr - n
521 ELSE
522 info = n + 1
523 END IF
524 GO TO 40
525 END IF
526*
527* Sort eigenvalues ALPHA/BETA if desired
528*
529 sdim = 0
530 IF( wantst ) THEN
531*
532* Undo scaling on eigenvalues before SELCTGing
533*
534 IF( ilascl ) THEN
535 CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n,
536 \$ ierr )
537 CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n,
538 \$ ierr )
539 END IF
540 IF( ilbscl )
541 \$ CALL slascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
542*
543* Select eigenvalues
544*
545 DO 10 i = 1, n
546 bwork( i ) = selctg( alphar( i ), alphai( i ), beta( i ) )
547 10 CONTINUE
548*
549 CALL stgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb, alphar,
550 \$ alphai, beta, vsl, ldvsl, vsr, ldvsr, sdim, pvsl,
551 \$ pvsr, dif, work( iwrk ), lwork-iwrk+1, idum, 1,
552 \$ ierr )
553 IF( ierr.EQ.1 )
554 \$ info = n + 3
555*
556 END IF
557*
558* Apply back-permutation to VSL and VSR
559*
560 IF( ilvsl )
561 \$ CALL sggbak( 'P', 'L', n, ilo, ihi, work( ileft ),
562 \$ work( iright ), n, vsl, ldvsl, ierr )
563*
564 IF( ilvsr )
565 \$ CALL sggbak( 'P', 'R', n, ilo, ihi, work( ileft ),
566 \$ work( iright ), n, vsr, ldvsr, ierr )
567*
568* Check if unscaling would cause over/underflow, if so, rescale
569* (ALPHAR(I),ALPHAI(I),BETA(I)) so BETA(I) is on the order of
570* B(I,I) and ALPHAR(I) and ALPHAI(I) are on the order of A(I,I)
571*
572 IF( ilascl )THEN
573 DO 50 i = 1, n
574 IF( alphai( i ).NE.zero ) THEN
575 IF( ( alphar( i )/safmax ).GT.( anrmto/anrm ) .OR.
576 \$ ( safmin/alphar( i ) ).GT.( anrm/anrmto ) ) THEN
577 work( 1 ) = abs( a( i, i )/alphar( i ) )
578 beta( i ) = beta( i )*work( 1 )
579 alphar( i ) = alphar( i )*work( 1 )
580 alphai( i ) = alphai( i )*work( 1 )
581 ELSE IF( ( alphai( i )/safmax ).GT.( anrmto/anrm ) .OR.
582 \$ ( safmin/alphai( i ) ).GT.( anrm/anrmto ) ) THEN
583 work( 1 ) = abs( a( i, i+1 )/alphai( i ) )
584 beta( i ) = beta( i )*work( 1 )
585 alphar( i ) = alphar( i )*work( 1 )
586 alphai( i ) = alphai( i )*work( 1 )
587 END IF
588 END IF
589 50 CONTINUE
590 END IF
591*
592 IF( ilbscl )THEN
593 DO 60 i = 1, n
594 IF( alphai( i ).NE.zero ) THEN
595 IF( ( beta( i )/safmax ).GT.( bnrmto/bnrm ) .OR.
596 \$ ( safmin/beta( i ) ).GT.( bnrm/bnrmto ) ) THEN
597 work( 1 ) = abs(b( i, i )/beta( i ))
598 beta( i ) = beta( i )*work( 1 )
599 alphar( i ) = alphar( i )*work( 1 )
600 alphai( i ) = alphai( i )*work( 1 )
601 END IF
602 END IF
603 60 CONTINUE
604 END IF
605*
606* Undo scaling
607*
608 IF( ilascl ) THEN
609 CALL slascl( 'H', 0, 0, anrmto, anrm, n, n, a, lda, ierr )
610 CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n, ierr )
611 CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n, ierr )
612 END IF
613*
614 IF( ilbscl ) THEN
615 CALL slascl( 'U', 0, 0, bnrmto, bnrm, n, n, b, ldb, ierr )
616 CALL slascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
617 END IF
618*
619 IF( wantst ) THEN
620*
621* Check if reordering is correct
622*
623 lastsl = .true.
624 lst2sl = .true.
625 sdim = 0
626 ip = 0
627 DO 30 i = 1, n
628 cursl = selctg( alphar( i ), alphai( i ), beta( i ) )
629 IF( alphai( i ).EQ.zero ) THEN
630 IF( cursl )
631 \$ sdim = sdim + 1
632 ip = 0
633 IF( cursl .AND. .NOT.lastsl )
634 \$ info = n + 2
635 ELSE
636 IF( ip.EQ.1 ) THEN
637*
638* Last eigenvalue of conjugate pair
639*
640 cursl = cursl .OR. lastsl
641 lastsl = cursl
642 IF( cursl )
643 \$ sdim = sdim + 2
644 ip = -1
645 IF( cursl .AND. .NOT.lst2sl )
646 \$ info = n + 2
647 ELSE
648*
649* First eigenvalue of conjugate pair
650*
651 ip = 1
652 END IF
653 END IF
654 lst2sl = lastsl
655 lastsl = cursl
656 30 CONTINUE
657*
658 END IF
659*
660 40 CONTINUE
661*
662 work( 1 ) = lwkopt
663*
664 RETURN
665*
666* End of SGGES3
667*
subroutine slascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
SLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: slascl.f:143
subroutine slaset(UPLO, M, N, ALPHA, BETA, A, LDA)
SLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: slaset.f:110
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:103
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
recursive subroutine slaqz0(WANTS, WANTQ, WANTZ, N, ILO, IHI, A, LDA, B, LDB, ALPHAR, ALPHAI, BETA, Q, LDQ, Z, LDZ, WORK, LWORK, REC, INFO)
SLAQZ0
Definition: slaqz0.f:304
subroutine sggbak(JOB, SIDE, N, ILO, IHI, LSCALE, RSCALE, M, V, LDV, INFO)
SGGBAK
Definition: sggbak.f:147
subroutine sggbal(JOB, N, A, LDA, B, LDB, ILO, IHI, LSCALE, RSCALE, WORK, INFO)
SGGBAL
Definition: sggbal.f:177
real function slange(NORM, M, N, A, LDA, WORK)
SLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: slange.f:114
subroutine sgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGEQRF
Definition: sgeqrf.f:146
subroutine stgsen(IJOB, WANTQ, WANTZ, SELECT, N, A, LDA, B, LDB, ALPHAR, ALPHAI, BETA, Q, LDQ, Z, LDZ, M, PL, PR, DIF, WORK, LWORK, IWORK, LIWORK, INFO)
STGSEN
Definition: stgsen.f:451
subroutine sorgqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
SORGQR
Definition: sorgqr.f:128
subroutine sormqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMQR
Definition: sormqr.f:168
subroutine sgghd3(COMPQ, COMPZ, N, ILO, IHI, A, LDA, B, LDB, Q, LDQ, Z, LDZ, WORK, LWORK, INFO)
SGGHD3
Definition: sgghd3.f:230
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: