ctrti2()

subroutine ctrti2	(	character	uplo,
		character	diag,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		integer	info
	)

CTRTI2 computes the inverse of a triangular matrix (unblocked algorithm).

Download CTRTI2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CTRTI2 computes the inverse of a complex upper or lower triangular
 matrix.

 This is the Level 2 BLAS version of the algorithm.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the matrix A is upper or lower triangular. = 'U': Upper triangular = 'L': Lower triangular
[in]	DIAG	DIAG is CHARACTER*1 Specifies whether or not the matrix A is unit triangular. = 'N': Non-unit triangular = 'U': Unit triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the triangular matrix A. If UPLO = 'U', the leading n by n upper triangular part of the array A contains the upper triangular matrix, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n by n lower triangular part of the array A contains the lower triangular matrix, and the strictly upper triangular part of A is not referenced. If DIAG = 'U', the diagonal elements of A are also not referenced and are assumed to be 1. On exit, the (triangular) inverse of the original matrix, in the same storage format.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 109 of file ctrti2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE
      parameter( one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOUNIT, UPPER
      INTEGER            J
      COMPLEX            AJJ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cscal, ctrmv, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      nounit = lsame( diag, 'N' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CTRTI2', -info )
         RETURN
      END IF
*
      IF( upper ) THEN
*
*        Compute inverse of upper triangular matrix.
*
         DO 10 j = 1, n
            IF( nounit ) THEN
               a( j, j ) = one / a( j, j )
               ajj = -a( j, j )
            ELSE
               ajj = -one
            END IF
*
*           Compute elements 1:j-1 of j-th column.
*
            CALL ctrmv( 'Upper', 'No transpose', diag, j-1, a, lda,
     $                  a( 1, j ), 1 )
            CALL cscal( j-1, ajj, a( 1, j ), 1 )
   10    CONTINUE
      ELSE
*
*        Compute inverse of lower triangular matrix.
*
         DO 20 j = n, 1, -1
            IF( nounit ) THEN
               a( j, j ) = one / a( j, j )
               ajj = -a( j, j )
            ELSE
               ajj = -one
            END IF
            IF( j.LT.n ) THEN
*
*              Compute elements j+1:n of j-th column.
*
               CALL ctrmv( 'Lower', 'No transpose', diag, n-j,
     $                     a( j+1, j+1 ), lda, a( j+1, j ), 1 )
               CALL cscal( n-j, ajj, a( j+1, j ), 1 )
            END IF
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of CTRTI2
*

Here is the call graph for this function:

Here is the caller graph for this function: