LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ cungl2()

 subroutine cungl2 ( integer M, integer N, integer K, complex, dimension( lda, * ) A, integer LDA, complex, dimension( * ) TAU, complex, dimension( * ) WORK, integer INFO )

CUNGL2 generates all or part of the unitary matrix Q from an LQ factorization determined by cgelqf (unblocked algorithm).

Purpose:
CUNGL2 generates an m-by-n complex matrix Q with orthonormal rows,
which is defined as the first m rows of a product of k elementary
reflectors of order n

Q  =  H(k)**H . . . H(2)**H H(1)**H

as returned by CGELQF.
Parameters
 [in] M M is INTEGER The number of rows of the matrix Q. M >= 0. [in] N N is INTEGER The number of columns of the matrix Q. N >= M. [in] K K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0. [in,out] A A is COMPLEX array, dimension (LDA,N) On entry, the i-th row must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by CGELQF in the first k rows of its array argument A. On exit, the m by n matrix Q. [in] LDA LDA is INTEGER The first dimension of the array A. LDA >= max(1,M). [in] TAU TAU is COMPLEX array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by CGELQF. [out] WORK WORK is COMPLEX array, dimension (M) [out] INFO INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value

Definition at line 112 of file cungl2.f.

113*
114* -- LAPACK computational routine --
115* -- LAPACK is a software package provided by Univ. of Tennessee, --
116* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
117*
118* .. Scalar Arguments ..
119 INTEGER INFO, K, LDA, M, N
120* ..
121* .. Array Arguments ..
122 COMPLEX A( LDA, * ), TAU( * ), WORK( * )
123* ..
124*
125* =====================================================================
126*
127* .. Parameters ..
128 COMPLEX ONE, ZERO
129 parameter( one = ( 1.0e+0, 0.0e+0 ),
130 \$ zero = ( 0.0e+0, 0.0e+0 ) )
131* ..
132* .. Local Scalars ..
133 INTEGER I, J, L
134* ..
135* .. External Subroutines ..
136 EXTERNAL clacgv, clarf, cscal, xerbla
137* ..
138* .. Intrinsic Functions ..
139 INTRINSIC conjg, max
140* ..
141* .. Executable Statements ..
142*
143* Test the input arguments
144*
145 info = 0
146 IF( m.LT.0 ) THEN
147 info = -1
148 ELSE IF( n.LT.m ) THEN
149 info = -2
150 ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
151 info = -3
152 ELSE IF( lda.LT.max( 1, m ) ) THEN
153 info = -5
154 END IF
155 IF( info.NE.0 ) THEN
156 CALL xerbla( 'CUNGL2', -info )
157 RETURN
158 END IF
159*
160* Quick return if possible
161*
162 IF( m.LE.0 )
163 \$ RETURN
164*
165 IF( k.LT.m ) THEN
166*
167* Initialise rows k+1:m to rows of the unit matrix
168*
169 DO 20 j = 1, n
170 DO 10 l = k + 1, m
171 a( l, j ) = zero
172 10 CONTINUE
173 IF( j.GT.k .AND. j.LE.m )
174 \$ a( j, j ) = one
175 20 CONTINUE
176 END IF
177*
178 DO 40 i = k, 1, -1
179*
180* Apply H(i)**H to A(i:m,i:n) from the right
181*
182 IF( i.LT.n ) THEN
183 CALL clacgv( n-i, a( i, i+1 ), lda )
184 IF( i.LT.m ) THEN
185 a( i, i ) = one
186 CALL clarf( 'Right', m-i, n-i+1, a( i, i ), lda,
187 \$ conjg( tau( i ) ), a( i+1, i ), lda, work )
188 END IF
189 CALL cscal( n-i, -tau( i ), a( i, i+1 ), lda )
190 CALL clacgv( n-i, a( i, i+1 ), lda )
191 END IF
192 a( i, i ) = one - conjg( tau( i ) )
193*
194* Set A(i,1:i-1,i) to zero
195*
196 DO 30 l = 1, i - 1
197 a( i, l ) = zero
198 30 CONTINUE
199 40 CONTINUE
200 RETURN
201*
202* End of CUNGL2
203*
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:78
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:74
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:128
Here is the call graph for this function:
Here is the caller graph for this function: