LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ spftrf()

subroutine spftrf ( character transr,
character uplo,
integer n,
real, dimension( 0: * ) a,
integer info )

SPFTRF

Download SPFTRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> SPFTRF computes the Cholesky factorization of a real symmetric
!> positive definite matrix A.
!>
!> The factorization has the form
!>    A = U**T * U,  if UPLO = 'U', or
!>    A = L  * L**T,  if UPLO = 'L',
!> where U is an upper triangular matrix and L is lower triangular.
!>
!> This is the block version of the algorithm, calling Level 3 BLAS.
!>
Parameters
[in]TRANSR
!>          TRANSR is CHARACTER*1
!>          = 'N':  The Normal TRANSR of RFP A is stored;
!>          = 'T':  The Transpose TRANSR of RFP A is stored.
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangle of RFP A is stored;
!>          = 'L':  Lower triangle of RFP A is stored.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix A.  N >= 0.
!>
[in,out]A
!>          A is REAL array, dimension ( N*(N+1)/2 );
!>          On entry, the symmetric matrix A in RFP format. RFP format is
!>          described by TRANSR, UPLO, and N as follows: If TRANSR = 'N'
!>          then RFP A is (0:N,0:k-1) when N is even; k=N/2. RFP A is
!>          (0:N-1,0:k) when N is odd; k=N/2. IF TRANSR = 'T' then RFP is
!>          the transpose of RFP A as defined when
!>          TRANSR = 'N'. The contents of RFP A are defined by UPLO as
!>          follows: If UPLO = 'U' the RFP A contains the NT elements of
!>          upper packed A. If UPLO = 'L' the RFP A contains the elements
!>          of lower packed A. The LDA of RFP A is (N+1)/2 when TRANSR =
!>          'T'. When TRANSR is 'N' the LDA is N+1 when N is even and N
!>          is odd. See the Note below for more details.
!>
!>          On exit, if INFO = 0, the factor U or L from the Cholesky
!>          factorization RFP A = U**T*U or RFP A = L*L**T.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  if INFO = i, the leading principal minor of order i
!>                is not positive, and the factorization could not be
!>                completed.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  We first consider Rectangular Full Packed (RFP) Format when N is
!>  even. We give an example where N = 6.
!>
!>      AP is Upper             AP is Lower
!>
!>   00 01 02 03 04 05       00
!>      11 12 13 14 15       10 11
!>         22 23 24 25       20 21 22
!>            33 34 35       30 31 32 33
!>               44 45       40 41 42 43 44
!>                  55       50 51 52 53 54 55
!>
!>
!>  Let TRANSR = 'N'. RFP holds AP as follows:
!>  For UPLO = 'U' the upper trapezoid A(0:5,0:2) consists of the last
!>  three columns of AP upper. The lower triangle A(4:6,0:2) consists of
!>  the transpose of the first three columns of AP upper.
!>  For UPLO = 'L' the lower trapezoid A(1:6,0:2) consists of the first
!>  three columns of AP lower. The upper triangle A(0:2,0:2) consists of
!>  the transpose of the last three columns of AP lower.
!>  This covers the case N even and TRANSR = 'N'.
!>
!>         RFP A                   RFP A
!>
!>        03 04 05                33 43 53
!>        13 14 15                00 44 54
!>        23 24 25                10 11 55
!>        33 34 35                20 21 22
!>        00 44 45                30 31 32
!>        01 11 55                40 41 42
!>        02 12 22                50 51 52
!>
!>  Now let TRANSR = 'T'. RFP A in both UPLO cases is just the
!>  transpose of RFP A above. One therefore gets:
!>
!>
!>           RFP A                   RFP A
!>
!>     03 13 23 33 00 01 02    33 00 10 20 30 40 50
!>     04 14 24 34 44 11 12    43 44 11 21 31 41 51
!>     05 15 25 35 45 55 22    53 54 55 22 32 42 52
!>
!>
!>  We then consider Rectangular Full Packed (RFP) Format when N is
!>  odd. We give an example where N = 5.
!>
!>     AP is Upper                 AP is Lower
!>
!>   00 01 02 03 04              00
!>      11 12 13 14              10 11
!>         22 23 24              20 21 22
!>            33 34              30 31 32 33
!>               44              40 41 42 43 44
!>
!>
!>  Let TRANSR = 'N'. RFP holds AP as follows:
!>  For UPLO = 'U' the upper trapezoid A(0:4,0:2) consists of the last
!>  three columns of AP upper. The lower triangle A(3:4,0:1) consists of
!>  the transpose of the first two columns of AP upper.
!>  For UPLO = 'L' the lower trapezoid A(0:4,0:2) consists of the first
!>  three columns of AP lower. The upper triangle A(0:1,1:2) consists of
!>  the transpose of the last two columns of AP lower.
!>  This covers the case N odd and TRANSR = 'N'.
!>
!>         RFP A                   RFP A
!>
!>        02 03 04                00 33 43
!>        12 13 14                10 11 44
!>        22 23 24                20 21 22
!>        00 33 34                30 31 32
!>        01 11 44                40 41 42
!>
!>  Now let TRANSR = 'T'. RFP A in both UPLO cases is just the
!>  transpose of RFP A above. One therefore gets:
!>
!>           RFP A                   RFP A
!>
!>     02 12 22 00 01             00 10 20 30 40 50
!>     03 13 23 33 11             33 11 21 31 41 51
!>     04 14 24 34 44             43 44 22 32 42 52
!>

Definition at line 195 of file spftrf.f.

196*
197* -- LAPACK computational routine --
198* -- LAPACK is a software package provided by Univ. of Tennessee, --
199* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
200*
201* .. Scalar Arguments ..
202 CHARACTER TRANSR, UPLO
203 INTEGER N, INFO
204* ..
205* .. Array Arguments ..
206 REAL A( 0: * )
207*
208* =====================================================================
209*
210* .. Parameters ..
211 REAL ONE
212 parameter( one = 1.0e+0 )
213* ..
214* .. Local Scalars ..
215 LOGICAL LOWER, NISODD, NORMALTRANSR
216 INTEGER N1, N2, K
217* ..
218* .. External Functions ..
219 LOGICAL LSAME
220 EXTERNAL lsame
221* ..
222* .. External Subroutines ..
223 EXTERNAL xerbla, ssyrk, spotrf, strsm
224* ..
225* .. Intrinsic Functions ..
226 INTRINSIC mod
227* ..
228* .. Executable Statements ..
229*
230* Test the input parameters.
231*
232 info = 0
233 normaltransr = lsame( transr, 'N' )
234 lower = lsame( uplo, 'L' )
235 IF( .NOT.normaltransr .AND. .NOT.lsame( transr, 'T' ) ) THEN
236 info = -1
237 ELSE IF( .NOT.lower .AND. .NOT.lsame( uplo, 'U' ) ) THEN
238 info = -2
239 ELSE IF( n.LT.0 ) THEN
240 info = -3
241 END IF
242 IF( info.NE.0 ) THEN
243 CALL xerbla( 'SPFTRF', -info )
244 RETURN
245 END IF
246*
247* Quick return if possible
248*
249 IF( n.EQ.0 )
250 $ RETURN
251*
252* If N is odd, set NISODD = .TRUE.
253* If N is even, set K = N/2 and NISODD = .FALSE.
254*
255 IF( mod( n, 2 ).EQ.0 ) THEN
256 k = n / 2
257 nisodd = .false.
258 ELSE
259 nisodd = .true.
260 END IF
261*
262* Set N1 and N2 depending on LOWER
263*
264 IF( lower ) THEN
265 n2 = n / 2
266 n1 = n - n2
267 ELSE
268 n1 = n / 2
269 n2 = n - n1
270 END IF
271*
272* start execution: there are eight cases
273*
274 IF( nisodd ) THEN
275*
276* N is odd
277*
278 IF( normaltransr ) THEN
279*
280* N is odd and TRANSR = 'N'
281*
282 IF( lower ) THEN
283*
284* SRPA for LOWER, NORMAL and N is odd ( a(0:n-1,0:n1-1) )
285* T1 -> a(0,0), T2 -> a(0,1), S -> a(n1,0)
286* T1 -> a(0), T2 -> a(n), S -> a(n1)
287*
288 CALL spotrf( 'L', n1, a( 0 ), n, info )
289 IF( info.GT.0 )
290 $ RETURN
291 CALL strsm( 'R', 'L', 'T', 'N', n2, n1, one, a( 0 ),
292 $ n,
293 $ a( n1 ), n )
294 CALL ssyrk( 'U', 'N', n2, n1, -one, a( n1 ), n, one,
295 $ a( n ), n )
296 CALL spotrf( 'U', n2, a( n ), n, info )
297 IF( info.GT.0 )
298 $ info = info + n1
299*
300 ELSE
301*
302* SRPA for UPPER, NORMAL and N is odd ( a(0:n-1,0:n2-1)
303* T1 -> a(n1+1,0), T2 -> a(n1,0), S -> a(0,0)
304* T1 -> a(n2), T2 -> a(n1), S -> a(0)
305*
306 CALL spotrf( 'L', n1, a( n2 ), n, info )
307 IF( info.GT.0 )
308 $ RETURN
309 CALL strsm( 'L', 'L', 'N', 'N', n1, n2, one, a( n2 ),
310 $ n,
311 $ a( 0 ), n )
312 CALL ssyrk( 'U', 'T', n2, n1, -one, a( 0 ), n, one,
313 $ a( n1 ), n )
314 CALL spotrf( 'U', n2, a( n1 ), n, info )
315 IF( info.GT.0 )
316 $ info = info + n1
317*
318 END IF
319*
320 ELSE
321*
322* N is odd and TRANSR = 'T'
323*
324 IF( lower ) THEN
325*
326* SRPA for LOWER, TRANSPOSE and N is odd
327* T1 -> A(0,0) , T2 -> A(1,0) , S -> A(0,n1)
328* T1 -> a(0+0) , T2 -> a(1+0) , S -> a(0+n1*n1); lda=n1
329*
330 CALL spotrf( 'U', n1, a( 0 ), n1, info )
331 IF( info.GT.0 )
332 $ RETURN
333 CALL strsm( 'L', 'U', 'T', 'N', n1, n2, one, a( 0 ),
334 $ n1,
335 $ a( n1*n1 ), n1 )
336 CALL ssyrk( 'L', 'T', n2, n1, -one, a( n1*n1 ), n1,
337 $ one,
338 $ a( 1 ), n1 )
339 CALL spotrf( 'L', n2, a( 1 ), n1, info )
340 IF( info.GT.0 )
341 $ info = info + n1
342*
343 ELSE
344*
345* SRPA for UPPER, TRANSPOSE and N is odd
346* T1 -> A(0,n1+1), T2 -> A(0,n1), S -> A(0,0)
347* T1 -> a(n2*n2), T2 -> a(n1*n2), S -> a(0); lda = n2
348*
349 CALL spotrf( 'U', n1, a( n2*n2 ), n2, info )
350 IF( info.GT.0 )
351 $ RETURN
352 CALL strsm( 'R', 'U', 'N', 'N', n2, n1, one,
353 $ a( n2*n2 ),
354 $ n2, a( 0 ), n2 )
355 CALL ssyrk( 'L', 'N', n2, n1, -one, a( 0 ), n2, one,
356 $ a( n1*n2 ), n2 )
357 CALL spotrf( 'L', n2, a( n1*n2 ), n2, info )
358 IF( info.GT.0 )
359 $ info = info + n1
360*
361 END IF
362*
363 END IF
364*
365 ELSE
366*
367* N is even
368*
369 IF( normaltransr ) THEN
370*
371* N is even and TRANSR = 'N'
372*
373 IF( lower ) THEN
374*
375* SRPA for LOWER, NORMAL, and N is even ( a(0:n,0:k-1) )
376* T1 -> a(1,0), T2 -> a(0,0), S -> a(k+1,0)
377* T1 -> a(1), T2 -> a(0), S -> a(k+1)
378*
379 CALL spotrf( 'L', k, a( 1 ), n+1, info )
380 IF( info.GT.0 )
381 $ RETURN
382 CALL strsm( 'R', 'L', 'T', 'N', k, k, one, a( 1 ),
383 $ n+1,
384 $ a( k+1 ), n+1 )
385 CALL ssyrk( 'U', 'N', k, k, -one, a( k+1 ), n+1, one,
386 $ a( 0 ), n+1 )
387 CALL spotrf( 'U', k, a( 0 ), n+1, info )
388 IF( info.GT.0 )
389 $ info = info + k
390*
391 ELSE
392*
393* SRPA for UPPER, NORMAL, and N is even ( a(0:n,0:k-1) )
394* T1 -> a(k+1,0) , T2 -> a(k,0), S -> a(0,0)
395* T1 -> a(k+1), T2 -> a(k), S -> a(0)
396*
397 CALL spotrf( 'L', k, a( k+1 ), n+1, info )
398 IF( info.GT.0 )
399 $ RETURN
400 CALL strsm( 'L', 'L', 'N', 'N', k, k, one, a( k+1 ),
401 $ n+1, a( 0 ), n+1 )
402 CALL ssyrk( 'U', 'T', k, k, -one, a( 0 ), n+1, one,
403 $ a( k ), n+1 )
404 CALL spotrf( 'U', k, a( k ), n+1, info )
405 IF( info.GT.0 )
406 $ info = info + k
407*
408 END IF
409*
410 ELSE
411*
412* N is even and TRANSR = 'T'
413*
414 IF( lower ) THEN
415*
416* SRPA for LOWER, TRANSPOSE and N is even (see paper)
417* T1 -> B(0,1), T2 -> B(0,0), S -> B(0,k+1)
418* T1 -> a(0+k), T2 -> a(0+0), S -> a(0+k*(k+1)); lda=k
419*
420 CALL spotrf( 'U', k, a( 0+k ), k, info )
421 IF( info.GT.0 )
422 $ RETURN
423 CALL strsm( 'L', 'U', 'T', 'N', k, k, one, a( k ), n1,
424 $ a( k*( k+1 ) ), k )
425 CALL ssyrk( 'L', 'T', k, k, -one, a( k*( k+1 ) ), k,
426 $ one,
427 $ a( 0 ), k )
428 CALL spotrf( 'L', k, a( 0 ), k, info )
429 IF( info.GT.0 )
430 $ info = info + k
431*
432 ELSE
433*
434* SRPA for UPPER, TRANSPOSE and N is even (see paper)
435* T1 -> B(0,k+1), T2 -> B(0,k), S -> B(0,0)
436* T1 -> a(0+k*(k+1)), T2 -> a(0+k*k), S -> a(0+0)); lda=k
437*
438 CALL spotrf( 'U', k, a( k*( k+1 ) ), k, info )
439 IF( info.GT.0 )
440 $ RETURN
441 CALL strsm( 'R', 'U', 'N', 'N', k, k, one,
442 $ a( k*( k+1 ) ), k, a( 0 ), k )
443 CALL ssyrk( 'L', 'N', k, k, -one, a( 0 ), k, one,
444 $ a( k*k ), k )
445 CALL spotrf( 'L', k, a( k*k ), k, info )
446 IF( info.GT.0 )
447 $ info = info + k
448*
449 END IF
450*
451 END IF
452*
453 END IF
454*
455 RETURN
456*
457* End of SPFTRF
458*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
ssyrk
subroutine ssyrk(uplo, trans, n, k, alpha, a, lda, beta, c, ldc)
SSYRK
Definition ssyrk.f:169
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
spotrf
subroutine spotrf(uplo, n, a, lda, info)
SPOTRF
Definition spotrf.f:105
strsm
subroutine strsm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
STRSM
Definition strsm.f:181
Here is the call graph for this function:
Here is the caller graph for this function: